BLHOTSKY / App-ElasticSearch-Utilities-8.1 / lib / App / ElasticSearch / Utilities / QueryString / Plugin.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
—
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156

              
package App::ElasticSearch::Utilities::QueryString::Plugin;
# ABSTRACT: Moo::Role for implementing QueryString Plugins
use strict;
use warnings;
our $VERSION = '8.1'; # VERSION
use Hash::Merge::Simple qw(clone_merge);
use Moo::Role;
use Ref::Util qw(is_arrayref is_hashref);
use Types::Standard qw( Str Int );
# Attributes
has name => (
    is  => 'lazy',
    isa => Str,
);
sub _build_name {
    my $self = shift;
    my $class = ref $self;
    return (split /::/, $class)[-1];
}
has priority => (
    is  => 'lazy',
    isa => Int,
);
sub _build_priority { 50; }
requires qw(handle_token);
around 'handle_token' => sub {
    my $orig = shift;
    my $self = shift;
    my $refs = $orig->($self,@_);
    if( defined $refs ) {
        if( is_arrayref($refs) ) {
            foreach my $doc (@{ $refs }) {
                $doc->{_by} = $self->name;
            }
        }
        elsif( is_hashref($refs) ) {
            $refs->{_by} = $self->name;
        }
        return $refs;
    }
    else {
        return;
    }
};
# Handle Build Args
sub BUILDARGS {
    my($class,%in) = @_;
    my @search = map { $_ => lc $_ } ($class,(split /::/, $class)[-1]);
    my $options = exists $in{options} ? delete $in{options} : {};
    my @options = ();
    foreach my $s (@search) {
        if( exists $options->{$s} ) {
            push @options, $options->{$s};
            last;
        }
    }
    push @options, \%in if keys %in;
    return scalar(@options) ? clone_merge(@options) : {};
}
1;
__END__
=pod
=head1 NAME
App::ElasticSearch::Utilities::QueryString::Plugin - Moo::Role for implementing QueryString Plugins
=head1 VERSION
version 8.1
=head1 ATTRIBUTES
=head2 name
Name of the plugin, used in debug reporting.
=head2 priority
Priority is an integer which determmines the order tokens are parsed in
low->high order.
=head1 INTERFACE
=head2 handle_token()
The handle_token() routine receives a single token from the command line, often a single word
and returns a hash reference specifying
The token expansion plugins can return undefined, which is basically a noop on the token.
The plugin can return a hash reference, which marks that token as handled and no other plugins
receive that token.  The hash reference may contain:
=head2 query_string
This is the rewritten bits that will be reassembled in to the final query string.
=head2 condition
This is usually a hash reference representing the condition going into the bool query. For instance:
    { terms => { field => [qw(alice bob charlie)] } }
Or
    { prefix => { user_agent => 'Go ' } }
These conditions will wind up in the B<must> or B<must_not> section of the B<bool> query depending on the
state of the the invert flag.
=head2 invert
This is used by the bareword "not" to track whether the token invoked a flip from the B<must> to the B<must_not>
state.  After each token is processed, if it didn't set this flag, the flag is reset.
=head2 dangles
This is used for bare words like "not", "or", and "and" to denote that these terms cannot dangle from the
beginning or end of the query_string.  This allows the final pass of the query_string builder to strip these
words to prevent syntax errors.
=for Pod::Coverage BUILDARGS
=head1 AUTHOR
Brad Lhotsky <brad@divisionbyzero.net>
=head1 COPYRIGHT AND LICENSE
This software is Copyright (c) 2021 by Brad Lhotsky.
This is free software, licensed under:
  The (three-clause) BSD License
=cut