From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

THALJEF / Pinto-0.14 / lib / Pinto / Action / Update.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
—
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203

              
# ABSTRACT: Update packages to latest versions
package Pinto::Action::Update;
use Moose;
use MooseX::StrictConstructor;
use MooseX::Types::Moose qw(Bool);
use MooseX::MarkAsMethods ( autoclean => 1 );
use Try::Tiny;
use Pinto::Util qw(throw);
use Pinto::Types qw(PackageTargetList);
use Pinto::Target::Package;
#------------------------------------------------------------------------------
our $VERSION = '0.14'; # VERSION
#------------------------------------------------------------------------------
extends qw( Pinto::Action );
#------------------------------------------------------------------------------
has targets => (
    isa      => PackageTargetList,
    traits   => [qw(Array)],
    handles  => { targets => 'elements' },
    default  => sub { [] },
    coerce   => 1,
);
has all => (
    is      => 'ro',
    isa     => Bool,
    default => 0,
);
has roots => (
    is      => 'ro',
    isa     => Bool,
    default => 0,
);
has no_fail => (
    is      => 'ro',
    isa     => Bool,
    default => 0,
);
#------------------------------------------------------------------------------
with qw( Pinto::Role::Committable Pinto::Role::Puller );
#------------------------------------------------------------------------------
sub execute {
    my ($self) = @_;
    my $stack   = $self->stack;
    my @targets = $self->compute_targets;
    for my $target ( @targets ) {
        if ($target->version) {
            $self->warning("Ignoring version specification on target $target");
            $target = $target->unversioned;
        }
        try {
            $self->repo->svp_begin;
            my ($dist, $did_update, $did_update_prereqs) = $self->update($target);
            push @{$self->affected}, $dist if $did_update;
        }
        catch {
            throw $_ unless $self->no_fail;
            $self->result->failed( because => $_ );
            $self->repo->svp_rollback;
            $self->error($_);
            $self->error("Target $target failed...continuing anyway");
        }
        finally {
            my ($error) = @_;
            $self->repo->svp_release unless $error;
        };
    }
    $self->chrome->progress_done;
    return $self;
}
#------------------------------------------------------------------------------
sub compute_targets {
    my ($self) = @_;
    my $stack = $self->stack;
    return map {$_->main_module->as_target->unversioned} $stack->distributions
        if $self->all;
    return map {$_->main_module->as_target->unversioned} $stack->roots
        if $self->roots;
    return $self->targets
        if $self->targets;
    throw "No targets specified";
}
#------------------------------------------------------------------------------
# TODO: Should we only update packages from foreign dists?
# TODO: Skip pinned targets unless --force
# TODO: Should pins be preserved?
sub update {
    my ($self, $target) = @_;
    my $pkg_name = $target->name;
    my $stack    = $self->stack;
    throw ("Package $pkg_name is not on stack $stack")
        unless my $reg = $stack->head->registrations->find({package_name => $pkg_name});
    my $current_dist = $reg->distribution;
    my $current_pkg  = $reg->package;
    if ($reg->is_pinned && not $self->force) {
        $self->notice("Skipping package $pkg_name because it is pinned to $current_dist");
        return ($current_dist, 0, 0);
    }
    if ($current_dist->is_local && !$self->all) {
        $self->notice("Skipping local package $pkg_name");
        return ($current_dist, 0, 0);
    }
    # Now go look for a newer version...
    my $latest_pkg = $self->repo->locate(target => $target);
    if (!$latest_pkg and !$current_dist->is_local) {
        $self->warning("No upstream version of $pkg_name was found");
        return ($current_dist, 0, 0);
    }
    my $latest_pkg_version = $latest_pkg->{version};
    my $current_pkg_version = $current_pkg->version;
    if ($latest_pkg_version <= $current_pkg_version) {
        $self->notice( "Package $pkg_name~$current_pkg_version is up to date");
        return ($current_dist, 0, 0);
    }
    # Finally, we update...
    $self->notice("Updating $pkg_name to $latest_pkg_version on stack $stack");
    my %target_args = (name => $pkg_name, version => $latest_pkg_version);
    my $new_target = Pinto::Target::Package->new(%target_args);
    return $self->pull(target => $new_target);
}
#------------------------------------------------------------------------------
__PACKAGE__->meta->make_immutable;
#------------------------------------------------------------------------------
1;
__END__
=pod
=encoding UTF-8
=for :stopwords Jeffrey Ryan Thalhammer
=head1 NAME
Pinto::Action::Update - Update packages to latest versions
=head1 VERSION
version 0.14
=head1 AUTHOR
Jeffrey Ryan Thalhammer <jeff@stratopan.com>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2015 by Jeffrey Ryan Thalhammer.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut