NAME

perldelta - what's new for perl5.004

DESCRIPTION

This document describes differences between the 5.003 release (as documented in Programming Perl, second edition--the Camel Book) and this one.

Supported Environments

Perl5.004 builds out of the box on Unix, Plan9, LynxOS, VMS, OS/2, QNX, and AmigaOS.

Core Changes

Most importantly, many bugs were fixed. See the Changes file in the distribution for details.

Compilation Option: Binary Compatibility With 5.003

There is a new Configure question that asks if you want to maintain binary compatibility with Perl 5.003. If you choose binary compatibility, you do not have to recompile your extensions, but you might have symbol conflicts if you embed Perl in another application, just as in the 5.003 release. By default, binary compatibility is preserved at the expense of symbol table pollution.

New Opcode Module and Revised Safe Module

A new Opcode module supports the creation, manipulation and application of opcode masks. The revised Safe module has a new API and is implemented using the new Opcode module. Please read the new Opcode and Safe documentation.

Internal Change: FileHandle Deprecated

Filehandles are now stored internally as type IO::Handle. Although use FileHandle and *STDOUT{FILEHANDLE} are still supported for backwards compatibility, use IO::Handle (or IO::Seekable or IO::File) and *STDOUT{IO} are the way of the future.

Internal Change: PerlIO internal IO abstraction interface

It is now possible to build Perl with AT&T's sfio IO package instead of stdio. See perlapio for more details, and the INSTALL file for how to use it.

New and Changed Built-in Variables

$^E

Extended error message on some platforms. (Also known as $EXTENDED_OS_ERROR if you use English).

$^H

The current set of syntax checks enabled by use strict. See the documentation of strict for more details. Not actually new, but newly documented. Because it is intended for internal use by Perl core components, there is no use English long name for this variable.

$^M

By default, running out of memory it is not trappable. However, if compiled for this, Perl may use the contents of $^M as an emergency pool after die()ing with this message. Suppose that your Perl were compiled with -DEMERGENCY_SBRK and used Perl's malloc. Then

$^M = 'a' x (1<<16);

would allocate a 64K buffer for use when in emergency. See the INSTALL file for information on how to enable this option. As a disincentive to casual use of this advanced feature, there is no use English long name for this variable.

$^S

The status returned by the last pipe close, back-tick (``) command, or system() operator, in the native system format. On UNIX and UNIX-like systems, $^S is a synonym for $?. Elsewhere, $^S can be used to determine aspects of child status that are system-specific. Check $^O before using this variable. (Mnemonic: System-Specific Subprocess Status. Also known as $SYSTEM_CHILD_STATUS if you use English.)

New and Changed Built-in Functions

delete on slices

This now works. (e.g. delete @ENV{'PATH', 'MANPATH'})

flock

is now supported on more platforms, and prefers fcntl to lockf when emulating.

keys as an lvalue

As an lvalue, keys allows you to increase the number of hash buckets allocated for the given associative array. This can gain you a measure of efficiency if you know the hash is going to get big. (This is similar to pre-extending an array by assigning a larger number to $#array.) If you say

keys %hash = 200;

then %hash will have at least 200 buckets allocated for it. These buckets will be retained even if you do %hash = (); use undef %hash if you want to free the storage while %hash is still in scope. You can't shrink the number of buckets allocated for the hash using keys in this way (but you needn't worry about doing this by accident, as trying has no effect).

my() in Control Structures

You can now use my() (with or without the parentheses) in the control expressions of control structures such as:

while (my $line = <>) {
    $line = lc $line;
} continue {
    print $line;
}

if ((my $answer = <STDIN>) =~ /^y(es)?$/i) {
    user_agrees();
} elsif ($answer =~ /^n(o)?$/i) {
    user_disagrees();
} else {
    chomp $answer;
    die "`$answer' is neither `yes' nor `no'";
}

Also, you can declare a foreach loop control variable as lexical by preceding it with the word "my". For example, in:

foreach my $i (1, 2, 3) {
    some_function();
}

$i is a lexical variable, and the scope of $i extends to the end of the loop, but not beyond it.

Note that you still cannot use my() on global punctuation variables such as $_ and the like.

unpack() and pack()

A new format 'w' represents a BER compressed integer (as defined in ASN.1). Its format is a sequence of one or more bytes, each of which provides seven bits of the total value, with the most significant first. Bit eight of each byte is set, except for the last byte, in which bit eight is clear.

use VERSION

