From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

KENTNL / Dist-Zilla-Plugin-Git-Remote-Check-0.1.2 / lib / Dist / Zilla / Role / Git / Remote.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
—
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144

              
use strict;
use warnings;
package Dist::Zilla::Role::Git::Remote;
BEGIN {
  $Dist::Zilla::Role::Git::Remote::AUTHORITY = 'cpan:KENTNL';
}
{
  $Dist::Zilla::Role::Git::Remote::VERSION = '0.1.2';
}
# FILENAME: Remote.pm
# CREATED: 12/10/11 17:12:13 by Kent Fredric (kentnl) <kentfredric@gmail.com>
# ABSTRACT: Git Remote specification and validation for plugins.
use Moose::Role;
requires 'git';
requires 'log_fatal';
sub remote {
  my ($self) = @_;
  $self->_assert_valid_remote;
  return $self->_remote_name;
}
has '_remote_name' => (
  isa      => 'Str',
  is       => 'rw',
  default  => 'origin',
  init_arg => 'remote_name',
);
has '_remotes' => (
  isa        => 'ArrayRef[ Str ]',
  is         => 'rw',
  lazy_build => 1,
  traits     => [qw( Array )],
  handles    => { _has_remote => 'first' },
  init_arg   => undef,
);
sub _build__remotes {
  my $self = shift;
  return [ $self->git->remote ];
}
sub _remote_valid {
  my $self = shift;
  return $self->_has_remote( sub { $_ eq $self->_remote_name } );
}
sub _assert_valid_remote {
  my $self = shift;
  return if $self->_remote_valid;
  require Data::Dump;
  my $msg = qq[Git reports remote name '%s' does not exist.\n Remotes: %s];
  return $self->log_fatal( [ $msg, $self->_remote_name, Data::Dump::dump( $self->_remotes ), ] );
}
no Moose::Role;
1;
__END__
=pod
=head1 NAME
Dist::Zilla::Role::Git::Remote - Git Remote specification and validation for plugins.
=head1 VERSION
version 0.1.2
=head1 PARAMETERS
=head2 C<remote_name>
String.
The name of the C<git remote> you want to refer to.
Defaults to C<origin>
=head1 METHODS
=head2 C<remote>
If a consuming package specifies a valid value via C<remote_name>, 
this method will validate the existence of that remote in the current Git repository.
If specified remote does not exist, a fatal log event is triggered.
=head1 REQUIRED METHODS
=head2 C<git>
Must return a L<Git::Wrapper> or compatible instance.
Available from:
=over 4
=item * L<Dist::Zilla::Role::Git::LocalRepository>
=back
=head2 C<log_fatal>
Expected to take parameters as follows:
  ->log_fatal( [ 'FormatString %s' , $formatargs ] )
Expected to halt execution ( throw an exception ) when called.
Available from:
=over 4
=item * L<Dist::Zilla::Role::Plugin>
=back
=head1 AUTHOR
Kent Fredric <kentnl@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2012 by Kent Fredric <kentnl@cpan.org>.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut