/ 
Minion-1.03
River stage two • 22 direct dependents • 31 total dependents
/ Minion

NAME

Minion - Job queue

SYNOPSIS

use Minion;

# Connect to backend
my $minion = Minion->new(File => '/Users/sri/minion.db');
my $minion = Minion->new(Pg   => 'postgresql://postgres@/test');

# Add tasks
$minion->add_task(something_slow => sub {
  my ($job, @args) = @_;
  sleep 5;
  say 'This is a background worker process.';
});

# Enqueue jobs
$minion->enqueue(something_slow => ['foo', 'bar']);
$minion->enqueue(something_slow => [1, 2, 3] => {priority => 5});

# Perform jobs for testing
$minion->enqueue(something_slow => ['foo', 'bar']);
$minion->perform_jobs;

# Build more sophisticated workers
my $worker = $minion->repair->worker->register;
while (int rand 2) {
  if (my $job = $worker->dequeue(5)) { $job->perform }
}
$worker->unregister;

DESCRIPTION

Minion is a job queue for the Mojolicious real-time web framework with support for multiple backends, such as DBM::Deep and PostgreSQL.

A job queue allows you to process time and/or computationally intensive tasks in background processes, outside of the request/response lifecycle. Among those tasks you'll commonly find image resizing, spam filtering, HTTP downloads, building tarballs, warming caches and basically everything else you can imagine that's not super fast.

use Mojolicious::Lite;

plugin Minion => {Pg => 'postgresql://sri:s3cret@localhost/test'};

# Slow task
app->minion->add_task(poke_mojo => sub {
  my $job = shift;
  $job->app->ua->get('mojolicio.us');
  $job->app->log->debug('We have poked mojolicio.us for a visitor.');
});

# Perform job in a background worker process
get '/' => sub {
  my $c = shift;
  $c->minion->enqueue('poke_mojo');
  $c->render(text => 'We will poke mojolicio.us for you soon.');
};

app->start;

Background worker processes are usually started with the command Minion::Command::minion::worker, which becomes automatically available when an application loads the plugin Mojolicious::Plugin::Minion.

$ ./myapp.pl minion worker

Jobs can be managed right from the command line with Minion::Command::minion::job.

$ ./myapp.pl minion job

EVENTS

Minion inherits all events from Mojo::EventEmitter and can emit the following new ones.

worker

$minion->on(worker => sub {
  my ($minion, $worker) = @_;
  ...
});

Emitted when a new worker is created.

$minion->on(worker => sub {
  my ($minion, $worker) = @_;
  my $id = $worker->id;
  say "Worker $$:$id started.";
});

ATTRIBUTES

Minion implements the following attributes.

app

my $app = $minion->app;
$minion = $minion->app(MyApp->new);

Application for job queue, defaults to a Mojo::HelloWorld object.

backend

my $backend = $minion->backend;
$minion     = $minion->backend(Minion::Backend::File->new);

Backend, usually a Minion::Backend::File or Minion::Backend::Pg object.

remove_after

my $after = $minion->remove_after;
$minion   = $minion->remove_after(86400);

Amount of time in seconds after which jobs that have reached the state finished will be removed automatically by "repair", defaults to 864000 (10 days).

tasks

my $tasks = $minion->tasks;
$minion   = $minion->tasks({foo => sub {...}});

Registered tasks.

METHODS

Minion inherits all methods from Mojo::EventEmitter and implements the following new ones.

add_task

$minion = $minion->add_task(foo => sub {...});

Register a new task.

enqueue

my $id = $minion->enqueue('foo');
my $id = $minion->enqueue(foo => [@args]);
my $id = $minion->enqueue(foo => [@args] => {priority => 1});

Enqueue a new job with inactive state. Arguments get serialized, so you shouldn't send objects.

These options are currently available:

delay
delay => 10

Delay job for this many seconds from now.

priority
priority => 5

Job priority, defaults to 0.

job

my $job = $minion->job($id);

Get Minion::Job object without making any changes to the actual job or return undef if job does not exist.

new

my $minion = Minion->new(File => '/Users/sri/minion.db');

Construct a new Minion object.

perform_jobs

$minion->perform_jobs;

Perform all jobs, very useful for testing.

repair

$minion = $minion->repair;

Repair worker registry and job queue if necessary. All processes running this method and workers on this host should be owned by the same user, so they can check which workers are still alive with signals.

reset

$minion = $minion->reset;

Reset job queue.

stats

my $stats = $minion->stats;

Get statistics for jobs and workers.

worker

my $worker = $minion->worker;

Build Minion::Worker object.

AUTHOR

Sebastian Riedel, sri@cpan.org.

CREDITS

In alphabetical order:

    Brian Medley

COPYRIGHT AND LICENSE

Copyright (C) 2014, Sebastian Riedel.

This program is free software, you can redistribute it and/or modify it under the terms of the Artistic License version 2.0.

SEE ALSO

https://github.com/kraih/minion, Mojolicious::Guides, http://mojolicio.us.