If the first argument to use is a number, it is treated as a version number instead of a module name. If the version of the Perl interpreter is less than VERSION, then an error message is printed and Perl exits immediately. Because use occurs at compile time, this check happens immediately during the compilation process, unlike require VERSION, which waits until run-time for the check. This is often useful if you need to check the current Perl version before useing library modules which have changed in incompatible ways from older versions of Perl. (We try not to do this more than we have to.)

use Module VERSION LIST

If the VERSION argument is present between Module and LIST, then the use will call the VERSION method in class Module with the given version as an argument. The default VERSION method, inherited from the Universal class, croaks if the given version is larger than the value of the variable $Module::VERSION. (Note that there is not a comma after VERSION!)

This version-checking mechanism is similar to the one currently used in the Exporter module, but it is faster and can be used with modules that don't use the Exporter. It is the recommended method for new code.

prototype(FUNCTION)

Returns the prototype of a function as a string (or undef if the function has no prototype). FUNCTION is a reference to or the name of the function whose prototype you want to retrieve. (Not actually new; just never documented before.)

$_ as Default

Functions documented in the Camel to default to $_ now in fact do, and all those that do are so documented in perlfunc.

m//g does not trigger a pos() reset on failure

The m//g match iteration construct used to reset the iteration when it failed to match (so that the next m//g match would start at the beginning of the string). You now have to explicitly do a pos $str = 0; to reset the "last match" position, or modify the string in some way. This change makes it practical to chain m//g matches together in conjunction with ordinary matches using the \G zero-width assertion. See perlop and perlre.

nested sub{} closures work now

Prior to the 5.004 release, nested anonymous functions didn't work right. They do now.

formats work right on changing lexicals

Just like anonymous functions that contain lexical variables that change (like a lexical index variable for a foreach loop), formats now work properly. For example, this silently failed before, and is fine now:

    my $i;
    foreach $i ( 1 .. 10 ) {
	format =
	my i is @#
	$i
    .
	write;
    } 

New Built-in Methods

The UNIVERSAL package automatically contains the following methods that are inherited by all other classes:

isa(CLASS)

isa returns true if its object is blessed into a sub-class of CLASS

isa is also exportable and can be called as a sub with two arguments. This allows the ability to check what a reference points to. Example:

use UNIVERSAL qw(isa);

if(isa($ref, 'ARRAY')) {
   ...
}

can(METHOD)

can checks to see if its object has a method called METHOD, if it does then a reference to the sub is returned; if it does not then undef is returned.

VERSION( [NEED] )

VERSION returns the version number of the class (package). If the NEED argument is given then it will check that the current version (as defined by the $VERSION variable in the given package) not less than NEED; it will die if this is not the case. This method is normally called as a class method. This method is called automatically by the VERSION form of use.

use A 1.2 qw(some imported subs);
# implies:
A->VERSION(1.2);

class()

class returns the class name of its object.

is_instance()

is_instance returns true if its object is an instance of some class, false if its object is the class (package) itself. Example

A->is_instance();       # False

$var = 'A';
$var->is_instance();    # False

$ref = bless [], 'A';
$ref->is_instance();    # True

This can be useful for methods that wish to easily distinguish whether they were invoked as class or as instance methods.

    sub some_meth {
	my $classname = shift;
	if ($classname->is_instance()) {
	    die "unexpectedly called as instance not class method";
	} 
	.....
    } 

NOTE: can directly uses Perl's internal code for method lookup, and isa uses a very similar method and caching strategy. This may cause strange effects if the Perl code dynamically changes @ISA in any package.

You may add other methods to the UNIVERSAL class via Perl or XS code. You do not need to use UNIVERSAL in order to make these methods available to your program. This is necessary only if you wish to have isa available as a plain subroutine in the current package.

TIEHANDLE Now Supported

See perltie for other kinds of tie()s.

TIEHANDLE classname, LIST

This is the constructor for the class. That means it is expected to return an object of some sort. The reference can be used to hold some internal information.

    sub TIEHANDLE { 
	print "<shout>\n"; 
	my $i; 
	return bless \$i, shift;
    }

PRINT this, LIST

This method will be triggered every time the tied handle is printed to. Beyond its self reference it also expects the list that was passed to the print function.

    sub PRINT { 
	$r = shift; 
	$$r++; 
	return print join( $, => map {uc} @_), $\;
    }

READLINE this

This method will be called when the handle is read from. The method should return undef when there is no more data.

    sub READLINE { 
	$r = shift; 
	return "PRINT called $$r times\n"; 
    }

