—

              
#!perl
our $DATE = '2020-04-29'; # DATE
our $VERSION = '0.122'; # VERSION
use 5.010;
use strict;
use warnings;
use App::PlUtils;
use Perinci::CmdLine::Any;
our %SPEC;
$SPEC{plsub} = {
    v => 1.1,
    summary => 'List subroutines defined in a Perl script (or module)',
    description => <<'_',
_
    args => {
        module => $App::PlUtils::arg_module_single,
        file => {
            summary => 'Specify file instead of module',
            schema  => 'filename*',
            pos     => 0,
        },
        detail => {
            schema => 'bool',
        },
    },
    result_naked=>1,
};
sub plsub {
    require Compiler::Lexer;
    require Module::Path::More;
    my %args = @_;
    my $path;
    if (defined $args{module}) {
        my $mod = $args{module};
        $mod =~ s/\.pm$//; $mod =~ s!/!::!g; # convenience
        $path = Module::Path::More::module_path(module=>$mod);
        die "Can't find module '$mod'" unless $path;
    } elsif (defined $args{file}) {
        $path = $args{file};
        (-f $path) or die "No such file '$path'\n";
    } else {
        die "Please specify file or module (-m)\n";
    }
    my $lexer = Compiler::Lexer->new($path);
    my $ct = do {
        undef $/;
        open my $fh, "<", $path or die "Can't open '$path': $!\n";
        my $res = <$fh>;
        close $fh;
        $res;
    };
    my $tokens = $lexer->tokenize($ct);
    my @res;
    for my $i (0..@$tokens-1) {
        my $t = $tokens->[$i];
        my $sub;
        if ($i < @$tokens-1 && $t->{name} eq 'FunctionDecl') {
            my $t2 = $tokens->[$i+1];
            if ($t2->{name} eq 'Function') {
                $sub = $t2->{data};
            }
        }
        if ($sub) {
            if ($args{detail}) {
                push @res, {
                    name => $sub,
                    line => $t->{line},
                };
            } else {
                push @res, $sub;
            }
        }
    }
    \@res;
}
Perinci::CmdLine::Any->new(
    url => '/main/plsub',
    read_config => 0,
    read_env => 0,
)->run;
# ABSTRACT: List subroutines defined in a Perl script (or module)
# PODNAME: plsub
__END__
HideShow 178 lines of Pod
=pod
=encoding UTF-8
=head1 NAME
plsub - List subroutines defined in a Perl script (or module)
=head1 VERSION
This document describes version 0.122 of plsub (from Perl distribution App-PlUtils), released on 2020-04-29.
=head1 SYNOPSIS
 % plsub Some/script.pl
 % plsub --module Some::Module
Sample output:
 % plsub --module Org::Element::Table
 +--------------+
 | BUILD        |
 | rows         |
 | row_count    |
 | column_count |
 | as_aoa       |
 +--------------+
 % plsub -m Org/Element/Table --detail
 +------+--------------+
 | line | name         |
 | 13   | BUILD        |
 | 55   | rows         |
 | 65   | row_count    |
 | 75   | column_count |
 | 96   | as_aoa       |
 +------+--------------+
=head1 DESCRIPTION
=head1 OPTIONS
C<*> marks required options.
=head2 Main options
=over
=item B<--detail>
=item B<--file>=I<s>
Specify file instead of module.
=item B<--module>=I<s>, B<-m>
=back
=head2 Output options
=over
=item B<--format>=I<s>
Choose output format, e.g. json, text.
Default value:
 undef
=item B<--json>
Set output format to json.
=item B<--naked-res>
When outputing as JSON, strip result envelope.
Default value:
 0
By default, when outputing as JSON, the full enveloped result is returned, e.g.:
    [200,"OK",[1,2,3],{"func.extra"=>4}]
The reason is so you can get the status (1st element), status message (2nd
element) as well as result metadata/extra result (4th element) instead of just
the result (3rd element). However, sometimes you want just the result, e.g. when
you want to pipe the result for more post-processing. In this case you can use
`--naked-res` so you just get:
    [1,2,3]
=item B<--page-result>
Filter output through a pager.
=back
=head2 Other options
=over
=item B<--help>, B<-h>, B<-?>
Display help message and exit.
=item B<--version>, B<-v>
Display program's version and exit.
=back
=head1 COMPLETION
This script has shell tab completion capability with support for several
shells.
=head2 bash
To activate bash completion for this script, put:
 complete -C plsub plsub
in your bash startup (e.g. F<~/.bashrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.
It is recommended, however, that you install modules using L<cpanm-shcompgen>
which can activate shell completion for scripts immediately.
=head2 tcsh
To activate tcsh completion for this script, put:
 complete plsub 'p/*/`plsub`/'
in your tcsh startup (e.g. F<~/.tcshrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.
It is also recommended to install L<shcompgen> (see above).
=head2 other shells
For fish and zsh, install L<shcompgen> as described above.
=head1 HOMEPAGE
Please visit the project's homepage at L<https://metacpan.org/release/App-PlUtils>.
=head1 SOURCE
Source repository is at L<https://github.com/perlancar/perl-App-PlUtils>.
=head1 BUGS
Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-PlUtils>
When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.
=head1 AUTHOR
perlancar <perlancar@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2020, 2019, 2017, 2016, 2015, 2014 by perlancar@cpan.org.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut