NAME

HTML::Make - A flexible HTML generator

SYNOPSIS

# Make a table.
use HTML::Make;
my $table = HTML::Make->new ('table');
# Can add elements as text
$table->add_text ('<tr><th>Item<th>Cost');
my %items = (
    compressor => 12800,
    heater => 'free',
    camera => 1080,
);
for my $k (sort keys %items) {
    # Add an element using "push". The return value is the new element.
    my $tr = $table->push ('tr');
    # Can add element to $tr using "push"
    $tr->push ('td', text => $k);
    # Can also make a new element then "push" it.
    my $td = HTML::Make->new ('td', text => $items{$k},
                              attr => {style => 'padding:1em'});
    $tr->push ($td);
}
# Get the output
print $table->text ();

produces output

<table>
<tr><th>Item<th>Cost<tr><td>camera</td>
<td style="padding:1em">1080</td>
</tr>
<tr><td>compressor</td>
<td style="padding:1em">12800</td>
</tr>
<tr><td>heater</td>
<td style="padding:1em">free</td>
</tr>
</table>

As HTML, this looks like

Item	Cost
camera	1080
compressor	12800
heater	free

(This example is included as synopsis.pl in the distribution.)

VERSION

This documents HTML::Make version 0.07 corresponding to git commit 9ca145cd21545344c0f29b162dc1cf469f765d05 released on Thu Jan 5 13:11:29 2017 +0900.

DESCRIPTION

HTML::Make is an HTML generator. It was designed for generating HTML fragments rather than complete pages. A typical use would be for automating generation of a list or table within an HTML document.

METHODS

new

my $element = HTML::Make->new ('li');

Make a new HTML element of the specified type.

It is possible to add attributes or text to the item. To add attributes, use the following syntax:

my $element = HTML::Make->new ('li', attr => {class => 'biglist'});

To add text,

my $element = HTML::Make->new ('li', text => "White punks on dope");

Both attributes and text may be added:

my $element = HTML::Make->new ('li', attr => {id => 'ok'}, text => 'OK');

HTML::Make uses the list of known HTML tags from "HTML::Valid::Tagset", and will issue a warning if the type given as the first argument to "new" is not on its list of tags. To switch off this behaviour, use the nocheck option:

my $freaky = HTML::Make->new ('freaky', nocheck => 1);

add_attr

$obj->add_attr (class => 'buggles');

Add attributes to the specified object, in other words

my $obj = HTML::Make->new ('li');
$obj->add_attr (class => 'beano');
my $obj_text = $obj->text ();
# <li class="beano"></li>

This issues a warning of the form "Overwriting attribute 'class' for 'li'" if the object already contains an attribute of the specified type.

This issues a warning if the attribute is not valid for the tag, according to "tag_attr_ok" in HTML::Valid::Tagset. This is restricted to what is valid in HTML5.

add_text

$element->add_text ('buggles');

Add text to $element. For example,

my $element = HTML::Make->new ('p');
$element->add_text ('peanuts');
print $element->text ();
# <p>peanuts</p>

The text may contain HTML elements:

my $element = HTML::Make->new ('p');
$element->add_text ('peanuts <i>eggs</i>');
print $element->text ();
# <p>peanuts <i>eggs</i></p>

The return value is the added text object.

push

my $child = $element->push ('tag');

Add child element of type <tag> to $element and return the result as a new HTML::Make object. For example,

use utf8;
use HTML::Make;
my $table = HTML::Make->new ('table');
my $row = $table->push ('tr');
my $cell = $row->push ('td', text => 'Cell');
print $table->text ();

produces output

<table>
<tr><td>Cell</td>
</tr>
</table>

As HTML, this looks like

Cell

(This example is included as table.pl in the distribution.)

An object created with HTML::Make may also be pushed:

use utf8;
use HTML::Make;
my @colours = (
    daidai => 0xEE7800,
    murasaki => 0x884898,
    kimidori => 0xB9C42F,
    kogecha => 0x6A4D32,
    uguisuiro => 0x838B0D,
);
my $ul = HTML::Make->new ('ul');
while (@colours) {
    my $colour = shift @colours;
    my $rgb = shift @colours;
    # Here we make a new element and then push it into $ul, rather
    # than using the return value of $ul->push ().
    my $li = HTML::Make->new (
        'li', text => $colour,
        attr => {
            style => sprintf ("background: #%06X", $rgb),
        });
    $ul->push ($li);
}
print $ul->text ();

# Inspired by
# https://www.amazon.co.jp/gp/product/B001D7WIFY/
# http://irocore.com/read-list/

produces output

<ul>
<li style="background: #EE7800">daidai</li>
<li style="background: #884898">murasaki</li>
<li style="background: #B9C42F">kimidori</li>
<li style="background: #6A4D32">kogecha</li>
<li style="background: #838B0D">uguisuiro</li>
</ul>

As HTML, this looks like

daidai
murasaki
kimidori
kogecha
uguisuiro

(This example is included as push-new.pl in the distribution.)

It's also possible to add all of the same arguments as "new", for example

$element->push ('a', attr => {href => 'http://www.example.org/'});

This warns if you add some types of elements to possibly inappropriate parent elements. For example if you add an <li> tag to a <tr> or something.

opening_tag

my $tag = $obj->opening_tag ();

Returns the text value of the HTML tag opening, complete with attributes.

text

$element->text ();

This function returns the element as text.

my $p = HTML::Make->new ('p');
print $p->text ();
# <p></p>

multiply

my @elements = $obj->multiply ('li', \@contents);

Create multiple child elements of $obj of type given by the first argument, with text contents given by \@contents.

use HTML::Make;
my $ol = HTML::Make->new ('ol');
$ol->multiply ('li', ['one', 'two', 'three']);
print $ol->text ();

produces output

<ol><li>one</li>
<li>two</li>
<li>three</li>
</ol>

As HTML, this looks like

one
two
three

(This example is included as multiply.pl in the distribution.)

EXTENDED EXAMPLES

JSON to HTML

This script converts arbitrary JSON to HTML:

use utf8;
use JSON::Parse 'parse_json';
use HTML::Make;
my $json =<<EOF;
{"words":[{"j_pron_only":"パイプ","word":"pipe"},{"word":"cutting","j_pron_only":"カティング"},{"word":"implement","j_pron_only":"インプリムント"}]}
EOF
my $p = parse_json ($json);
my $html = json_to_html ($p);
print $html->text ();
exit;

sub json_to_html
{
    my ($input) = @_;
    my $element;
    if (ref $input eq 'ARRAY') {
        $element = HTML::Make->new ('ol');
        for my $k (@$input) {
            my $li = $element->push ('li');
            $li->push (json_to_html ($k));
        }
    }
    elsif (ref $input eq 'HASH') {
        $element = HTML::Make->new ('table');
        for my $k (sort keys %$input) {
            my $tr = $element->push ('tr');
            $tr->push ('th', text => $k);
            my $td = $tr->push ('td');
            $td->push (json_to_html ($input->{$k}));
        }
    }
    else {
        $element = HTML::Make->new ('span', text => $input);
    }
    return $element;
}

produces output

<table>
<tr><th>words</th>
<td><ol>
<li><table>
<tr><th>j_pron_only</th>
<td><span>パイプ</span>
</td>
</tr>
<tr><th>word</th>
<td><span>pipe</span>
</td>
</tr>
</table>
</li>
<li><table>
<tr><th>j_pron_only</th>
<td><span>カティング</span>
</td>
</tr>
<tr><th>word</th>
<td><span>cutting</span>
</td>
</tr>
</table>
</li>
<li><table>
<tr><th>j_pron_only</th>
<td><span>インプリムント</span>
</td>
</tr>
<tr><th>word</th>
<td><span>implement</span>
</td>
</tr>
</table>
</li>
</ol>
</td>
</tr>
</table>

As HTML, this looks like

words

j_pron_only ãã¤ã

word pipe
j_pron_only ã«ãã£ã³ã°

word cutting
j_pron_only ã¤ã³ããªã ã³ã

word implement

(This example is included as json-to-html.pl in the distribution.)

BUGS

This module assumes you want to make HTML5.

There is no way to control the whitespace in the output HTML.

There is no way to add HTML comments to the output except by adding them as text.

DEPENDENCIES

This module depends on the following Perl modules.

Carp: Carp is used to report errors.
HTML::Valid::Tagset: HTML::Valid::Tagset is used to validate tags and tag/attribute pairs.

AUTHOR

Ben Bullock, <bkb@cpan.org>

COPYRIGHT & LICENCE

You can use, copy, modify and redistribute this package and associated files under the Perl Artistic Licence or the GNU General Public Licence.

To install HTML::Make, copy and paste the appropriate command in to your terminal.

cpanm

cpanm HTML::Make

CPAN shell

perl -MCPAN -e shell
install HTML::Make

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

VERSION

DESCRIPTION

METHODS

new

add_attr

add_text

push

opening_tag

text

multiply

EXTENDED EXAMPLES

JSON to HTML

BUGS

DEPENDENCIES

SEE ALSO

AUTHOR

COPYRIGHT & LICENCE

Module Install Instructions