DESTROY this

As with the other types of ties, this method will be called when the tied handle is about to be destroyed. This is useful for debugging and possibly for cleaning up.

    sub DESTROY { 
	print "</shout>\n";
    }

Efficiency Enhancements

All hash keys with the same string are only allocated once, so even if you have 100 copies of the same hash, the immutable keys never have to be re-allocated.

Functions that have an empty prototype and that do nothing but return a fixed value are now inlined (e.g. sub PI () { 3.14159 }).

Pragmata

Three new pragmatic modules exist:

use blib

use blib 'dir'

Looks for MakeMaker-like 'blib' directory structure starting in dir (or current directory) and working back up to five levels of parent directories.

Intended for use on command line with -M option as a way of testing arbitrary scripts against an uninstalled version of a package.

use locale

Tells the compiler to enable (or disable) the use of POSIX locales for built-in operations.

When use locale is in effect, the current LC_CTYPE locale is used for regular expressions and case mapping; LC_COLLATE for string ordering; and LC_NUMERIC for numeric formating in printf and sprintf (but not in print). LC_NUMERIC is always used in write, since lexical scoping of formats is problematic at best.

Each use locale or no locale affects statements to the end of the enclosing BLOCK or, if not inside a BLOCK, to the end of the current file. Locales can be switched and queried with POSIX::setlocale().

See perllocale for more information.

use ops

Disable unsafe opcodes, or any named opcodes, when compiling Perl code.

Modules

Installation Directories

The installperl script now places the Perl source files for extensions in the architecture-specific library directory, which is where the shared libraries for extensions have always been. This change is intended to allow administrators to keep the Perl 5.004 library directory unchanged from a previous version, without running the risk of binary incompatibility between extensions' Perl source and shared libraries.

Fcntl

New constants in the existing Fcntl modules are now supported, provided that your operating system happens to support them:

F_GETOWN F_SETOWN
O_ASYNC O_DEFER O_DSYNC O_FSYNC O_SYNC 
O_EXLOCK O_SHLOCK

These constants are intended for use with the Perl operators sysopen() and fcntl() and the basic database modules like SDBM_File. For the exact meaning of these and other Fcntl constants please refer to your operating system's documentation for fcntl() and open().

In addition, the Fcntl module now provides these constants for use with the Perl operator flock():

LOCK_SH LOCK_EX LOCK_NB LOCK_UN

These constants are defined in all environments (because where there is no flock() system call, Perl emulates it). However, for historical reasons, these constants are not exported unless they are explicitly requested with the ":flock" tag (e.g. use Fcntl ':flock').

Module Information Summary

Brand new modules, arranged by topic rather than strictly alphabetically:

CPAN                 interface to Comprehensive Perl Archive Network
CPAN::FirstTime      create a CPAN configuration file
CPAN::Nox            run CPAN while avoiding compiled extensions

IO.pm                Top-level interface to IO::* classes
IO/File.pm           IO::File extension Perl module
IO/Handle.pm         IO::Handle extension Perl module
IO/Pipe.pm           IO::Pipe extension Perl module
IO/Seekable.pm       IO::Seekable extension Perl module
IO/Select.pm         IO::Select extension Perl module
IO/Socket.pm         IO::Socket extension Perl module

Opcode.pm            Disable named opcodes when compiling Perl code

ExtUtils/Embed.pm    Utilities for embedding Perl in C programs
ExtUtils/testlib.pm  Fixes up @INC to use just-built extension

Fatal.pm             Make do-or-die equivalents of functions
FindBin.pm           Find path of currently executing program

Class/Template.pm    Structure/member template builder
File/stat.pm         Object-oriented wrapper around CORE::stat
Net/hostent.pm       Object-oriented wrapper around CORE::gethost*
Net/netent.pm        Object-oriented wrapper around CORE::getnet*
Net/protoent.pm      Object-oriented wrapper around CORE::getproto*
Net/servent.pm       Object-oriented wrapper around CORE::getserv*
Time/gmtime.pm       Object-oriented wrapper around CORE::gmtime
Time/localtime.pm    Object-oriented wrapper around CORE::localtime
Time/tm.pm           Perl implementation of "struct tm" for {gm,local}time
User/grent.pm        Object-oriented wrapper around CORE::getgr*
User/pwent.pm        Object-oriented wrapper around CORE::getpw*

