NAME

Mojolicious::Guides::Cookbook - Cooking with Mojolicious

OVERVIEW

This document contains many fun recipes for cooking with Mojolicious.

CONCEPTS

Essentials every Mojolicious developer should know.

Blocking and non-blocking operations

A blocking operation is a subroutine that blocks the execution of the calling subroutine until the subroutine is finished.

sub foo {
  my $result = blocking_subroutine();
  ...
}

A non-blocking operation on the other hand lets the calling subroutine continue execution even though the subroutine is not yet finished. Instead of waiting, the calling subroutine passes along a callback to be executed once the subroutine is finished, this is called continuation-passing style.

sub foo {
  non_blocking_subroutine(sub {
    my $result = shift;
    ...
  });
  ...
}

While Mojolicious has been designed from the ground up for non-blocking I/O and event loops, it is not possible to magically make Perl code non-blocking. You have to use specialized non-blocking code available through modules like Mojo::IOLoop and Mojo::UserAgent, or third-party event loops. You can wrap your blocking code in subprocesses though to prevent it from interfering with your non-blocking code.

Event loops

An event loop is basically a loop that continually tests for external events and executes the appropriate callbacks to handle them, it is often the main loop in a program. Non-blocking tests for readability/writability of file descriptors and timers are commonly used events for highly scalable network servers, because they allow a single process to handle thousands of client connections concurrently.

while (1) {
  my @readable = test_fds_for_readability();
  handle_readable_fds(@readable);

  my @writable = test_fds_for_writability();
  handle_writable_fds(@writable);

  my @expired = test_timers();
  handle_timers(@expired);
}

In Mojolicious this event loop is Mojo::IOLoop.

Reverse proxy

A reverse proxy architecture is a deployment technique used in many production environments, where a reverse proxy server is put in front of your application to act as the endpoint accessible by external clients. It can provide a lot of benefits, like terminating SSL connections from the outside, limiting the number of concurrent open sockets towards the Mojolicious application (or even using Unix sockets), balancing load across multiple instances, or supporting several applications through the same IP/port.

                ..........................................
                :                                        :
+--------+      :  +-----------+      +---------------+  :
|        |-------->|           |      |               |  :
| client |      :  |  reverse  |----->|  Mojolicious  |  :
|        |<--------|   proxy   |      |  application  |  :
+--------+      :  |           |<-----|               |  :
                :  +-----------+      +---------------+  :
                :                                        :
                .. system boundary (e.g. same host) ......

This setup introduces some problems, though: the application will receive requests from the reverse proxy instead of the original client; the address/hostname where your application lives internally will be different from the one visible from the outside; and if terminating SSL, the reverse proxy exposes services via HTTPS while using HTTP towards the Mojolicious application.

As an example, compare a sample request from the client and what the Mojolicious application receives:

client                       reverse proxy                Mojolicious app
 __|__              _______________|______________             ____|____
/     \            /                              \           /         \
1.2.3.4 --HTTPS--> api.example.com      10.20.30.39 --HTTP--> 10.20.30.40

GET /foo/1 HTTP/1.1                |    GET /foo/1 HTTP/1.1
Host: api.example.com              |    Host: 10.20.30.40
User-Agent: Firefox                |    User-Agent: ShinyProxy/1.2
...                                |    ...

However, now the client address is no longer available (which might be useful for analytics, or Geo-IP) and URLs generated via "url_for" in Mojolicious::Controller will look like this:

http://10.20.30.40/bar/2

instead of something meaningful for the client, like this:

https://api.example.com/bar/2

To solve these problems, you can configure your reverse proxy to send the missing data (see "Nginx" and "Apache/mod_proxy") and tell your application about it by setting the environment variable MOJO_REVERSE_PROXY. For finer control, "Rewriting" includes examples of how the changes could be implemented manually.

DEPLOYMENT

Getting Mojolicious and Mojolicious::Lite applications running on different platforms. Note that many real-time web features are based on the Mojo::IOLoop event loop, and therefore require one of the built-in web servers to be able to use them to their full potential.

Built-in web server

Mojolicious contains a very portable non-blocking I/O HTTP and WebSocket server with Mojo::Server::Daemon. It is usually used during development and in the construction of more advanced web servers, but is solid and fast enough for small to mid sized applications.

$ ./script/my_app daemon
Server available at http://127.0.0.1:3000

It is available to every application through the command Mojolicious::Command::daemon, which has many configuration options and is known to work on every platform Perl works on with its single-process architecture.

$ ./script/my_app daemon -h
...List of available options...

Another huge advantage is that it supports TLS and WebSockets out of the box, a development certificate for testing purposes is built right in, so it just works, but you can specify all listen locations supported by "listen" in Mojo::Server::Daemon.

$ ./script/my_app daemon -l https://[::]:3000
Server available at https://[::]:3000

To manage the web server with systemd, you can use a unit configuration file like this.

[Unit]
Description=My Mojolicious application
After=network.target

[Service]
Type=simple
ExecStart=/home/sri/myapp/script/my_app daemon -m production -l http://*:8080

[Install]
WantedBy=multi-user.target

Pre-forking

On UNIX platforms you can also add pre-forking to the built-in web server and switch to a multi-process architecture with Mojolicious::Command::prefork, to take advantage of multiple CPU cores and copy-on-write memory management.

$ ./script/my_app prefork
Server available at http://127.0.0.1:3000

Since all built-in web servers are based on the Mojo::IOLoop event loop, they scale best with non-blocking operations. But if your application for some reason needs to perform many blocking operations, you can improve performance by increasing the number of worker processes and decreasing the number of concurrent connections each worker is allowed to handle (often as low as 1).

$ ./script/my_app prefork -m production -w 10 -c 1
Server available at http://127.0.0.1:3000

During startup your application is preloaded in the manager process, which does not run an event loop, so you can use "next_tick" in Mojo::IOLoop to run code whenever a new worker process has been forked and its event loop gets started.

use Mojolicious::Lite;

Mojo::IOLoop->next_tick(sub {
  app->log->info("Worker $$ star...ALL GLORY TO THE HYPNOTOAD!");
});

get '/' => {text => 'Hello Wor...ALL GLORY TO THE HYPNOTOAD!'};

app->start;

And to manage the pre-forking web server with systemd, you can use a unit configuration file like this.

[Unit]
Description=My Mojolicious application
After=network.target

[Service]
Type=simple
ExecStart=/home/sri/myapp/script/my_app prefork -m production -l http://*:8080

[Install]
WantedBy=multi-user.target

Morbo

After reading the Mojolicious::Guides::Tutorial, you should already be familiar with Mojo::Server::Morbo.

Mojo::Server::Morbo
+- Mojo::Server::Daemon

It is basically a restarter that forks a new Mojo::Server::Daemon web server whenever a file in your project changes, and should therefore only be used during development. To start applications with it you can use the morbo script.

$ morbo ./script/my_app
Server available at http://127.0.0.1:3000

Hypnotoad

For bigger applications Mojolicious contains the UNIX optimized pre-forking web server Hypnotoad, which can take advantage of multiple CPU cores and copy-on-write memory management to scale up to thousands of concurrent client connections.

Mojo::Server::Hypnotoad
|- Mojo::Server::Daemon [1]
|- Mojo::Server::Daemon [2]
|- Mojo::Server::Daemon [3]
+- Mojo::Server::Daemon [4]

It is based on the Mojo::Server::Prefork web server, which adds pre-forking to Mojo::Server::Daemon, but optimized specifically for production environments out of the box. To start applications with it you can use the hypnotoad script, which listens on port 8080, automatically daemonizes the server process and defaults to production mode for Mojolicious and Mojolicious::Lite applications.

$ hypnotoad ./script/my_app

Many configuration settings can be tweaked right from within your application with "config" in Mojolicious, for a full list see "SETTINGS" in Mojo::Server::Hypnotoad.

use Mojolicious::Lite;

app->config(hypnotoad => {listen => ['http://*:80']});

get '/' => {text => 'Hello Wor...ALL GLORY TO THE HYPNOTOAD!'};

app->start;

Or just add a hypnotoad section to your Mojolicious::Plugin::Config or Mojolicious::Plugin::JSONConfig configuration file.

# myapp.conf
{
  hypnotoad => {
    listen  => ['https://*:443?cert=/etc/server.crt&key=/etc/server.key'],
    workers => 10
  }
};

But one of its biggest advantages is the support for effortless zero downtime software upgrades (hot deployment). That means you can upgrade Mojolicious, Perl or even system libraries at runtime without ever stopping the server or losing a single incoming connection, just by running the command above again.

$ hypnotoad ./script/my_app
Starting hot deployment for Hypnotoad server 31841.

You might also want to enable proxy support if you're using Hypnotoad behind a reverse proxy. This allows Mojolicious to automatically pick up the X-Forwarded-For and X-Forwarded-Proto headers.

# myapp.conf
{hypnotoad => {proxy => 1}};

To manage Hypnotoad with systemd, you can use a unit configuration file like this.

[Unit]
Description=My Mojolicious application
After=network.target

[Service]
Type=forking
PIDFile=/home/sri/myapp/script/hypnotoad.pid
ExecStart=/path/to/hypnotoad /home/sri/myapp/script/my_app
ExecReload=/path/to/hypnotoad /home/sri/myapp/script/my_app
KillMode=process

[Install]
WantedBy=multi-user.target

Zero downtime software upgrades

Hypnotoad makes zero downtime software upgrades (hot deployment) very simple, as you can see above, but on modern operating systems that support the SO_REUSEPORT socket option, there is also another method available that works with all built-in web servers.

$ ./script/my_app prefork -P /tmp/first.pid -l http://*:8080?reuse=1
Server available at http://127.0.0.1:8080

All you have to do, is to start a second web server listening to the same port, and stop the first web server gracefully afterwards.

$ ./script/my_app prefork -P /tmp/second.pid -l http://*:8080?reuse=1
Server available at http://127.0.0.1:8080
$ kill -s TERM `cat /tmp/first.pid`

Just remember that both web servers need to be started with the reuse parameter.

Nginx

One of the most popular setups these days is Hypnotoad behind an Nginx reverse proxy, which even supports WebSockets in newer versions.

upstream myapp {
  server 127.0.0.1:8080;
}
server {
  listen 80;
  server_name localhost;
  location / {
    proxy_pass http://myapp;
    proxy_http_version 1.1;
    proxy_set_header Upgrade $http_upgrade;
    proxy_set_header Connection "upgrade";
    proxy_set_header Host $host;
    proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
    proxy_set_header X-Forwarded-Proto $scheme;
  }
}

Apache/mod_proxy

Another good reverse proxy is Apache with mod_proxy, the configuration looks quite similar to the Nginx one above. And if you need WebSocket support, newer versions come with mod_proxy_wstunnel.

<VirtualHost *:80>
  ServerName localhost
  <Proxy *>
    Require all granted
  </Proxy>
  ProxyRequests Off
  ProxyPreserveHost On
  ProxyPass /echo ws://localhost:8080/echo
  ProxyPass / http://localhost:8080/ keepalive=On
  ProxyPassReverse / http://localhost:8080/
  RequestHeader set X-Forwarded-Proto "http"
</VirtualHost>

Apache/CGI

CGI is supported out of the box and your Mojolicious application will automatically detect that it is executed as a CGI script. Its use in production environments is discouraged though, because as a result of how CGI works, it is very slow and many web servers are making it exceptionally hard to configure properly. Additionally, many real-time web features, such as WebSockets, are not available.

ScriptAlias / /home/sri/my_app/script/my_app/

PSGI/Plack

PSGI is an interface between Perl web frameworks and web servers, and Plack is a Perl module and toolkit that contains PSGI middleware, helpers and adapters to web servers. PSGI and Plack are inspired by Python's WSGI and Ruby's Rack. Mojolicious applications are ridiculously simple to deploy with Plack, but be aware that many real-time web features, such as WebSockets, are not available.

$ plackup ./script/my_app

Plack provides many server and protocol adapters for you to choose from, such as FCGI, uWSGI and mod_perl.

$ plackup ./script/my_app -s FCGI -l /tmp/myapp.sock

The MOJO_REVERSE_PROXY environment variable can be used to enable proxy support, this allows Mojolicious to automatically pick up the X-Forwarded-For and X-Forwarded-Proto headers.

$ MOJO_REVERSE_PROXY=1 plackup ./script/my_app

If an older server adapter is unable to correctly detect the application home directory, you can simply use the MOJO_HOME environment variable.

$ MOJO_HOME=/home/sri/my_app plackup ./script/my_app

There is no need for a .psgi file, just point the server adapter at your application script, it will automatically act like one if it detects the presence of a PLACK_ENV environment variable.

Plack middleware

Wrapper scripts like myapp.fcgi are a great way to separate deployment and application logic.

#!/usr/bin/env plackup -s FCGI
use Plack::Builder;

builder {
  enable 'Deflater';
  require './script/my_app';
};

Mojo::Server::PSGI can be used directly to load and customize applications in the wrapper script.

#!/usr/bin/env plackup -s FCGI
use Mojo::Server::PSGI;
use Plack::Builder;

builder {
  enable 'Deflater';
  my $server = Mojo::Server::PSGI->new;
  $server->load_app('./script/my_app');
  $server->app->config(foo => 'bar');
  $server->to_psgi_app;
};

But you could even use middleware right in your application.

use Mojolicious::Lite;
use Plack::Builder;

get '/welcome' => sub {
  my $c = shift;
  $c->render(text => 'Hello Mojo!');
};

