NAME
CGI::Header - Adapter for CGI::header() function
SYNOPSIS
use CGI::Header;
my $header = {
-attachment => 'foo.gif',
-charset => 'utf-7',
-cookie => [ $cookie1, $cookie2 ], # CGI::Cookie objects
-expires => '+3d',
-nph => 1,
-p3p => [qw/CAO DSP LAW CURa/],
-target => 'ResultsWindow',
-type => 'image/gif',
};
my $h = CGI::Header->new( $header );
# update $header
$h->set( 'Content-Length' => 3002 );
$h->delete( 'Content-Disposition' );
$h->clear;
my @headers = $h->flatten;
# => ( 'Content-length', '3002', 'Content-Type', 'text/plain' )
print $h->as_string;
# Content-length: 3002
# Content-Type: text/plain
$h->header; # same reference as $header
DESCRIPTION
This module is a utility class to manipulate a hash reference which CGI's header()
function receives. This class is, so to speak, a subclass of Hash because the function behaves like a hash, while Perl5 doesn't provide a built-in class called Hash.
This module isn't the replacement of the function. Although this class implements as_string()
method, the function should stringify the reference in most cases.
This module can be used in the following situation:
- 1. $header is a hash reference which represents CGI response headers
-
For exmaple, CGI::Application implements
header_add()
method which can be used to add CGI.pm-compatible HTTP header properties. Instances of CGI applications often hold those properties.my $header = { -type => 'text/plain' };
- 2. Manipulates $header using CGI::Header
-
Since property names are case-insensitive, application developers have to normalize them manually when they specify header properties. CGI::Header normalizes them automatically.
use CGI::Header; my $h = CGI::Header->new( $header ); $h->set( 'Content-Length' => 3002 ); # add Content-Length header $header; # => { # -type => 'text/plain', # -content_length => '3002', # }
- 3. Passes $header to CGI::header() to stringify the variable
-
header()
function just stringifies given header properties. This module can be used to generate PSGI-compatible header array references. See also flatten().use CGI; print CGI::header( $header ); # Content-length: 3002 # Content-Type: text/plain; charset=ISO-8859-1 #
CLASS METHOD
- $header = CGI::Header->new({ -type => 'text/plain', ... })
-
Given a header hash reference, returns a CGI::Header object which holds a reference to the original given argument:
my $header = { -type => 'text/plain' }; my $h = CGI::Header->new( $header );
The object updates the reference when called write methods like
set()
,delete()
orclear()
:# updates $header $h->set( 'Content-Length' => 3002 ); $h->delete( 'Content-Disposition' ); $h->clear;
It also has
header()
method that would return the same reference:$h->header; # same reference as $header
- $header = CGI::Header->new( -type => 'text/plain', ... )
-
A shortcut for:
my $header = CGI::Header->new({ -type => 'text/plain', ... });
INSTANCE METHODS
- $header->header
-
Returns the header hash reference associated with this CGI::Header object.
- $header->rehash
-
Rebuilds the header hash to normalize parameter names without changing the reference. If parameter names aren't normalized, the methods listed below won't work as you expect.
my $h1 = $header->header; # => { # '-content_type' => 'text/plain', # 'Set-Cookie' => 'ID=123456; path=/', # 'expires' => '+3d', # '-target' => 'ResultsWindow', # '-content-length' => '3002', # } $header->rehash; my $h2 = $header->header; # same reference as $h1 # => { # '-type' => 'text/plain', # '-cookie' => 'ID=123456; path=/', # '-expires' => '+3d', # '-target' => 'ResultsWindow', # '-content_length' => '3002', # }
Normalized parameter names are:
- lowercased
-
'Content-Length' -> 'content-length'
- start with a dash
-
'content-length' -> '-content-length'
- use underscores instead of dashes except for the first character
-
'-content-length' -> '-content_length'
CGI::header()
also accepsts aliases of parameter names. This module converts them as follows:'-content_type' -> '-type' '-set_cookie' -> '-cookie' '-cookies' -> '-cookie' '-window_target' -> '-target'
NOTE:
new()
doesn't check whether parameter names are normalized or not at all, and so you have torehash()
the header hash explicitly when you aren't sure that they are normalized. - $value = $header->get( $field )
- $header->set( $field => $value )
-
Get or set the value of the header field. The header field name (
$field
) is not case sensitive. You can use underscores as a replacement for dashes in header names.# field names are case-insensitive $header->get( 'Content-Length' ); $header->get( 'content_length' );
The
$value
argument may be a plain string or a reference to an array of CGI::Cookie objects for the Set-Cookie header.$header->set( 'Content-Length' => 3002 ); $header->set( 'Set-Cookie' => [$cookie1, $cookie2] );
- $bool = $header->exists( $field )
-
Returns a Boolean value telling whether the specified field exists.
if ( $header->exists('ETag') ) { ... }
- $value = $header->delete( $field )
-
Deletes the specified field form CGI response headers. Returns the value of the deleted field.
my $value = $header->delete( 'Content-Disposition' ); # => 'inline'
- $bool = $header->is_empty
-
Returns true if the header contains no key-value pairs.
$header->clear; if ( $header->is_empty ) { # true ... }
- $header->clear
-
This will remove all header fields.
- $clone = $header->clone
-
Returns a copy of this CGI::Header object. It's identical to:
my %copy = %{ $header->header }; my $clone = CGI::Header->new( \%copy );
- $filename = $header->attachment
- $header->attachment( $filename )
-
Can be used to turn the page into an attachment. Represents suggested name for the saved file.
$header->attachment( 'genome.jpg' );
In this case, the outgoing header will be formatted as:
Content-Disposition: attachment; filename="genome.jpg"
-
Represents P3P tags. The parameter can be an array or a space-delimited string. Returns a list of P3P tags.
$header->p3p_tags(qw/CAO DSP LAW CURa/); # or $header->p3p_tags( 'CAO DSP LAW CURa' );
In this case, the outgoing header will be formatted as:
P3P: policyref="/w3c/p3p.xml", CP="CAO DSP LAW CURa"
- $format = $header->expires
- $header->expires( $format )
-
The Expires header gives the date and time after which the entity should be considered stale. You can specify an absolute or relative expiration interval. The following forms are all valid for this field:
$header->expires( '+30s' ); # 30 seconds from now $header->expires( '+10m' ); # ten minutes from now $header->expires( '+1h' ); # one hour from now $header->expires( 'now' ); # immediately $header->expires( '+3M' ); # in three months $header->expires( '+10y' ); # in ten years time # at the indicated time & date $header->expires( 'Thu, 25 Apr 1999 00:40:33 GMT' );
- $header->nph
-
If set to a true value, will issue the correct headers to work with a NPH (no-parse-header) script.
$header->nph( 1 );
- @fields = $header->field_names
-
Returns the list of distinct field names present in the header. The field names have case as returned by
CGI::header()
.my @fields = $header->field_names; # => ( 'Set-Cookie', 'Content-length', 'Content-Type' )
- $header->each( \&callback )
-
Apply a subroutine to each header field in turn. The callback routine is called with two parameters; the name of the field and a value. If the Set-Cookie header is multi-valued, then the routine is called once for each value. Any return values of the callback routine are ignored.
my @lines; $header->each(sub { my ( $field, $value ) = @_; push @lines, "$field: $value"; }); print join @lines, "\n"; # Content-length: 3002 # Content-Type: text/plain
- @headers = $header->flatten
-
Returns pairs of fields and values.
my @headers = $header->flatten; # => ( 'Content-length', '3002', 'Content-Type', 'text/plain' )
It's identical to:
my @headers; $self->each(sub { my ( $field, $value ) = @_; push @headers, $field, "$value"; # force stringification });
This method can be used to generate PSGI-compatible header array references:
my $status_code = $header->delete( 'Status' ) || '200 OK'; $status_code =~ s/\D*$//; $header->nph( 0 ); # removes the Server header my @headers = $header->flatten;
See also CGI::Emulate::PSGI, CGI::PSGI.
- $header->as_string
- $header->as_string( $eol )
-
Returns the header fields as a formatted MIME header. The optional
$eol
parameter specifies the line ending sequence to use. The default is\015\012
.The following:
use CGI; print CGI::header( $header->header );
is identical to:
my $CRLF = $CGI::CRLF; print $header->as_string( $CRLF ), $CRLF;
When valid multi-line headers are included, this method will always output them back as a single line, according to the folding rules of RFC 2616: the newlines will be removed, while the white space remains.
Unlike CGI.pm, when invalid newlines are included, this module removes them instead of throwing exceptions.
tie() INTERFACE
use CGI::Header;
my $header = { -type => 'text/plain' };
tie my %header => 'CGI::Header' => $header;
# update $header
$header{'Content-Length'} = 3002;
delete $header{'Content-Disposition'};
%header = ();
Above methods are aliased as follows:
TIEHASH -> new
FETCH -> get
STORE -> set
DELETE -> delete
CLEAR -> clear
EXISTS -> exists
SCALAR -> !is_empty
NOTE: FIRSTKEY()
and NEXTKEY()
aren't implemented, and so you can't iterate through the tied hash.
# doesn't work
keys %header;
values %header;
each %header;
See also perltie.
LIMITATIONS
- Can't set '-content_type' to neither undef nor an empty string
-
# wrong $header->set( 'Content-Type' => undef ); $header->set( 'Content-Type' => q{} );
Use delete() instead:
$header->delete( 'Content-Type' );
- Can't assign to '-expires' directly, use expires() instead
-
# wrong $header->set( 'Expires' => '+3d' );
Use expires() instead:
$header->expires( '+3d' );
because the following behavior will surprize us:
$header->set( 'Expires' => '+3d' ); my $value = $header->get( 'Expires' ); # => "Thu, 25 Apr 1999 00:40:33 GMT"
-
CGI::header()
restricts where the policy-reference file is located, and so you can't modify the location (/w3c/p3p.xml
). The following code doesn't work as you expect:# wrong $header->set( 'P3P' => '/path/to/p3p.xml' );
You're allowed to set P3P tags using
p3p_tags()
.
SEE ALSO
BUGS
There are no known bugs in this module. Please report problems to ANAZAWA (anazawa@cpan.org). Patches are welcome.
AUTHOR
Ryo Anazawa (anazawa@cpan.org)
LICENSE
This module is free software; you can redistibute it and/or modify it under the same terms as Perl itself. See perlartistic.