/ 
Crypt-Sodium-XS-0.000039
River stage zero No dependents
/ Crypt::Sodium::XS::OO::secretbox

NAME

Crypt::Sodium::XS::OO::secretbox - Secret key authenticated encryption

SYNOPSIS

use Crypt::Sodium::XS::OO::secretbox;
my $sbox = Crypt::Sodium::XS::OO::secretbox->new;
# or use the shortcut
# use Crypt::Sodium::XS;
# my $sbox = Crypt::Sodium::XS->secretbox;
use Crypt::Sodium::XS::Util "sodium_increment";

my $sk = $sbox->keygen;
my $nonce = $sbox->nonce;

my $ct = $sbox->encrypt("hello", $nonce, $sk);
my $pt = $sbox->decrypt($ct, $nonce, $sk);
# $pt is now "hello" (MemVault)

$nonce = sodium_increment($nonce);
($ct, my $tag) = $sbox->encrypt_detached("world", $nonce, $sk);
$pt = $sbox->decrypt_detached($ct, $tag, $nonce, $sk);
# $pt is now "world" (MemVault)

DESCRIPTION

Encrypts a message with a key and a nonce to keep it confidential.

Computes an authentication tag. This tag is used to make sure that the message hasn't been tampered with before decrypting it.

A single key is used both to encrypt/authenticate and verify/decrypt messages. For this reason, it is critical to keep the key confidential.

The nonce doesn't have to be confidential, but it should never ever be reused with the same key. The easiest way to generate a nonce is to use "nonce".

Messages encrypted are assumed to be independent. If multiple messages are sent using this API and random nonces, there will be no way to detect if a message has been received twice, or if messages have been reordered. If this is a requirement, see Crypt::Sodium::XS::secretstream.

CONSTRUCTOR

new

my $sbox = Crypt::Sodium::XS::OO::secretbox->new;
my $sbox
  = Crypt::Sodium::XS::OO::secretbox->new(primitive => 'xsalsa20poly1305');
my $sbox = Crypt::Sodium::XS->secretbox;

Returns a new secretbox object for the given primitive. If not given, the default primitive is default.

ATTRIBUTES

primitive

my $primitive = $sbox->primitive;
$sbox->primitive('poly1305');

Gets or sets the primitive used for all operations by this object. Note this can be default.

METHODS

primitives

my @primitives = Crypt::Sodium::XS::OO::secretbox->primitives;
my @primitives = $sbox->primitives;

Returns a list of all supported primitive names, including default.

Can be called as a class method.

PRIMITIVE

my $primitive = $sbox->PRIMITIVE;

Returns the primitive used for all operations by this object. Note this will never be default but would instead be the primitive it represents.

decrypt

my $plaintext = $sbox->decrypt($ciphertext, $nonce, $key, $flags);

Croaks on decryption failure.

$ciphertext is the combined ciphertext to decrypt.

$nonce is the nonce used to encrypt the ciphertext. It must be "NONCEBYTES" bytes.

$key is the secret key used to encrypt the ciphertext. It must be "KEYBYTES" bytes. It may be a Crypt::Sodium::XS::MemVault.

$flags is optional. It is the flags used for the $plaintext Crypt::Sodium::XS::MemVault. See Crypt::Sodium::XS::Protmem.

Returns a Crypt::Sodium::XS::MemVault: the decrypted plaintext.

decrypt_detached

my $plaintext
  = $sbox->decrypt_detached($ciphertext, $tag, $nonce, $key, $flags);

Croaks on decryption failure.

$ciphertext is the detached ciphertext to decrypt.

$tag is the ciphertext's authentication tag. It must be "MACBYTES" bytes.

$nonce is the nonce used to encrypt the ciphertext. It must be "NONCEBYTES" bytes.

$key is the secret key used to encrypt the ciphertext. It must be "KEYBYTES" bytes. It may be a Crypt::Sodium::XS::MemVault.

$flags is optional. It is the flags used for the $plaintext Crypt::Sodium::XS::MemVault. See Crypt::Sodium::XS::Protmem.

Returns a Crypt::Sodium::XS::MemVault: the decrypted plaintext.

encrypt

my $ciphertext = $sbox->encrypt($message, $nonce, $key);

$message is the message to encrypt. It may be a Crypt::Sodium::XS::MemVault.

$nonce is the nonce used to encrypt the ciphertext. It must be "NONCEBYTES" bytes.

$key is the secret key used to encrypt the ciphertext. It must be "KEYBYTES" bytes. It may be a Crypt::Sodium::XS::MemVault.

Returns the encrypted ciphertext.

encrypt_detached

my ($ciphertext, $tag) = $sbox->encrypt($message, $nonce, $key);

$message is the message to encrypt. It may be a Crypt::Sodium::XS::MemVault.

$nonce is the nonce used to encrypt the ciphertext. It must be "NONCEBYTES" bytes.

$key is the secret key used to encrypt the ciphertext. It must be "KEYBYTES" bytes. It may be a Crypt::Sodium::XS::MemVault.

Returns the encrypted ciphertext and its authentication tag.

keygen

my $key = $sbox->keygen($flags);

$flags is optional. It is the flags used for the $key Crypt::Sodium::XS::MemVault. See Crypt::Sodium::XS::Protmem.

Returns a Crypt::Sodium::XS::MemVault: a secret key of "KEYBYTES" bytes.

nonce

my $nonce = $sbox->nonce;
my $nonce = $sbox->nonce($base);

$base is optional. It must be less than or equal to "NONCEBYTES" bytes. If not provided, the nonce will be random.

Returns a nonce of "NONCEBYTES" bytes.

NONCEBYTES

my $nonce_size = $sbox->NONCEBYTES;

Returns the size, in bytes, of a nonce.

KEYBYTES

my $key_size = $sbox->KEYBYTES;

Returns the size, in bytes, of a secret key.

MACBYTES

my $tag_size = $sbox->MACBYTES;

Returns the size, in bytes, of an authentication tag.

SEE ALSO

Crypt::Sodium::XS
Crypt::Sodium::XS::secretbox
https://doc.libsodium.org/secret-key_cryptography/secretbox

FEEDBACK

For reporting bugs, giving feedback, submitting patches, etc. please use the following:

For any security sensitive reports, please email the author directly or contact privately via IRC.

AUTHOR

Brad Barden <perlmodules@5c30.org>

COPYRIGHT & LICENSE

Copyright (c) 2022 Brad Barden. All rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.