Tie/RefHash.pm       Base class for tied hashes with references as keys

UNIVERSAL.pm         Base class for *ALL* classes

IO

The IO module provides a simple mechanism to load all of the IO modules at one go. Currently this includes:

IO::Handle
IO::Seekable
IO::File
IO::Pipe
IO::Socket

For more information on any of these modules, please see its respective documentation.

Math::Complex

The Math::Complex module has been totally rewritten, and now supports more operations. These are overloaded:

+ - * / ** <=> neg ~ abs sqrt exp log sin cos atan2 "" (stringify)

And these functions are now exported:

pi i Re Im arg
log10 logn cbrt root
tan cotan asin acos atan acotan
sinh cosh tanh cotanh asinh acosh atanh acotanh
cplx cplxe

DB_File

There have been quite a few changes made to DB_File. Here are a few of the highlights:

• Fixed a handful of bugs.

• By public demand, added support for the standard hash function exists().

• Made it compatible with Berkeley DB 1.86.

• Made negative subscripts work with RECNO interface.

• Changed the default flags from O_RDWR to O_CREAT|O_RDWR and the default mode from 0640 to 0666.

• Made DB_File automatically import the open() constants (O_RDWR, O_CREAT etc.) from Fcntl, if available.

• Updated documentation.

Refer to the HISTORY section in DB_File.pm for a complete list of changes. Everything after DB_File 1.01 has been added since 5.003.

Net::Ping

Major rewrite - support added for both udp echo and real icmp pings.

Overridden Built-ins

Many of the Perl built-ins returning lists now have object-oriented overrides. These are:

File::stat
Net::hostent
Net::netent
Net::protoent
Net::servent
Time::gmtime
Time::localtime
User::grent
User::pwent

For example, you can now say

use File::stat;
use User::pwent;
$his = (stat($filename)->st_uid == pwent($whoever)->pw_uid);

Utility Changes

xsubpp

void XSUBs now default to returning nothing

Due to a documentation/implementation bug in previous versions of Perl, XSUBs with a return type of void have actually been returning one value. Usually that value was the GV for the XSUB, but sometimes it was some already freed or reused value, which would sometimes lead to program failure.

In Perl 5.004, if an XSUB is declared as returning void, it actually returns no value, i.e. an empty list (though there is a backward-compatibility exception; see below). If your XSUB really does return an SV, you should give it a return type of SV *.

For backward compatibility, xsubpp tries to guess whether a void XSUB is really void or if it wants to return an SV *. It does so by examining the text of the XSUB: if xsubpp finds what looks like an assignment to ST(0), it assumes that the XSUB's return type is really SV *.

C Language API Changes

gv_fetchmethod and perl_call_sv

The gv_fetchmethod function finds a method for an object, just like in Perl 5.003. The GV it returns may be a method cache entry. However, in Perl 5.004, method cache entries are not visible to users; therefore, they can no longer be passed directly to perl_call_sv. Instead, you should use the GvCV macro on the GV to extract its CV, and pass the CV to perl_call_sv.

The most likely symptom of passing the result of gv_fetchmethod to perl_call_sv is Perl's producing an "Undefined subroutine called" error on the second call to a given method (since there is no cache on the first call).

Documentation Changes

Many of the base and library pods were updated. These new pods are included in section 1:

perldelta

This document.

perllocale

Locale support (internationalization and localization).

perltoot

Tutorial on Perl OO programming.

perlapio

Perl internal IO abstraction interface.

perldebug

Although not new, this has been massively updated.

perlsec

Although not new, this has been massively updated.

New Diagnostics

Several new conditions will trigger warnings that were silent before. Some only affect certain platforms. The following new warnings and errors outline these. These messages are classified as follows (listed in increasing order of desperation):

(W) A warning (optional).
(D) A deprecation (optional).
(S) A severe warning (mandatory).
(F) A fatal error (trappable).
(P) An internal error you should never see (trappable).
(X) A very fatal error (non-trappable).
(A) An alien error message (not generated by Perl).

"my" variable %s masks earlier declaration in same scope

(S) A lexical variable has been redeclared in the same scope, effectively eliminating all access to the previous instance. This is almost always a typographical error. Note that the earlier variable will still exist until the end of the scope or until all closure referents to it are destroyed.

%s argument is not a HASH element or slice

(F) The argument to delete() must be either a hash element, such as

$foo{$bar}
$ref->[12]->{"susie"}

or a hash slice, such as

