/ 
POE-Component-Server-SimpleHTTP-1.05
River stage two • 8 direct dependents • 10 total dependents
/ POE::Component::Server::SimpleHTTP

NAME

POE::Component::Server::SimpleHTTP - Perl extension to serve HTTP requests in POE.

SYNOPSIS

use POE;
use POE::Component::Server::SimpleHTTP;

# Start the server!
POE::Component::Server::SimpleHTTP->new(
	'ALIAS'		=>	'HTTPD',
	'ADDRESS'	=>	'192.168.1.1',
	'PORT'		=>	11111,
	'HOSTNAME'	=>	'MySite.com',
	'HANDLERS'	=>	[
		{
			'DIR'		=>	'^/bar/.*',
			'SESSION'	=>	'HTTP_GET',
			'EVENT'		=>	'GOT_BAR',
		},
		{
			'DIR'		=>	'^/$',
			'SESSION'	=>	'HTTP_GET',
			'EVENT'		=>	'GOT_MAIN',
		},
		{
			'DIR'		=>	'.*',
			'SESSION'	=>	'HTTP_GET',
			'EVENT'		=>	'GOT_ERROR',
		},
	],
) or die 'Unable to create the HTTP Server';

# Create our own session to receive events from SimpleHTTP
POE::Session->create(
	inline_states => {
		'_start'	=>	sub {	$_[KERNEL]->alias_set( 'HTTP_GET' );
						$_[KERNEL]->post( 'HTTPD', 'GETHANDLERS', $_[SESSION], 'GOT_HANDLERS' );
					},

		'GOT_BAR'	=>	\&GOT_REQ,
		'GOT_MAIN'	=>	\&GOT_REQ,
		'GOT_ERROR'	=>	\&GOT_ERR,
		'GOT_HANDLERS'	=>	\&GOT_HANDLERS,
	},
);

# Start POE!
POE::Kernel->run();

sub GOT_HANDLERS {
	# ARG0 = HANDLERS array
	my $handlers = $_[ ARG0 ];

	# Move the first handler to the last one
	push( @$handlers, shift( @$handlers ) );

	# Send it off!
	$_[KERNEL]->post( 'HTTPD', 'SETHANDLERS', $handlers );
}

sub GOT_REQ {
	# ARG0 = HTTP::Request object, ARG1 = HTTP::Response object, ARG2 = the DIR that matched
	my( $request, $response, $dirmatch ) = @_[ ARG0 .. ARG2 ];

	# Do our stuff to HTTP::Response
	$response->code( 200 );
	$response->content( 'Some funky HTML here' );

	# We are done!
	# For speed, you could use $_[KERNEL]->call( ... )
	$_[KERNEL]->post( 'HTTPD', 'DONE', $response );
}

sub GOT_ERR {
	# ARG0 = HTTP::Request object, ARG1 = HTTP::Response object, ARG2 = the DIR that matched
	my( $request, $response, $dirmatch ) = @_[ ARG0 .. ARG2 ];

	# Check for errors
	if ( ! defined $request ) {
		$_[KERNEL]->post( 'HTTPD', 'DONE', $response );
		return;
	}

	# Do our stuff to HTTP::Response
	$response->code( 404 );
	$response->content( "Hi visitor from " . $response->connection->remote_ip . ", Page not found -> '" . $request->uri->path . "'" );

	# We are done!
	# For speed, you could use $_[KERNEL]->call( ... )
	$_[KERNEL]->post( 'HTTPD', 'DONE', $response );
}

ABSTRACT

An easy to use HTTP daemon for POE-enabled programs

CHANGES

1.05

Got rid of POE::Component::Server::TCP and replaced it with POE::Wheel::SocketFactory for speed/efficiency
As the documentation for POE::Filter::HTTPD says, updated POD to reflect the HTTP::Request/Response issue
Got rid of SimpleHTTP::Request, due to moving of the Connection object to Response
	->	Found a circular leak by having SimpleHTTP::Connection in SimpleHTTP::Request, to get rid of it, moved it to Response
	->	Realized that sometimes HTTP::Request will be undef, so how would you get the Connection object?
Internal tweaking to save some memory
Added the MAX_RETRIES subroutine
More extensive DEBUG statements
POD updates
Paul Visscher tracked down the HTTP::Request object leak, thanks!
Cleaned up the Makefile.PL
Benchmarked and found a significant speed difference between post()ing and call()ing the DONE event
	-> The call() method is ~8% faster
	-> However, the chance of connecting sockets timing out is greater...

1.04

Fixed a bug reported by Tim Wood about socket disappearing
Fixed *another* bug in the Connection object, pesky CaPs! ( Again, reported by Tim Wood )

1.03

Added the GETHANDLERS/SETHANDLERS event
POD updates
Fixed SimpleHTTP::Connection to get rid of the funky CaPs

1.02

Small fix regarding the Got_Error routine for Wheel::ReadWrite

1.01

Initial Revision

DESCRIPTION

This module makes serving up HTTP requests a breeze in POE.

The hardest thing to understand in this module is the HANDLERS. That's it!

The standard way to use this module is to do this:

use POE;
use POE::Component::Server::SimpleHTTP;

POE::Component::Server::SimpleHTTP->new( ... );

POE::Session->create( ... );

POE::Kernel->run();

Starting SimpleHTTP

To start SimpleHTTP, just call it's new method:

