From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

FERKI / Rex-1.16.0 / lib / Rex / Group / Lookup / XML.pm 

            

              
1
2
3
—
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
—
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129

              
#
# (c) Nathan Abu <aloha2004@gmail.com>
#
=head1 NAME
Rex::Group::Lookup::XML - read hostnames and groups from a XML file
=head1 DESCRIPTION
With this module you can define hostgroups out of an xml file.
=head1 SYNOPSIS
 use Rex::Group::Lookup::XML;
 groups_xml "file.xml";
=head1 EXPORTED FUNCTIONS
=cut
package Rex::Group::Lookup::XML;
use v5.12.5;
use warnings;
use Rex -base;
our $VERSION = '1.16.0'; # VERSION
require Exporter;
use base qw(Exporter);
use vars qw(@EXPORT);
XML::LibXML->require;
@EXPORT = qw(groups_xml);
=head2 groups_xml($file)
With this function you can read groups from xml files.
File example:
 <configuration>
   <group name="database">
       <server name="machine01" user="root" password="foob4r" sudo="true" hdd="300" loc="/opt" />
   </group>
   <group name="application">
       <server name="machine01" user="root" password="foob4r" sudo="true" hdd="50" loc="/export" />
       <server name="machine02" user="root" password="foob5r" sudo="true"/>
   </group>
   <group name="profiler">
       <server name="machine03" user="root" password="blue123"/>
   </group>
 </configuration>
The XML file is validated against the DTD schema stored in C<Rex::Group::Lookup::XML::$schema_file> as string.
=cut
=head2 $schema_file
A variable that contains the XSD schema for which the XML is validated against.
=cut
our $schema_file = <<"XSD";
<xsd:schema attributeFormDefault="unqualified" elementFormDefault="qualified" version="1.0" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <xsd:element name="configuration">
        <xsd:complexType>
            <xsd:sequence>
                <xsd:element minOccurs="1" maxOccurs="unbounded" name="group">
                    <xsd:complexType>
                        <xsd:sequence>
                            <xsd:element name="server" minOccurs="1" maxOccurs="unbounded">
                                <xsd:complexType>
                                    <xsd:attribute name="name" use="required" type="xsd:string" />
                                    <xsd:anyAttribute processContents="lax"/>
                                </xsd:complexType>
                            </xsd:element>
                        </xsd:sequence>
                        <xsd:attribute use="required" name="name" type="xsd:string" />
                    </xsd:complexType>
                </xsd:element>
            </xsd:sequence>
        </xsd:complexType>
    </xsd:element>
</xsd:schema>
XSD
sub xml_validate {
  my $xmldoc = shift;
  my $schema = XML::LibXML::Schema->new( string => $schema_file );
  eval { $schema->validate($xmldoc); 1 }
    or die "Could not validate XML file against the XSD schema: $@";
}
sub groups_xml {
  my $file   = shift;
  my $parser = XML::LibXML->new();
  my $xmldoc = $parser->parse_file($file);
  my %groups;
  xml_validate($xmldoc);
  foreach my $server_node ( $xmldoc->findnodes('/configuration/group/server') )
  {
    my ($group) =
      map { $_->getValue() }
      grep { $_->nodeName eq 'name' } $server_node->parentNode->attributes();
    my %atts =
      map { $_->nodeName => $_->getValue() } $server_node->attributes();
    push(
      @{ $groups{$group} },
      Rex::Group::Entry::Server->new( name => delete( $atts{name} ), %atts )
    );
  }
  group( $_ => @{ $groups{$_} } ) foreach ( keys(%groups) );
}
1;