The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

DROLSKY / Specio-0.50 / lib / Specio / Exception.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
—
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160

              
package Specio::Exception;
use strict;
use warnings;
use overload
    q{""}    => 'as_string',
    fallback => 1;
our $VERSION = '0.50';
use Devel::StackTrace;
use Scalar::Util qw( blessed );
use Specio::OO;
{
    my $attrs = {
        message => {
            isa      => 'Str',
            required => 1,
        },
        type => {
            does     => 'Specio::Constraint::Role::Interface',
            required => 1,
        },
        value => {
            required => 1,
        },
        stack_trace => {
            init_arg => undef,
        },
    };
    ## no critic (Subroutines::ProhibitUnusedPrivateSubroutines)
    sub _attrs {
        return $attrs;
    }
}
sub BUILD {
    my $self = shift;
    $self->{stack_trace}
        = Devel::StackTrace->new( ignore_package => __PACKAGE__ );
    return;
}
sub as_string {
    my $self = shift;
    my $str = $self->message;
    $str .= "\n\n" . $self->stack_trace->as_string;
    return $str;
}
sub throw {
    my $self = shift;
    die $self if blessed $self;
    die $self->new(@_);
}
__PACKAGE__->_ooify;
1;
# ABSTRACT: An exception class for type constraint failures
__END__
=pod
=encoding UTF-8
=head1 NAME
Specio::Exception - An exception class for type constraint failures
=head1 VERSION
version 0.50
=head1 SYNOPSIS
  use Try::Tiny;
  try {
      $type->validate_or_die($value);
  }
  catch {
      if ( $_->isa('Specio::Exception') ) {
          print $_->message, "\n";
          print $_->type->name, "\n";
          print $_->value, "\n";
      }
  };
=head1 DESCRIPTION
This exception class is thrown by Specio when a type check fails. It emulates
the L<Throwable::Error> API, but doesn't use that module to avoid adding a
dependency on L<Moo>.
=for Pod::Coverage BUILD throw
=head1 API
This class provides the following methods:
=head2 $exception->message
The error message associated with the exception.
=head2 $exception->stack_trace
A L<Devel::StackTrace> object for the exception.
=head2 $exception->type
The type constraint object against which the value failed.
=head2 $exception->value
The value that failed the type check.
=head2 $exception->as_string
The exception as a string. This includes the method and the stack trace.
=head1 OVERLOADING
This class overloads stringification to call the C<as_string> method.
=head1 SUPPORT
Bugs may be submitted at L<https://github.com/houseabsolute/Specio/issues>.
=head1 SOURCE
The source code repository for Specio can be found at L<https://github.com/houseabsolute/Specio>.
=head1 AUTHOR
Dave Rolsky <autarch@urth.org>
=head1 COPYRIGHT AND LICENSE
This software is Copyright (c) 2012 - 2025 by Dave Rolsky.
This is free software, licensed under:
  The Artistic License 2.0 (GPL Compatible)
The full text of the license can be found in the
F<LICENSE> file included with this distribution.
=cut