POE::Component::Server::SimpleHTTP->new(
	'ALIAS'		=>	'HTTPD',
	'ADDRESS'	=>	'192.168.1.1',
	'PORT'		=>	11111,
	'HOSTNAME'	=>	'MySite.com',
	'HEADERS'	=>	{},
	'HANDLERS'	=>	[ ],
);

This method will die on error or return success.

This constructor accepts only 6 options.

ALIAS

This will set the alias SimpleHTTP uses in the POE Kernel. This will default to "SimpleHTTP"

ADDRESS

This value will be passed to POE::Component::Server::TCP to bind to.

PORT

This value will be passed to POE::Component::Server::TCP to bind to.

HOSTNAME

This value is for the HTTP::Request's URI to point to. If this is not supplied, SimpleHTTP will use Sys::Hostname to find it.

HEADERS

This should be a hashref, that will become the default headers on all HTTP::Response objects. You can override this in individual requests by setting it via $request->header( ... )

For more information, consult the HTTP::Headers module.

HANDLERS

This is the hardest part of SimpleHTTP :)

You supply an array, with each element being a hash. All the hashes should contain those 3 keys:

DIR -> The regexp that will be used, more later.

SESSION -> The session to send the input

EVENT -> The event to trigger

The DIR key should be a valid regexp. This will be matched against the current request path. Pseudocode is: if ( $path =~ /$DIR/ )

NOTE: The path is UNIX style, not MSWIN style ( /blah/foo not \blah\foo )

Now, if you supply 100 handlers, how will SimpleHTTP know what to do? Simple! By passing in an array in the first place, you have already told SimpleHTTP the order of your handlers. They will be tried in order, and if one is not found, SimpleHTTP will DIE!

This allows some cool things like specifying 3 handlers with DIR of: '^/foo/.*', '^/$', '.*'

Now, if the request is not in /foo or not root, your 3rd handler will catch it, becoming the "404 not found" handler!

NOTE: You might get weird Session/Events, make sure your handlers are in order, for example: '^/', '^/foo/.*' The 2nd handler will NEVER get any requests, as the first one will match ( no $ in the regex )

Now, here's what a handler receives:

ARG0 -> HTTP::Request object

ARG1 -> POE::Component::Server::SimpleHTTP::Response object

ARG2 -> The exact DIR that matched, so you can see what triggered what

NOTE: If ARG0 is undef, that means POE::Filter::HTTPD encountered an error parsing the client request, simply modify the HTTP::Response object and send some sort of generic error. SimpleHTTP will set the path used in matching the DIR regexes to an empty string, so if there is a "catch-all" DIR regex like '.*', it will catch the errors, and only that one.

Events

SimpleHTTP is so simple, there are only 4 events available.

DONE
This event accepts only one argument: the HTTP::Response object we sent to the handler.

Calling this event implies that this particular request is done, and will proceed to close the socket.

NOTE: This method automatically sets those 3 headers if they are not already set:
	Date		->	Current date stringified via HTTP::Date->time2str
	Content-Type	->	text/html
	Content-Length	->	length( $response->content )

To get greater throughput and response time, do not post() to the DONE event, call() it!
However, this will force your program to block while servicing web requests...
GETHANDLERS
This event accepts 2 arguments: The session + event to send the response to

This event will send back the current HANDLERS array ( deep-cloned via Storable::dclone )

The resulting array can be played around to your tastes, then once you are done...
SETHANDLERS
This event accepts only one argument: pointer to HANDLERS array

BEWARE: if there is an error in the HANDLERS, SimpleHTTP will die!
SHUTDOWN
Calling this event makes SimpleHTTP shut down by closing it's TCP socket.

SimpleHTTP Notes

This module is very picky about capitalization!

All of the options are uppercase, to avoid confusion.

You can enable debugging mode by doing this:

sub POE::Component::Server::SimpleHTTP::DEBUG () { 1 }
use POE::Component::Server::SimpleHTTP;

Also, this module will try to keep the SocketFactory wheel alive. if it dies, it will open it again for a max of 5 retries.

You can override this behavior by doing this:

sub POE::Component::Server::SimpleHTTP::MAX_RETRIES () { 10 }
use POE::Component::Server::SimpleHTTP;

For those who are pondering about basic-authentication, here's a tiny snippet to put in the Event handler

# Contributed by Rocco Caputo
sub Got_Request {
	# ARG0 = HTTP::Request, ARG1 = HTTP::Response
	my( $request, $response ) = @_[ ARG0, ARG1 ];

	# Get the login
	my ( $login, $password ) = $request->authorization_basic();

	# Decide what to do
	if ( ! defined $login or ! defined $password ) {
		# Set the authorization
		$response->header( 'WWW-Authenticate' => 'Basic realm="MyRealm"' );
		$response->code( 401 );
		$response->content( 'FORBIDDEN.' );

		# Send it off!
		$_[KERNEL]->post( 'SimpleHTTP', 'DONE', $response );
	} else {
		# Authenticate the user and move on
	}
}

EXPORT

Nothing.

SEE ALSO

POE

POE::Component::Server::HTTP

POE::Filter::HTTPD

HTTP::Request

HTTP::Response

POE::Component::Server::SimpleHTTP::Connection

POE::Component::Server::SimpleHTTP::Response

AUTHOR

Apocalypse <apocal@cpan.org>

COPYRIGHT AND LICENSE

Copyright 2003 by Apocalypse

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.