The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

SSIMMS / PDF-API2-2.047 / lib / PDF / API2 / Resource / XObject / Image.pm 

            

              
1
2
3
4
5
6
7
8
9
10
—
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
—
34
35
36
37
38
39
40
41
42
43
44
45
—
46
47
48
49
50
51
52
53
54
55
56
57
—
58
59
60
61
62
63
64
65
66
67
68
69
70
—
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
—
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
—
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
—
140
141
142
143
144
145

              
package PDF::API2::Resource::XObject::Image;
use base 'PDF::API2::Resource::XObject';
use strict;
use warnings;
our $VERSION = '2.047'; # VERSION
use PDF::API2::Basic::PDF::Utils;
=head1 NAME
PDF::API2::Resource::XObject::Image - Base class for external raster image objects
=head1 METHODS
=over
=item $image = PDF::API2::Resource::XObject::Image->new($pdf, $name)
Returns an image resource object.
=cut
sub new {
    my ($class, $pdf, $name) = @_;
    my $self = $class->SUPER::new($pdf, $name);
    $self->subtype('Image');
    return $self;
}
=item $width = $image->width($width)
Get or set the width value for the image object.
=cut
sub width {
    my $self = shift();
    $self->{'Width'} = PDFNum(shift()) if scalar @_;
    return $self->{'Width'}->val();
}
=item $height = $image->height($height)
Get or set the height value for the image object.
=cut
sub height {
    my $self = shift();
    $self->{'Height'} = PDFNum(shift()) if scalar @_;
    return $self->{'Height'}->val();
}
=item $image->smask($xobject)
Set the soft-mask image object.
=cut
sub smask {
    my $self = shift();
    $self->{'SMask'} = shift();
    return $self;
}
=item $image->mask(@color_range)
=item $image->mask($xobject)
Set the mask to an image mask XObject or an array containing a range
of colors to be applied as a color key mask.
=cut
sub mask {
    my $self = shift();
    if (ref($_[0])) {
        $self->{'Mask'} = shift();
    }
    else {
        $self->{'Mask'} = PDFArray(map { PDFNum($_) } @_);
    }
    return $self;
}
# Deprecated (rolled into mask)
sub imask { return mask(@_); }
=item $image->colorspace($name)
=item $image->colorspace($array)
Set the color space used by the image.  Depending on the color space,
this will either be just the name of the color space, or it will be an
array containing the color space and any required parameters.
If passing an array, parameters must already be encoded as PDF
objects.  The array itself may also be a PDF object.  If not, one will
be created.
=cut
sub colorspace {
    my ($self, @values) = @_;
    if (scalar @values == 1 and ref($values[0])) {
        $self->{'ColorSpace'} = $values[0];
    }
    elsif (scalar @values == 1) {
        $self->{'ColorSpace'} = PDFName($values[0]);
    }
    else {
        $self->{'ColorSpace'} = PDFArray(@values);
    }
    return $self;
}
=item $image->bits_per_component($integer)
Set the number of bits used to represent each color component.
=cut
sub bits_per_component {
    my $self = shift();
    $self->{'BitsPerComponent'} = PDFNum(shift());
    return $self;
}
# Deprecated (renamed)
sub bpc { return bits_per_component(@_); }
=back
=cut
1;