The Perl Toolchain Summit 2025 Needs You: You can help 🙏 Learn more

LIOSHA / Geo-Openstreetmap-Parser-0.03 / lib / Geo / Openstreetmap / Parser.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
—
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117

              
use 5.010;
use strict;
use warnings;
package Geo::Openstreetmap::Parser;
$Geo::Openstreetmap::Parser::VERSION = '0.03';
# ABSTRACT: Openstreetmap XML dump parser
use autodie;
use XML::Parser;
sub new
{
    my ($class, %callback) = @_;
     
    my $self = bless { callback => \%callback }, $class;
    $self->_init_parser();
    return $self;
}
sub parse
{
    my ($self, $fh) = @_;
    $self->{parser}->parse($fh);
    return;
}
sub _init_parser
{
    my ($self) = @_;
    my @path;
    $self->{parser} = XML::Parser->new( Handlers => {
            Start => sub {
                    my ($expat, $el, %attr) = @_;
                    push @path, { attr => \%attr };
                },
            End => sub {
                    my ($expat, $el) = @_;
                    my $obj = pop @path;
                    if ($el eq 'tag')    { $path[-1]->{$el}->{$obj->{attr}->{k}} = $obj->{attr}->{v} }
                    if ($el eq 'nd')     { push @{$path[-1]->{$el}}, $obj->{attr}->{ref} }
                    if ($el eq 'member') { push @{$path[-1]->{$el}}, $obj->{attr} }
                    if (my $cb = $self->{callback}->{$el})    { $cb->($obj) }
                },
        });
    return;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Geo::Openstreetmap::Parser - Openstreetmap XML dump parser
=head1 VERSION
version 0.03
=head1 METHODS
=head2 new
Creates a parser object
    my $parser = Geo::Openstreetmap::Parser->new( node => \&process_node, ... );
    sub process_node {
        my ($obj) = @_;
        ...
    }
Callbacks are possible for any tag, but useful for osm primitives:
    node
    way
    relation
Callback function receives hash with params:
    attr    - hash with xml attributes
    tag     - hash with osm tags
    nd      - array of node_ids (for ways)
    member  - array of hashes like { type => 'way', role => 'from', ref => '-1' } (for relations)
=head2 parse
Parses XML input, executing defined callback functions for OSM objects
    $parser->parse( *STDIN );
=head1 AUTHOR
liosha <liosha@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2015 by liosha.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut