From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

BOLAV / DateTime-Format-Duration-DurationString-0.04 / lib / DateTime / Format / Duration / DurationString.pm 

            

              
1
2
3
4
5
6
—
7
8
9
10
11
12
13
14
15
16
17
18
—
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
—
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
—
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
—
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
—
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159

              
package DateTime::Format::Duration::DurationString;
use Moo;
use Carp;
use DateTime::Duration;
use MooX::Types::MooseLike::Numeric 'PositiveOrZeroInt';
=head1 NAME
DateTime::Format::Duration::DurationString - JIRA style parsing of duration
=head1 VERSION
Version 0.04
=cut
our $VERSION = '0.04';
=head1 SYNOPSIS
  package MyApp;
  use DateTime::Format::Duration::DurationString;
   
  my $seconds  = DateTime::Format::Duration::DurationString->new()->parse('1d 3h')->to_seconds;
  my $duration = DateTime::Format::Duration::DurationString->new()->parse('1d 3h')->to_duration;
=head1 DESCRIPTION
C<DateTime::Format::Duration::DurationString> parses a string and returns a duration.
=cut
# Constants:
use constant SECOND => 1;
use constant MINUTE => 60 * SECOND;
use constant HOUR   => 60 * MINUTE;
use constant DAY    => 24 * HOUR;
use constant WEEK   => 7 * DAY;
# use constant MONTH  => 31 * DAY;
# use constant YEAR   => 365 * DAY;
has 'seconds' => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
has 'minutes' => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
has 'hours'   => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
has 'days'    => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
has 'weeks'   => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
# has 'months'  => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
# has 'years'   => (is => 'rw', isa => PositiveOrZeroInt, default => 0);
=head2 to_seconds
Return this object as seconds
=cut
sub to_seconds {
    my $self = shift;
     
    return ($self->seconds * SECOND)
         + ($self->minutes * MINUTE)
         + ($self->hours   * HOUR)
         + ($self->days    * DAY)
         + ($self->weeks   * WEEK);
#         + ($self->months  * MONTH)
#         + ($self->years   * YEAR);
     
}
=head2 to_duration
Return this object as a DateTime::Duration
=cut
sub to_duration {
    my $self = shift;
     
    return DateTime::Duration->new( weeks   => $self->weeks,
                                    days    => $self->days,
                                    hours   => $self->hours,
                                    minutes => $self->minutes,
                                    seconds => $self->seconds,
                                  );
}
=head2 parse
Parse a string
=cut
sub parse {
    my $self = shift;
    my ($str) = @_;
     
    foreach my $token (split(/\s+/,$str)) {
        $self->_parse_token($token);
    }
     
    return $self;
}
sub _parse_token {
    my $self = shift;
    my ($token) = @_;
     
    if ($token =~ /^(\d+)(\D?)$/) {
        my $num = $1;
        my $typ = $2;
         
        if ($typ eq 's') {
            $self->seconds($self->seconds + $num);
        }
        elsif (($typ eq 'm')) {
            $self->minutes($self->minutes + $num);
        } 
        elsif (($typ eq 'h')||($typ eq '')) {
            $self->hours($self->hours + $num);
        } 
        elsif ($typ eq 'd'){
            $self->days($self->days + $num);
        }
        elsif ($typ eq 'w'){
            $self->weeks($self->weeks + $num);
        }
        else {
            croak "$token has unknown type $typ";
        }
    } 
    else {
        croak "$token not wellformed. <duration><wdhms>";
    }
    return $self;
}
1; # Return something nice to the caller
=head1 TODO
Parsestring in constructor?
=head1 SEE ALSO
L<DateTime>, L<DateTime::Duration> and L<DateTime::Format::Duration>
=head1 AUTHOR
Bjorn-Olav Strand E<lt>bo@startsiden.noE<gt>
=head1 LICENSE
Copyright 2009 by ABC Startsiden AS, BjE<oslash>rn-Olav Strand <bo@startsiden.no>.
This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
=cut