builder {
  enable 'Deflater';
  app->start;
};

Rewriting

Sometimes you might have to deploy your application in a blackbox environment where you can't just change the server configuration or behind a reverse proxy that passes along additional information with X-Forwarded-* headers. In such cases you can use the hook "before_dispatch" in Mojolicious to rewrite incoming requests.

# Change scheme if "X-Forwarded-HTTPS" header is set
$app->hook(before_dispatch => sub {
  my $c = shift;
  $c->req->url->base->scheme('https')
    if $c->req->headers->header('X-Forwarded-HTTPS');
});

Since reverse proxies generally don't pass along information about path prefixes your application might be deployed under, rewriting the base path of incoming requests is also quite common. This allows "url_for" in Mojolicious::Controller for example, to generate portable URLs based on the current environment.

# Move first part and slash from path to base path in production mode
$app->hook(before_dispatch => sub {
  my $c = shift;
  push @{$c->req->url->base->path->trailing_slash(1)},
    shift @{$c->req->url->path->leading_slash(0)};
}) if $app->mode eq 'production';

Mojo::URL objects are very easy to manipulate, just make sure that the URL (foo/bar?baz=yada), which represents the routing destination, is always relative to the base URL (http://example.com/myapp/), which represents the deployment location of your application.

Application embedding

From time to time you might want to reuse parts of Mojolicious applications like configuration files, database connection or helpers for other scripts, with this little Mojo::Server based mock server you can just embed them.

use Mojo::Server;

# Load application with mock server
my $server = Mojo::Server->new;
my $app = $server->load_app('./myapp.pl');

# Access fully initialized application
say for @{$app->static->paths};
say $app->config->{secret_identity};
say $app->dumper({just => 'a helper test'});
say $app->build_controller->render_to_string(template => 'foo');

The plugin Mojolicious::Plugin::Mount uses this functionality to allow you to combine multiple applications into one and deploy them together.

use Mojolicious::Lite;

app->config(hypnotoad => {listen => ['http://*:80']});

plugin Mount => {'test1.example.com' => '/home/sri/myapp1.pl'};
plugin Mount => {'test2.example.com' => '/home/sri/myapp2.pl'};

app->start;

Web server embedding

You can also use "one_tick" in Mojo::IOLoop to embed the built-in web server Mojo::Server::Daemon into alien environments like foreign event loops that for some reason can't just be integrated with a new reactor backend.

use Mojolicious::Lite;
use Mojo::IOLoop;
use Mojo::Server::Daemon;

# Normal action
get '/' => {text => 'Hello World!'};

# Connect application with web server and start accepting connections
my $daemon
  = Mojo::Server::Daemon->new(app => app, listen => ['http://*:8080']);
$daemon->start;

# Call "one_tick" repeatedly from the alien environment
Mojo::IOLoop->one_tick while 1;

REAL-TIME WEB

The real-time web is a collection of technologies that include Comet (long polling), EventSource and WebSockets, which allow content to be pushed to consumers with long-lived connections as soon as it is generated, instead of relying on the more traditional pull model. All built-in web servers use non-blocking I/O and are based on the Mojo::IOLoop event loop, which provides many very powerful features that allow real-time web applications to scale up to thousands of concurrent client connections.

Backend web services

Since Mojo::UserAgent is also based on the Mojo::IOLoop event loop, it won't block the built-in web servers when used non-blocking, even for high latency backend web services.

use Mojolicious::Lite;

# Search MetaCPAN for "mojolicious"
get '/' => sub {
  my $c = shift;
  $c->ua->get('fastapi.metacpan.org/v1/module/_search?q=mojolicious' => sub {
    my ($ua, $tx) = @_;
    $c->render('metacpan', hits => $tx->result->json->{hits}{hits});
  });
};

app->start;
__DATA__

@@ metacpan.html.ep
<!DOCTYPE html>
<html>
  <head><title>MetaCPAN results for "mojolicious"</title></head>
  <body>
    % for my $hit (@$hits) {
      <p><%= $hit->{_source}{release} %></p>
    % }
  </body>
</html>

The callback passed to "get" in Mojo::UserAgent will be executed once the request to the backend web service has been finished, this is called continuation-passing style.

Synchronizing non-blocking operations

Multiple non-blocking operations, such as concurrent requests, can be easily synchronized with promises and "all" in Mojo::Promise. You create Mojo::Promise objects manually or use methods like "get_p" in Mojo::UserAgent that create them for you.

use Mojolicious::Lite;
use Mojo::Promise;
use Mojo::URL;

# Search MetaCPAN for "mojo" and "minion"
get '/' => sub {
  my $c = shift;

  # Create two promises
  my $url   = Mojo::URL->new('fastapi.metacpan.org/v1/module/_search');
  my $mojo   = $c->ua->get_p($url->clone->query({q => 'mojo'}));
  my $minion = $c->ua->get_p($url->clone->query({q => 'minion'}));

  # Render a response once both promises have been resolved
  Mojo::Promise->all($mojo, $minion)->then(sub {
    my ($mojo, $minion) = @_;
    $c->render(json => {
      mojo   => $mojo->[0]->result->json('/hits/hits/0/_source/release'),
      minion => $minion->[0]->result->json('/hits/hits/0/_source/release')
    });
  })->catch(sub {
    my $err = shift;
    $c->reply->exception($err);
  })->wait;
};

app->start;

To create promises manually you just wrap your continuation-passing style APIs in functions that return promises. Here's an example for how "get_p" in Mojo::UserAgent works internally.

use Mojo::UserAgent;
use Mojo::Promise;

# Wrap a user agent method with a promise
my $ua = Mojo::UserAgent->new;
sub get_p {
  my $promise = Mojo::Promise->new;
  $ua->get(@_ => sub {
    my ($ua, $tx) = @_;
    my $err = $tx->error;
    $promise->resolve($tx) if !$err || $err->{code};
    $promise->reject($err->{message});
  });
  return $promise;
}

# Use our new promise generating function
get_p('http://mojolicious.org')->then(sub {
  my $tx = shift;
  say $tx->result->dom->at('title')->text;
})->wait;

Promises have three states, they start out as pending and you call "resolve" in Mojo::Promise to transition them to fulfilled, or "reject" in Mojo::Promise to transition them to rejected.

Timers

Timers, another primary feature of the event loop, are created with "timer" in Mojo::IOLoop and can, for example, be used to delay rendering of a response, and unlike sleep, won't block any other requests that might be processed concurrently.

use Mojolicious::Lite;
use Mojo::IOLoop;

# Wait 3 seconds before rendering a response
get '/' => sub {
  my $c = shift;
  Mojo::IOLoop->timer(3 => sub {
    $c->render(text => 'Delayed by 3 seconds!');
  });
};

app->start;

Recurring timers created with "recurring" in Mojo::IOLoop are slightly more powerful, but need to be stopped manually, or they would just keep getting emitted.

use Mojolicious::Lite;
use Mojo::IOLoop;

# Count to 5 in 1 second steps
get '/' => sub {
  my $c = shift;

  # Start recurring timer
  my $i = 1;
  my $id = Mojo::IOLoop->recurring(1 => sub {
    $c->write_chunk($i);
    $c->finish if $i++ == 5;
  });

  # Stop recurring timer
  $c->on(finish => sub { Mojo::IOLoop->remove($id) });
};

app->start;

Timers are not tied to a specific request or connection, and can even be created at startup time.

use Mojolicious::Lite;
use Mojo::IOLoop;

# Check title in the background every 10 seconds
my $title = 'Got no title yet.';
Mojo::IOLoop->recurring(10 => sub {
  app->ua->get('http://mojolicious.org' => sub {
    my ($ua, $tx) = @_;
    $title = $tx->result->dom->at('title')->text;
  });
});

# Show current title
get '/' => sub {
  my $c = shift;
  $c->render(json => {title => $title});
};

app->start;

Just remember that all these non-blocking operations are processed cooperatively, so your callbacks shouldn't block for too long.

Subprocesses

You can also use subprocesses, created with "subprocess" in Mojo::IOLoop, to perform computationally expensive operations without blocking the event loop.

use Mojolicious::Lite;
use Mojo::IOLoop;

# Operation that would block the event loop for 5 seconds
get '/' => sub {
  my $c = shift;
  Mojo::IOLoop->subprocess(
    sub {
      my $subprocess = shift;
      sleep 5;
      return '♥', 'Mojolicious';
    },
    sub {
      my ($subprocess, $err, @results) = @_;
      $c->reply->exception($err) and return if $err;
      $c->render(text => "I $results[0] $results[1]!");
    }
  );
};

app->start;

The first callback will be executed in a child process, without blocking the event loop of the parent process. The results of the first callback will then be shared between both processes, and the second callback executed in the parent process.

Exceptions in non-blocking operations

Since timers and other non-blocking operations are running solely in the event loop, outside of the application, exceptions that get thrown in callbacks can't get caught and handled automatically. But you can handle them manually by subscribing to the event "error" in Mojo::Reactor or catching them inside the callback.

use Mojolicious::Lite;
use Mojo::IOLoop;

# Forward error messages to the application log
Mojo::IOLoop->singleton->reactor->on(error => sub {
  my ($reactor, $err) = @_;
  app->log->error($err);
});

# Exception only gets logged (and connection times out)
get '/connection_times_out' => sub {
  my $c = shift;
  Mojo::IOLoop->timer(2 => sub {
    die 'This request will not be getting a response';
  });
};

# Exception gets caught and handled
get '/catch_exception' => sub {
  my $c = shift;
  Mojo::IOLoop->timer(2 => sub {
    eval { die 'This request will be getting a response' };
    $c->reply->exception($@) if $@;
  });
};

app->start;

A default subscriber that turns all errors into warnings will usually be added by Mojo::IOLoop as a fallback.

Mojo::IOLoop->singleton->reactor->unsubscribe('error');

During development or for applications where crashing is simply preferable, you can also make every exception that gets thrown in a callback fatal by removing all of its subscribers.

WebSocket web service

The WebSocket protocol offers full bi-directional low-latency communication channels between clients and servers. Receive messages just by subscribing to events such as "message" in Mojo::Transaction::WebSocket with "on" in Mojolicious::Controller and return them with "send" in Mojolicious::Controller.

use Mojolicious::Lite;

# Template with browser-side code
get '/' => 'index';

# WebSocket echo service
websocket '/echo' => sub {
  my $c = shift;

  # Opened
  $c->app->log->debug('WebSocket opened');

  # Increase inactivity timeout for connection a bit
  $c->inactivity_timeout(300);

  # Incoming message
  $c->on(message => sub {
    my ($c, $msg) = @_;
    $c->send("echo: $msg");
  });

  # Closed
  $c->on(finish => sub {
    my ($c, $code, $reason) = @_;
    $c->app->log->debug("WebSocket closed with status $code");
  });
};

app->start;
__DATA__

@@ index.html.ep
<!DOCTYPE html>
<html>
  <head><title>Echo</title></head>
  <body>
    <script>
      var ws = new WebSocket('<%= url_for('echo')->to_abs %>');

      // Incoming messages
      ws.onmessage = function (event) {
        document.body.innerHTML += event.data + '<br/>';
      };

      // Outgoing messages
      ws.onopen = function (event) {
        window.setInterval(function () { ws.send('Hello Mojo!') }, 1000);
      };
    </script>
  </body>
</html>

The event "finish" in Mojo::Transaction::WebSocket will be emitted right after the WebSocket connection has been closed.

$c->tx->with_compression;

You can activate permessage-deflate compression with "with_compression" in Mojo::Transaction::WebSocket, this can result in much better performance, but also increases memory usage by up to 300KiB per connection.

my $proto = $c->tx->with_protocols('v2.proto', 'v1.proto');

You can also use "with_protocols" in Mojo::Transaction::WebSocket to negotiate a subprotocol.

EventSource web service

EventSource is a special form of long polling where you can use "write" in Mojolicious::Controller to directly send DOM events from servers to clients. It is uni-directional, that means you will have to use Ajax requests for sending data from clients to servers, the advantage however is low infrastructure requirements, since it reuses the HTTP protocol for transport.

use Mojolicious::Lite;

# Template with browser-side code
get '/' => 'index';

# EventSource for log messages
get '/events' => sub {
  my $c = shift;

  # Increase inactivity timeout for connection a bit
  $c->inactivity_timeout(300);

  # Change content type and finalize response headers
  $c->res->headers->content_type('text/event-stream');
  $c->write;

  # Subscribe to "message" event and forward "log" events to browser
  my $cb = $c->app->log->on(message => sub {
    my ($log, $level, @lines) = @_;
    $c->write("event:log\ndata: [$level] @lines\n\n");
  });

  # Unsubscribe from "message" event again once we are done
  $c->on(finish => sub {
    my $c = shift;
    $c->app->log->unsubscribe(message => $cb);
  });
};

app->start;
__DATA__

@@ index.html.ep
<!DOCTYPE html>
<html>
  <head><title>LiveLog</title></head>
  <body>
    <script>
      var events = new EventSource('<%= url_for 'events' %>');

      // Subscribe to "log" event
      events.addEventListener('log', function (event) {
        document.body.innerHTML += event.data + '<br/>';
      }, false);
    </script>
  </body>
</html>

The event "message" in Mojo::Log will be emitted for every new log message and the event "finish" in Mojo::Transaction right after the transaction has been finished.

Streaming multipart uploads

Mojolicious contains a very sophisticated event system based on Mojo::EventEmitter, with ready-to-use events on almost all layers, and which can be combined to solve some of the hardest problems in web development.

use Mojolicious::Lite;
use Scalar::Util 'weaken';

# Intercept multipart uploads and log each chunk received
hook after_build_tx => sub {
  my $tx = shift;

  # Subscribe to "upgrade" event to identify multipart uploads
  weaken $tx;
  $tx->req->content->on(upgrade => sub {
    my ($single, $multi) = @_;
    return unless $tx->req->url->path->contains('/upload');

    # Subscribe to "part" event to find the right one
    $multi->on(part => sub {
      my ($multi, $single) = @_;

      # Subscribe to "body" event of part to make sure we have all headers
      $single->on(body => sub {
        my $single = shift;

        # Make sure we have the right part and replace "read" event
        return unless $single->headers->content_disposition =~ /example/;
        $single->unsubscribe('read')->on(read => sub {
          my ($single, $bytes) = @_;

          # Log size of every chunk we receive
          app->log->debug(length($bytes) . ' bytes uploaded');
        });
      });
    });
  });
};

# Upload form in DATA section
get '/' => 'index';

# Streaming multipart upload
post '/upload' => {text => 'Upload was successful.'};

app->start;
__DATA__

@@ index.html.ep
<!DOCTYPE html>
<html>
  <head><title>Streaming multipart upload</title></head>
  <body>
    %= form_for upload => (enctype => 'multipart/form-data') => begin
      %= file_field 'example'
      %= submit_button 'Upload'
    % end
  </body>
</html>

More event loops

Internally, the Mojo::IOLoop event loop can use multiple reactor backends, EV for example, will be automatically used if possible. Which in turn allows other event loops like AnyEvent to just work.

use Mojolicious::Lite;
use EV;
use AnyEvent;

# Wait 3 seconds before rendering a response
get '/' => sub {
  my $c = shift;
  my $w;
  $w = AE::timer 3, 0, sub {
    $c->render(text => 'Delayed by 3 seconds!');
    undef $w;
  };
};

app->start;

Who actually controls the event loop backend is not important.

use Mojo::UserAgent;
use EV;
use AnyEvent;

# Search MetaCPAN for "mojolicious"
my $cv = AE::cv;
my $ua = Mojo::UserAgent->new;
$ua->get('fastapi.metacpan.org/v1/module/_search?q=mojolicious' => sub {
  my ($ua, $tx) = @_;
  $cv->send($tx->result->json('/hits/hits/0/_source/release'));
});
say $cv->recv;

You could, for example, just embed the built-in web server into an AnyEvent application.

use Mojolicious::Lite;
use Mojo::Server::Daemon;
use EV;
use AnyEvent;

# Normal action
get '/' => {text => 'Hello World!'};

# Connect application with web server and start accepting connections
my $daemon
  = Mojo::Server::Daemon->new(app => app, listen => ['http://*:8080']);
$daemon->start;

# Let AnyEvent take control
AE::cv->recv;

USER AGENT

When we say Mojolicious is a web framework we actually mean it, with Mojo::UserAgent there's a full featured HTTP and WebSocket user agent built right in.

REST web services

Requests can be performed very comfortably with methods like "get" in Mojo::UserAgent, and always result in a Mojo::Transaction::HTTP object, which has many useful attributes and methods. You can check for connection errors with "result" in Mojo::Transaction, or access HTTP request and response information directly through "req" in Mojo::Transaction and "res" in Mojo::Transaction.

use Mojo::UserAgent;

# Request a resource and make sure there were no connection errors
my $ua = Mojo::UserAgent->new;
my $tx = $ua->get('mojolicious.org/perldoc/Mojo' => {Accept => 'text/plain'});
my $res = $tx->result;

# Decide what to do with its representation
if    ($res->is_success)  { say $res->body }
elsif ($res->is_error)    { say $res->message }
elsif ($res->code == 301) { say $res->headers->location }
else                      { say 'Whatever...' }

While methods like "is_success" in Mojo::Message::Response and "is_error" in Mojo::Message::Response serve as building blocks for more sophisticated REST clients.

Web scraping

Scraping information from websites has never been this much fun before. The built-in HTML/XML parser Mojo::DOM is accessible through "dom" in Mojo::Message and supports all CSS selectors that make sense for a standalone parser, it can be a very powerful tool especially for testing web application.

use Mojo::UserAgent;

# Fetch website
my $ua = Mojo::UserAgent->new;
my $res = $ua->get('mojolicious.org/perldoc')->result;

# Extract title
say 'Title: ', $res->dom->at('head > title')->text;

# Extract headings
$res->dom('h1, h2, h3')->each(sub { say 'Heading: ', shift->all_text });

# Visit all nodes recursively to extract more than just text
for my $n ($res->dom->descendant_nodes->each) {

  # Text or CDATA node
  print $n->content if $n->type eq 'text' || $n->type eq 'cdata';

  # Also include alternate text for images
  print $n->{alt} if $n->type eq 'tag' && $n->tag eq 'img';
}

For a full list of available CSS selectors see "SELECTORS" in Mojo::DOM::CSS.

JSON web services

Most web services these days are based on the JSON data-interchange format. That's why Mojolicious comes with the possibly fastest pure-Perl implementation Mojo::JSON built right in, which is accessible through "json" in Mojo::Message.

use Mojo::UserAgent;
use Mojo::URL;

# Fresh user agent
my $ua = Mojo::UserAgent->new;

# Search MetaCPAN for "mojolicious" and list latest releases
my $url = Mojo::URL->new('http://fastapi.metacpan.org/v1/release/_search');
$url->query({q => 'mojolicious', sort => 'date:desc'});
for my $hit (@{$ua->get($url)->result->json->{hits}{hits}}) {
  say "$hit->{_source}{name} ($hit->{_source}{author})";
}

Basic authentication

You can just add username and password to the URL, an Authorization header will be automatically generated.

use Mojo::UserAgent;

my $ua = Mojo::UserAgent->new;
say $ua->get('https://sri:secret@example.com/hideout')->result->body;

Decorating follow-up requests

Mojo::UserAgent can automatically follow redirects, the event "start" in Mojo::UserAgent allows you direct access to each transaction right after they have been initialized and before a connection gets associated with them.

use Mojo::UserAgent;

# User agent following up to 10 redirects
my $ua = Mojo::UserAgent->new(max_redirects => 10);

# Add a witty header to every request
$ua->on(start => sub {
  my ($ua, $tx) = @_;
  $tx->req->headers->header('X-Bender' => 'Bite my shiny metal ass!');
  say 'Request: ', $tx->req->url->clone->to_abs;
});

# Request that will most likely get redirected
say 'Title: ', $ua->get('google.com')->result->dom->at('head > title')->text;

This even works for proxy CONNECT requests.

Content generators

Content generators can be registered with "add_generator" in Mojo::UserAgent::Transactor to generate the same type of content repeatedly for multiple requests.

use Mojo::UserAgent;
use Mojo::Asset::File;

# Add "stream" generator
my $ua = Mojo::UserAgent->new;
$ua->transactor->add_generator(stream => sub {
  my ($transactor, $tx, $path) = @_;
  $tx->req->content->asset(Mojo::Asset::File->new(path => $path));
});

# Send multiple files streaming via PUT and POST
$ua->put('http://example.com/upload'  => stream => '/home/sri/mojo.png');
$ua->post('http://example.com/upload' => stream => '/home/sri/minion.png');

The json, form and multipart content generators are always available.

use Mojo::UserAgent;

# Send "application/json" content via PATCH
my $ua = Mojo::UserAgent->new;
my $tx = $ua->patch('http://api.example.com' => json => {foo => 'bar'});

# Send query parameters via GET
my $tx2 = $ua->get('search.example.com' => form => {q => 'test'});

# Send "application/x-www-form-urlencoded" content via POST
my $tx3 = $ua->post('http://search.example.com' => form => {q => 'test'});

# Send "multipart/form-data" content via PUT
my $tx4 = $ua->put(
  'upload.example.com' => form => {test => {content => 'Hello World!'}});

# Send custom multipart content via PUT
my $tx5 = $ua->put('api.example.com' => multipart => ['Hello', 'World!']);

For more information about available content generators see also "tx" in Mojo::UserAgent::Transactor.

Large file downloads

When downloading large files with Mojo::UserAgent you don't have to worry about memory usage at all, because it will automatically stream everything above 250KiB into a temporary file, which can then be moved into a permanent file with "move_to" in Mojo::Asset::File.

use Mojo::UserAgent;

# Fetch the latest Mojolicious tarball
my $ua = Mojo::UserAgent->new(max_redirects => 5);
my $tx = $ua->get('https://www.github.com/kraih/mojo/tarball/master');
$tx->result->content->asset->move_to('mojo.tar.gz');

To protect you from excessively large files there is also a limit of 2GiB by default, which you can tweak with the attribute "max_response_size" in Mojo::UserAgent.

# Increase limit to 10GiB
$ua->max_response_size(10737418240);

Large file upload

Uploading a large file is even easier.

use Mojo::UserAgent;

# Upload file via POST and "multipart/form-data"
my $ua = Mojo::UserAgent->new;
$ua->post('example.com/upload' =>
  form => {image => {file => '/home/sri/hello.png'}});

And once again you don't have to worry about memory usage, all data will be streamed directly from the file.

Streaming response

Receiving a streaming response can be really tricky in most HTTP clients, but Mojo::UserAgent makes it actually easy.

use Mojo::UserAgent;

# Accept responses of indefinite size
my $ua = Mojo::UserAgent->new(max_response_size => 0);

# Build a normal transaction
my $tx = $ua->build_tx(GET => 'http://example.com');

# Replace "read" events to disable default content parser
$tx->res->content->unsubscribe('read')->on(read => sub {
  my ($content, $bytes) = @_;
  say "Streaming: $bytes";
});

# Process transaction
$tx = $ua->start($tx);

The event "read" in Mojo::Content will be emitted for every chunk of data that is received, even chunked transfer encoding and gzip content encoding will be handled transparently if necessary.

Streaming request

Sending a streaming request is almost just as easy.

use Mojo::UserAgent;

# Build a normal transaction
my $ua = Mojo::UserAgent->new;
my $tx = $ua->build_tx(GET => 'http://example.com');

# Prepare body
my $body = 'Hello World!';
$tx->req->headers->content_length(length $body);

# Start writing directly with a drain callback
my $drain;
$drain = sub {
  my $content = shift;
  my $chunk = substr $body, 0, 1, '';
  $drain = undef unless length $body;
  $content->write($chunk, $drain);
};
$tx->req->content->$drain;

# Process transaction
$tx = $ua->start($tx);

The drain callback passed to "write" in Mojo::Content will be executed whenever the entire previous chunk of data has actually been written.

Non-blocking

Mojo::UserAgent has been designed from the ground up to be non-blocking, the whole blocking API is just a simple convenience wrapper. Especially for high latency tasks like web crawling this can be extremely useful, because you can keep many concurrent connections active at the same time.

use Mojo::UserAgent;
use Mojo::IOLoop;

# Concurrent non-blocking requests
my $ua = Mojo::UserAgent->new;
$ua->get('https://metacpan.org/search?q=mojo' => sub {
  my ($ua, $mojo) = @_;
  say $mojo->result->dom->at('title')->text;
});
$ua->get('https://metacpan.org/search?q=minion' => sub {
  my ($ua, $minion) = @_;
  say $minion->result->dom->at('title')->text;
});

# Start event loop if necessary
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

But don't try to open too many connections to one server at the same time, it might get overwhelmed. Better use a queue to process requests in smaller batches.

use Mojo::UserAgent;
use Mojo::IOLoop;

my @urls = (
  'mojolicious.org/perldoc/Mojo/DOM',  'mojolicious.org/perldoc/Mojo',
  'mojolicious.org/perldoc/Mojo/File', 'mojolicious.org/perldoc/Mojo/URL'
);

# User agent with a custom name, following up to 5 redirects
my $ua = Mojo::UserAgent->new(max_redirects => 5);
$ua->transactor->name('MyParallelCrawler 1.0');

# Use a delay to keep the event loop running until we are done
my $delay = Mojo::IOLoop->delay;
my $fetch;
$fetch = sub {

  # Stop if there are no more URLs
  return unless my $url = shift @urls;

  # Fetch the next title
  my $end = $delay->begin;
  $ua->get($url => sub {
    my ($ua, $tx) = @_;
    say "$url: ", $tx->result->dom->at('title')->text;

    # Next request
    $fetch->();
    $end->();
  });
};

# Process two requests at a time
$fetch->() for 1 .. 2;
$delay->wait;

It is also strongly recommended to respect every sites robots.txt file as well as terms of service, and to wait a little before reopening connections to the same host, or the operators might be forced to block your access.

Concurrent blocking requests

You might have seen "wait" in Mojo::Promise already in some examples above. It is used to make non-blocking operations portable, allowing them to work inside an already running event loop or start one on demand.

use Mojo::UserAgent;
use Mojo::Promise;

# Synchronize non-blocking requests with promises
my $ua = Mojo::UserAgent->new;
my $mojo   = $ua->get_p('https://metacpan.org/search?q=mojo');
my $minion = $ua->get_p('https://metacpan.org/search?q=minion');
Mojo::Promise->all($mojo, $minion)->then(sub {
  my ($mojo, $minion) = @_;
  say $mojo->[0]->result->dom->at('title')->text;
  say $minion->[0]->result->dom->at('title')->text;
})->wait;

WebSockets

WebSockets are not just for the server-side, you can use "websocket_p" in Mojo::UserAgent to open new connections, which are always non-blocking. The WebSocket handshake uses HTTP, and is a normal GET request with a few additional headers. It can even contain cookies, and is followed by a 101 response from the server, notifying our user agent that the connection has been established and it can start using the bi-directional WebSocket protocol.

use Mojo::UserAgent;
use Mojo::Promise;

# Open WebSocket to echo service
my $ua = Mojo::UserAgent->new;
$ua->websocket_p('ws://echo.websocket.org')->then(sub {
  my $tx = shift;

  # Prepare a followup promise so we can wait for messages
  my $promise = Mojo::Promise->new;

  # Wait for WebSocket to be closed
  $tx->on(finish => sub {
    my ($tx, $code, $reason) = @_;
    say "WebSocket closed with status $code.";
    $promise->resolve;
  });

  # Close WebSocket after receiving one message
  $tx->on(message => sub {
    my ($tx, $msg) = @_;
    say "WebSocket message: $msg";
    $tx->finish;
  });

  # Send a message to the server
  $tx->send('Hi!');

  # Insert a new promise into the promise chain
  return $promise;
})->catch(sub {
  my $err = shift;

  # Handle failed WebSocket handshakes and other exceptions
  warn "WebSocket error: $err";
})->wait;

UNIX domain sockets

Not just TCP/IP sockets are supported, but also UNIX domain sockets, which can have significant security and performance benefits when used for inter-process communication. Instead of http:// and ws:// you can use the http+unix:// and ws+unix:// schemes, and pass along a percent encoded path (/ becomes %2F) instead of a hostname.

use Mojo::UserAgent;
use Mojo::Promise;

# GET request via UNIX domain socket "/tmp/foo.sock"
my $ua = Mojo::UserAgent->new;
say $ua->get('http+unix://%2Ftmp%2Ffoo.sock/index.html')->result->body;

# GET request with HOST header via UNIX domain socket "/tmp/bar.sock"
my $tx = $ua->get('http+unix://%2Ftmp%2Fbar.sock' => {Host => 'example.com'});
say $tx->result->body;

# WebSocket connection via UNIX domain socket "/tmp/baz.sock"
$ua->websocket_p('ws+unix://%2Ftmp%2Fbaz.sock/echo')->then(sub {
  my $tx = shift;

  my $promise = Mojo::Promise->new;
  $tx->on(finish => sub { $promise->resolve });

  $tx->on(message => sub {
    my ($tx, $msg) = @_;
    say "WebSocket message: $msg";
    $tx->finish;
  });
  $tx->send('Hi!');

  return $promise;
})->catch(sub {
  my $err = shift;
  warn "WebSocket error: $err";
})->wait;

You can set the Host header manually to pass along a hostname.

Command line

Don't you hate checking huge HTML files from the command line? Thanks to the command Mojolicious::Command::get that is about to change. You can just pick the parts that actually matter with the CSS selectors from Mojo::DOM and JSON Pointers from Mojo::JSON::Pointer.

$ mojo get http://mojolicious.org 'head > title'

How about a list of all id attributes?

$ mojo get http://mojolicious.org '*' attr id

Or the text content of all heading tags?

$ mojo get http://mojolicious.org 'h1, h2, h3' text

Maybe just the text of the third heading?

$ mojo get http://mojolicious.org 'h1, h2, h3' 3 text

You can also extract all text from nested child elements.

$ mojo get http://mojolicious.org '#mojobar' all

The request can be customized as well.

$ mojo get -M POST -H 'X-Bender: Bite my shiny metal ass!' http://google.com

Store response data by redirecting STDOUT.

$ mojo get mojolicious.org > example.html

Pass request data by redirecting STDIN.

$ mojo get -M PUT mojolicious.org < example.html

Or use the output of another program.

$ echo 'Hello World' | mojo get -M PUT http://mojolicious.org

Submit forms as application/x-www-form-urlencoded content.

$ mojo get -M POST -f 'q=Mojo' -f 'size=5' https://metacpan.org/search

And upload files as multipart/form-data content.

$ mojo get -M POST -f 'upload=@example.html' mojolicious.org

You can follow redirects and view the headers for all messages.

$ mojo get -r -v http://google.com 'head > title'

Extract just the information you really need from JSON data structures.

$ mojo get https://fastapi.metacpan.org/v1/author/SRI /name

This can be an invaluable tool for testing your applications.

$ ./myapp.pl get /welcome 'head > title'

One-liners

For quick hacks and especially testing, ojo one-liners are also a great choice.

$ perl -Mojo -E 'say g("mojolicious.org")->dom->at("title")->text'

APPLICATIONS

Fun Mojolicious application hacks for all occasions.

Basic authentication

Basic authentication data will be automatically extracted from the Authorization header.

use Mojolicious::Lite;
use Mojo::Util 'secure_compare';

get '/' => sub {
  my $c = shift;

  # Check for username "Bender" and password "rocks"
  return $c->render(text => 'Hello Bender!')
    if secure_compare $c->req->url->to_abs->userinfo, 'Bender:rocks';

  # Require authentication
  $c->res->headers->www_authenticate('Basic');
  $c->render(text => 'Authentication required!', status => 401);
};

app->start;

This can be combined with TLS for a secure authentication mechanism.

$ ./myapp.pl daemon -l 'https://*:3000?cert=./server.crt&key=./server.key'

Adding a configuration file

Adding a configuration file to your application is as easy as adding a file to its home directory and loading the plugin Mojolicious::Plugin::Config. The default name is based on the value of "moniker" in Mojolicious (myapp), appended with a .conf extension (myapp.conf).

$ mkdir myapp
$ cd myapp
$ touch myapp.pl
$ chmod 744 myapp.pl
$ echo '{name => "my Mojolicious application"};' > myapp.conf

Configuration files themselves are just Perl scripts that return a hash reference with configuration settings of your choice. All those settings are then available through the method "config" in Mojolicious and the helper "config" in Mojolicious::Plugin::DefaultHelpers.

use Mojolicious::Lite;

plugin 'Config';

my $name = app->config('name');
app->log->debug("Welcome to $name");

get '/' => 'with_config';

app->start;
__DATA__
@@ with_config.html.ep
<!DOCTYPE html>
<html>
  <head><title><%= config 'name' %></title></head>
  <body>Welcome to <%= config 'name' %></body>
</html>

Alternatively you can also use configuration files in the JSON format with Mojolicious::Plugin::JSONConfig.

Adding a plugin to your application

To organize your code better and to prevent helpers from cluttering your application, you can use application specific plugins.

$ mkdir -p lib/MyApp/Plugin
$ touch lib/MyApp/Plugin/MyHelpers.pm

They work just like normal plugins and are also subclasses of Mojolicious::Plugin. Nested helpers with a prefix based on the plugin name are an easy way to avoid conflicts.

package MyApp::Plugin::MyHelpers;
use Mojo::Base 'Mojolicious::Plugin';

sub register {
  my ($self, $app) = @_;
  $app->helper('my_helpers.render_with_header' => sub {
    my ($c, @args) = @_;
    $c->res->headers->header('X-Mojo' => 'I <3 Mojolicious!');
    $c->render(@args);
  });
}

1;

You can have as many application specific plugins as you like, the only difference to normal plugins is that you load them using their full class name.

use Mojolicious::Lite;

use lib 'lib';

plugin 'MyApp::Plugin::MyHelpers';

get '/' => sub {
  my $c = shift;
  $c->my_helpers->render_with_header(text => 'I ♥ Mojolicious!');
};

app->start;

Of course these plugins can contain more than just helpers, take a look at "PLUGINS" in Mojolicious::Plugins for a few ideas.

Adding commands to Mojolicious

By now you've probably used many of the built-in commands described in Mojolicious::Commands, but did you know that you can just add new ones and that they will be picked up automatically by the command line interface if they are placed in a directory from @INC?

package Mojolicious::Command::spy;
use Mojo::Base 'Mojolicious::Command';

has description => 'Spy on application';
has usage       => "Usage: APPLICATION spy [TARGET]\n";

sub run {
  my ($self, @args) = @_;

  # Leak secret passphrases
  if ($args[0] eq 'secrets') { say for @{$self->app->secrets} }

  # Leak mode
  elsif ($args[0] eq 'mode') { say $self->app->mode }
}

1;

Command line arguments are passed right through and there are many useful attributes and methods in Mojolicious::Command that you can use or overload.

$ mojo spy secrets
HelloWorld

$ ./script/myapp spy secrets
secr3t

And to make your commands application specific, just add a custom namespace to "namespaces" in Mojolicious::Commands and use a class name like MyApp::Command::spy instead of Mojolicious::Command::spy.

# Application
package MyApp;
use Mojo::Base 'Mojolicious';

sub startup {
  my $self = shift;

  # Add another namespace to load commands from
  push @{$self->commands->namespaces}, 'MyApp::Command';
}

1;

The options -h/--help, --home and -m/--mode are handled automatically by Mojolicious::Commands and are shared by all commands.

$ ./script/myapp spy -m production mode
production

For a full list of shared options see "SYNOPSIS" in Mojolicious::Commands.

Running code against your application

Ever thought about running a quick one-liner against your Mojolicious application to test something? Thanks to the command Mojolicious::Command::eval you can do just that, the application object itself can be accessed via app.

$ mojo generate lite_app myapp.pl
$ ./myapp.pl eval 'say for @{app->static->paths}'
$ ./myapp.pl eval 'say for sort keys %{app->renderer->helpers}'

The verbose options will automatically print the return value or returned data structure to STDOUT.

$ ./myapp.pl eval -v 'app->static->paths->[0]'
$ ./myapp.pl eval -V 'app->static->paths'

Making your application installable

Ever thought about releasing your Mojolicious application to CPAN? It's actually much easier than you might think.

$ mojo generate app MyApp
$ cd my_app
$ mv public lib/MyApp/
$ mv templates lib/MyApp/

The trick is to move the public and templates directories so they can get automatically installed with the modules.

# Application
package MyApp;
use Mojo::Base 'Mojolicious';

use Mojo::File 'path';
use Mojo::Home;

# Every CPAN module needs a version
our $VERSION = '1.0';

sub startup {
  my $self = shift;

  # Switch to installable home directory
  $self->home(Mojo::Home->new(path(__FILE__)->sibling('MyApp')));

  # Switch to installable "public" directory
  $self->static->paths->[0] = $self->home->child('public');

  # Switch to installable "templates" directory
  $self->renderer->paths->[0] = $self->home->child('templates');

  $self->plugin('PODRenderer');

  my $r = $self->routes;
  $r->get('/welcome')->to('example#welcome');
}

1;

Finally there is just one small change to be made to the application script. The shebang line becomes the recommended #!perl, which the toolchain can rewrite to the proper shebang during installation.

#!perl

use strict;
use warnings;

use FindBin;
BEGIN { unshift @INC, "$FindBin::Bin/../lib" }
use Mojolicious::Commands;

# Start command line interface for application
Mojolicious::Commands->start_app('MyApp');

That's really everything, now you can package your application like any other CPAN module.

$ ./script/my_app generate makefile
$ perl Makefile.PL
$ make test
$ make manifest
$ make dist

And if you have a PAUSE account (which can be requested at http://pause.perl.org) even upload it.

$ mojo cpanify -u USER -p PASS MyApp-0.01.tar.gz

Hello World

If every byte matters this is the smallest Hello World application you can write with Mojolicious::Lite.

use Mojolicious::Lite;
any {text => 'Hello World!'};
app->start;

It works because all routes without a pattern default to / and automatic rendering kicks in even if no actual code gets executed by the router. The renderer just picks up the text value from the stash and generates a response.

Hello World one-liners

The Hello World example above can get even a little bit shorter in an ojo one-liner.

$ perl -Mojo -E 'a({text => "Hello World!"})->start' daemon

And you can use all the commands from Mojolicious::Commands.

$ perl -Mojo -E 'a({text => "Hello World!"})->start' get -v /

You can continue with Mojolicious::Guides now or take a look at the Mojolicious wiki, which contains a lot more documentation and examples by many different authors.

SUPPORT

If you have any questions the documentation might not yet answer, don't hesitate to ask on the mailing list or the official IRC channel #mojo on irc.perl.org (chat now!).

To install Mojolicious, copy and paste the appropriate command in to your terminal.

cpanm

cpanm Mojolicious

CPAN shell

perl -MCPAN -e shell
install Mojolicious

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

OVERVIEW

CONCEPTS

Blocking and non-blocking operations

Event loops

Reverse proxy

DEPLOYMENT

Built-in web server

Pre-forking

Morbo

Hypnotoad

Zero downtime software upgrades

Nginx

Apache/mod_proxy

Apache/CGI

PSGI/Plack

Plack middleware

Rewriting

Application embedding

Web server embedding

REAL-TIME WEB

Backend web services

Synchronizing non-blocking operations

Timers

Subprocesses

Exceptions in non-blocking operations

WebSocket web service

EventSource web service

Streaming multipart uploads

More event loops

USER AGENT

REST web services

Web scraping

JSON web services

Basic authentication

Decorating follow-up requests

Content generators

Large file downloads

Large file upload

Streaming response

Streaming request

Non-blocking

Concurrent blocking requests

WebSockets

UNIX domain sockets

Command line

One-liners

APPLICATIONS

Basic authentication

Adding a configuration file

Adding a plugin to your application

Adding commands to Mojolicious

Running code against your application

Making your application installable

Hello World

Hello World one-liners

MORE

SUPPORT

Module Install Instructions