@foo{$bar, $baz, $xyzzy}
@{$ref->[12]}{"susie", "queue"}

Allocation too large: %lx

(X) You can't allocate more than 64K on an MSDOS machine.

Allocation too large

(F) You can't allocate more than 2^31+"small amount" bytes.

Attempt to free non-existent shared string

(P) Perl maintains a reference counted internal table of strings to optimize the storage and access of hash keys and other strings. This indicates someone tried to decrement the reference count of a string that can no longer be found in the table.

Attempt to use reference as lvalue in substr

(W) You supplied a reference as the first argument to substr() used as an lvalue, which is pretty strange. Perhaps you forgot to dereference it first. See "substr" in perlfunc.

Unsupported function fork

(F) Your version of executable does not support forking.

Note that under some systems, like OS/2, there may be different flavors of Perl executables, some of which may support fork, some not. Try changing the name you call Perl by to perl_, perl__, and so on.

Ill-formed logical name |%s| in prime_env_iter

(W) A warning peculiar to VMS. A logical name was encountered when preparing to iterate over %ENV which violates the syntactic rules governing logical names. Since it cannot be translated normally, it is skipped, and will not appear in %ENV. This may be a benign occurrence, as some software packages might directly modify logical name tables and introduce non-standard names, or it may indicate that a logical name table has been corrupted.

Can't use bareword ("%s") as %s ref while "strict refs" in use

(F) Only hard references are allowed by "strict refs". Symbolic references are disallowed. See perlref.

Constant subroutine %s redefined

(S) You redefined a subroutine which had previously been eligible for inlining. See "Constant Functions" in perlsub for commentary and workarounds.

Died

(F) You passed die() an empty string (the equivalent of die "") or you called it with no args and both $@ and $_ were empty.

Integer overflow in hex number

(S) The literal hex number you have specified is too big for your architecture. On a 32-bit architecture the largest hex literal is 0xFFFFFFFF.

Integer overflow in octal number

(S) The literal octal number you have specified is too big for your architecture. On a 32-bit architecture the largest octal literal is 037777777777.

Name "%s::%s" used only once: possible typo

(W) Typographical errors often show up as unique variable names. If you had a good reason for having a unique name, then just mention it again somehow to suppress the message (the use vars pragma is provided for just this purpose).

Null picture in formline

(F) The first argument to formline must be a valid format picture specification. It was found to be empty, which probably means you supplied it an uninitialized value. See perlform.

Offset outside string

(F) You tried to do a read/write/send/recv operation with an offset pointing outside the buffer. This is difficult to imagine. The sole exception to this is that sysread()ing past the buffer will extend the buffer and zero pad the new area.

Stub found while resolving method `%s' overloading `%s' in package `%s'

(P) Overloading resolution over @ISA tree may be broken by importing stubs. Stubs should never be implicitely created, but explicit calls to can may break this.

Cannot resolve method `%s' overloading `%s' in package `s'

(P) Internal error trying to resolve overloading specified by a method name (as opposed to a subroutine reference).

Out of memory!

(X|F) The malloc() function returned 0, indicating there was insufficient remaining memory (or virtual memory) to satisfy the request.

The request was judged to be small, so the possibility to trap it depends on the way Perl was compiled. By default it is not trappable. However, if compiled for this, Perl may use the contents of $^M as an emergency pool after die()ing with this message. In this case the error is trappable once.

Out of memory during request for %s

(F) The malloc() function returned 0, indicating there was insufficient remaining memory (or virtual memory) to satisfy the request. However, the request was judged large enough (compile-time default is 64K), so a possibility to shut down by trapping this error is granted.

Possible attempt to put comments in qw() list

(W) qw() lists contain items separated by whitespace; as with literal strings, comment characters are not ignored, but are instead treated as literal data. (You may have used different delimiters than the exclamation marks parentheses shown here; braces are also frequently used.)

You probably wrote something like this:

@list = qw( 
    a # a comment
    b # another comment
);

when you should have written this:

@list = qw(
    a 
    b
);

If you really want comments, build your list the old-fashioned way, with quotes and commas:

@list = (
    'a',    # a comment
    'b',    # another comment
);

Possible attempt to separate words with commas

(W) qw() lists contain items separated by whitespace; therefore commas aren't needed to separate the items. (You may have used different delimiters than the parentheses shown here; braces are also frequently used.)

You probably wrote something like this:

qw! a, b, c !;

which puts literal commas into some of the list items. Write it without commas if you don't want them to appear in your data:

