/ 
Text-Xslate-0.1047
River stage two • 72 direct dependents • 86 total dependents
/ Text::Xslate::Cookbook

NAME

Text::Xslate::Cookbook - How to cook Xslate templates

DESCRIPTION

The Xslate cookbook is a set of recipes showing Xslate features.

RECIPES

How to manage HTML forms

Managing HTML forms is an important issue on web applications. you'd better to use modules that manage HTML forms, rather than do something with templates by yourself. This section propose two basic solutions: FillInForm and HTML form builders.

In both solutions, one should not use the mark_raw filter, which easily makes security holes. Instead, application code should be responsible to call the mark_raw function that Text::Xslate can export.

Using FillInForm

One solution to manage HTML forms is to use FillInForm modules with the block filter syntax.

Example code using HTML::FillInForm:

#!perl -w
use strict;
use Text::Xslate qw(mark_raw);
use HTML::FillInForm;

sub fillinform {
    my($q) = @_;

    return sub {
        my($html) = @_;
        # do mark_raw() here, not in templates
        return mark_raw(HTML::FillInForm->fill(\unmark_raw($html), $q));
    };
}

my $tx  = Text::Xslate->new(
    function => {
        fillinform => \&fillinform,
    },
);

my %vars = (
    q => { foo => "<filled value>" },
);
print $tx->render_string(<<'T', \%vars);
FillInForm:
: block form | fillinform($q) -> {
<form>
<input type="text" name="foo" />
</form>
: }
T

Output:

FillInForm:
<form>
<input type="text" name="foo" value="&lt;filled value&gt;" />
</form>

See also HTML::FillInForm or HTML::FillInForm::Lite for details.

Using HTML form builders

Another solution to manage HTML forms is to use form builders.

Here is a PSGI application that uses HTML::Shakan:

#!psgi
use strict;
use warnings;
use Text::Xslate qw(mark_raw);
use HTML::Shakan;
use Plack::Request;

my $tx = Text::Xslate->new();

sub app {
    my($env) = @_;
    my $req  = Plack::Request->new($env);

    my $shakan = HTML::Shakan->new(
        request => $req,
        fields  => [ TextField(name => 'name', label => 'Your name: ') ],
    );

    my $res = $req->new_response(200);

    # do mark_raw here, not in templates
    my $form = mark_raw($shakan->render());
    $res->body( $tx->render_string(<<'T', { form => $form }) );
<!doctype html>
<html>
<head><title>Building form</title></head>
<body>
<form>
<p>
Form:<br />
<: $form :>
</p>
</body>
</html>
T
    return $res->finalize();

}

return \&app;

Output:

<!doctype html>
<html>
<head><title>Building form</title></head>
<body>
<form>
<p>
Form:<br />
<label for="id_name">Your name</label>
<input id="id_name" name="name" type="text" value="&lt;Xslate&gt;" />
</p>
</body>
</html>

See also HTML::Shakan for details.

How to apply uri-escape to template expressions

Use URI::Escape or URI::Escape::XS.

Code using URI::Escape:

#!perl -w
use strict;
use Text::Xslate;

my $tx  = Text::Xslate->new(
    module => ['URI::Escape'],
);

print $tx->render_string(<<'T', { app_param => "foo & bar" });
<a href="http://example.com/app/<:
    $app_param | uri_escape_utf8 :>">something</a>
T

Output:

<a href="http://example.com/app/foo%20%26%20bar">something</a>

See also URI::Escape or URI::Escape::XS.

How to use Template Toolkit's WRAPPER feature in Kolon

Use template cascading, which is a super-set of the WRAPPER directive.

wrapper.tx:

<div class="wrapper">
block content -> { }
</div>

content.tx

: cascade wrapper

: override content -> {
    Hello, world!
: }

Output:

<div class="wrapper">
    Hello, world!
</div>

See "Template cascading" in Text::Xslate for details.

How to map __DATA__ sections to the include path

Use Data::Section::Simple, and the path option of new(), which accepts HASH references which contain $file_name => $content mapping.

use Text::Xslate;
use Data::Section::Simple;

my $vpath = Data::Section::Simple->new()->get_data_section();
my $tx = Text::Xslate->new(
    path => [$vpath],
);

print $tx->render('child.tx');

__DATA__
@@ base.tx
<html>
<body><: block body -> { :>default body<: } :></body>
</html>
@@ child.tx
: cascade base;
: override body -> {
child body
: } # endblock body

This feature is inspired by Text::MicroTemplate::DataSection.

See also Data::Section::Simple and Text::MicroTemplate::DataSection.

SEE ALSO

Text::Xslate