qw! a b c !;

Scalar value @%s{%s} better written as $%s{%s}

(W) You've used a hash slice (indicated by @) to select a single element of a hash. Generally it's better to ask for a scalar value (indicated by $). The difference is that $foo{&bar} always behaves like a scalar, both when assigning to it and when evaluating its argument, while @foo{&bar} behaves like a list when you assign to it, and provides a list context to its subscript, which can do weird things if you're expecting only one subscript.

untie attempted while %d inner references still exist

(W) A copy of the object returned from tie (or tied) was still valid when untie was called.

Value of %s construct can be "0"; test with defined()

(W) In a conditional expression, you used <HANDLE>, <*> (glob), or readdir as a boolean value. Each of these constructs can return a value of "0"; that would make the conditional expression false, which is probably not what you intended. When using these constructs in conditional expressions, test their values with the defined operator.

Variable "%s" may be unavailable

(W) An inner (nested) anonymous subroutine is inside a named subroutine, and outside that is another subroutine; and the anonymous (innermost) subroutine is referencing a lexical variable defined in the outermost subroutine. For example:

sub outermost { my $a; sub middle { sub { $a } } }

If the anonymous subroutine is called or referenced (directly or indirectly) from the outermost subroutine, it will share the variable as you would expect. But if the anonymous subroutine is called or referenced when the outermost subroutine is not active, it will see the value of the shared variable as it was before and during the *first* call to the outermost subroutine, which is probably not what you want.

In these circumstances, it is usually best to make the middle subroutine anonymous, using the sub {} syntax. Perl has specific support for shared variables in nested anonymous subroutines; a named subroutine in between interferes with this feature.

Variable "%s" will not stay shared

(W) An inner (nested) named subroutine is referencing a lexical variable defined in an outer subroutine.

When the inner subroutine is called, it will probably see the value of the outer subroutine's variable as it was before and during the *first* call to the outer subroutine; in this case, after the first call to the outer subroutine is complete, the inner and outer subroutines will no longer share a common value for the variable. In other words, the variable will no longer be shared.

Furthermore, if the outer subroutine is anonymous and references a lexical variable outside itself, then the outer and inner subroutines will never share the given variable.

This problem can usually be solved by making the inner subroutine anonymous, using the sub {} syntax. When inner anonymous subs that reference variables in outer subroutines are called or referenced, they are automatically re-bound to the current values of such variables.

Warning: something's wrong

(W) You passed warn() an empty string (the equivalent of warn "") or you called it with no args and $_ was empty.

Got an error from DosAllocMem

(P) An error peculiar to OS/2. Most probably you're using an obsolete version of Perl, and this should not happen anyway.

Malformed PERLLIB_PREFIX

(F) An error peculiar to OS/2. PERLLIB_PREFIX should be of the form

prefix1;prefix2

or

prefix1 prefix2

with non-empty prefix1 and prefix2. If prefix1 is indeed a prefix of a builtin library search path, prefix2 is substituted. The error may appear if components are not found, or are too long. See "PERLLIB_PREFIX" in perlos2.

PERL_SH_DIR too long

(F) An error peculiar to OS/2. PERL_SH_DIR is the directory to find the sh-shell in. See "PERL_SH_DIR" in perlos2.

Process terminated by SIG%s

(W) This is a standard message issued by OS/2 applications, while *nix applications die in silence. It is considered a feature of the OS/2 port. One can easily disable this by appropriate sighandlers, see "Signals" in perlipc. See "Process terminated by SIGTERM/SIGINT" in perlos2.

BUGS

If you find what you think is a bug, you might check the headers of recently posted articles in the comp.lang.perl.misc newsgroup. There may also be information at http://www.perl.com/perl/, the Perl Home Page.

If you believe you have an unreported bug, please run the perlbug program included with your release. Make sure you trim your bug down to a tiny but sufficient test case. Your bug report, along with the output of perl -V, will be sent off to perlbug@perl.com to be analysed by the Perl porting team.

SEE ALSO

The Changes file for exhaustive details on what changed.

The INSTALL file for how to build Perl. This file has been significantly updated for 5.004, so even veteran users should look through it.

The README file for general stuff.

The Copying file for copyright information.

HISTORY

Constructed by Tom Christiansen, grabbing material with permission from innumerable contributors, with kibitzing by more than a few Perl porters.

Last update: Tue Jan 14 14:03:02 EST 1997

cpanm lib

perl -MCPAN -e shell
install lib