NAME

Text::WikiFormat - module for translating Wiki formatted text into other formats

SYNOPSIS

use Text::WikiFormat;
my $html = Text::WikiFormat::format($raw);

DESCRIPTION

The original Wiki web site was intended to have a very simple interface to edit and to add pages. Its formatting rules are simple and easy to use. They are also easily translated into other, more complicated markup languages with this module. It creates HTML by default, but can be extended to produce valid POD, DocBook, XML, or any other format imaginable.

The most important function is format(). It is not exported by default.

format()

format() takes one required argument, the text to convert, and returns the converted text. It allows two optional arguments. The first is a reference to a hash of tags. Anything passed in here will override the default tag behavior. These tags are described later. The second argument is a hash reference of options. There are currently limited to:

• prefix

  The prefix of any links. In HTML mode, this is the path to the Wiki. The actual linked item itself will be appended to the prefix. This is used to create full URIs:

  { prefix => 'http://example.com/wiki.pl?page=' }

• extended

  A boolean flag, false by default, to use extended linking semantics. This is stolen from the Everything Engine (http://everydevel.com/), where links are marked by square brackets. An optional title may occur after the link target, preceded by an open pipe. That is to say, these are valid extended links:

  [a valid link]
  [link|title]

  Where the linking semantics of the destination format allow it, the title will be displayed instead of the URI. In HTML terms, the title is the content of an A element (not the content of its HREF attribute).

  You can use delimiters other than single square brackets for marking extended links, by passing a value for extended_link_delimiters in the %tags hash when calling format (see below for details).

• implicit_links

  A boolean flag, true by default, to cause links to be created wherever a StudlyCapsString is seen. Note that if you disable this flag, you'll most likely be wanting to enable the extended one also, or there will be no way of creating links in your documents. To disable it, use the pair:

  { implicit_links => 0 }

• absolute_links

  A boolean flag, false by default, which treats any links that are absolute URIs (such as http://www.cpan.org/) to be treated specially. Any prefix will not apply and the URIs aren't quoted. Must be used in conjunction with the extended option for the link to be detected.

Wiki Format

Wiki formatting is very simple. An item wrapped in three single quotes is marked as strong. An item wrapped in two single quotes is marked as emphasized. Any word with multiple CapitalLetters (e. g., StudlyCaps) will be turned into a link. Four or more hyphen characters at the start of a line create a horizontal line. Newlines are translated into the appropriate tag. Headers are marked with matching equals signs around the header text -- the more signs, the lesser the header.

Lists are indented by one tab or four spaces, by default. Indentation may be disabled. Lists can be unordered, where each item has its own bullet point. These are marked by a leading asterisk and space. They can also be ordered, where any combination of one or more alphanumeric characters can be followed by a period and an optional space. Any indented text without either marking is considered to be code, and is handled literally. Lists can be nested.

The following is valid Wiki formatting, with an extended link as marked.

= my interesting text =

ANormalLink
[let the Sun shine|AnExtendedLink]

== my interesting lists ==

    * unordered one
    * unordered two

    1. ordered one
    2. ordered two
		a. nested one
		b. nested two

    code one
    code two

The first line of a normal paragraph.
The second line of a normal paragraph.  Whee.

EXPORT

If you'd like to make your life more convenient, you can optionally import a subroutine that already has default tags and options set up. This is especially handy if you will be using a prefix:

use Text::WikiFormat prefix => 'http://www.example.com/';
wikiformat( 'some text' );

tags are interpreted as, well, tags, except for four special keys:

• prefix, interpreted as a link prefix

• extended, interpreted as the extended link flag

• implicit_links, interpreted as the flag to control implicit links

• as, interpreted as an alias for the imported function

Use the as flag to control the name by which the imported function is called. For example,

use Text::WikiFormat as => 'formatTextInWikiStyle';
formatTextInWikiStyle( 'some text' );

You might choose a better name, though.

The calling semantics are effectively the same as those of the format() function. Any additional tags or options to the imported function will override the defaults. In this example:

use Text::WikiFormat as => 'wf', extended => 0;
wf( 'some text', {}, { extended => 1 });

extended links will be enabled, though the default is to disable them.

This feature was suggested by Tony Bowden <tony@kasei.com>, but all implementation blame rests solely with me. Kate L Pugh (<kake@earth.li>) pointed out that it didn't work, with tests, so it's fixed now.

GORY DETAILS

Tags

There are two types of Wiki markup: line items and blocks. Blocks include lists, which are made up of lines and can also contain other lists.

Line items

There are two classes of line items: simple tags, and tags that contain data. The simple tags are newline and line. A newline is inserted whenever a newline character (\n) is encountered. A line is inserted whenever four or more dash characters (----) occur at the start of a line. No whitespace is allowed. These default to the <br> and <hr> HTML tags, respectively. To override either, simply pass tags such as:

my $html = format($text, { newline => "\n" });

The three line items are more complex, and require subroutine references. This category includes the strong and emphasized tags as well as links. The first argument passed to the subref will be the data found in between the marks. The second argument is the $opts hash reference. The default action for a strong tag can be reimplemented with this syntax:

my $html = format($text, { strong => sub { "<b>$_[0]</b>" } });

As of version 0.70, you can change the regular expressions used to find strong and emphasized tags:

%tags = (
	strong_tag     => qr/\*(.+?)\*/,
	emphasized_tag => qr|(?<!<)/(.+?)/|,
);

$wikitext = 'this is *strong*, /emphasized/, and */emphasized strong/*';
$htmltext = Text::WikiFormat::format( $wikitext, \%tags, {} );

Be aware that using forward slashes to mark anything leads to the hairy regular expression -- use something else. This interface is experimental and may change if I find something better. It's nice to be able to override those tags, though.

Finally, there are extended_link_delimiters, which allow you to use delimiters other than single square brackets for marking extended links. Pass the tags as:

my $html = format( $text, { extended_link_delimiters => [ '[[', ']]' ] });

This will allow you to use double square brackets as UseMod supports:

[[an extended link]]
[[a titled extended link|title]]

Blocks

Five block types are recognized by default: paragraph, header, code, unordered, and ordered. Each of these is usually marked by indentation, either one or more tabs or four or more whitespace characters. (This does not include newlines, however.) Any line that does not fall in any of these three categories is automatically put in a paragraph list.

Lists (code, unordered, and ordered blocks) are usually marked by indentation. This is not required, however, it's used to mark nesting. Be careful. To mark a block as requiring indentation, use the indented tag, which contains a reference to a hash:

my $html = format($text, { 
	indented    => { map { $_ => 1 } qw( ordered unordered code )}
});

Block entries in the tag hashes must contain array references. The first two items are the tags used at the start and end of the block. As you'd expect, the last items contain the tags used at the start and end of each line. Where there needs to be more processing of individual lines, use a subref as the third item. This is how ordered lines are numbered in HTML lists:

my $html = format($text, { ordered => [ '<ol>', "</ol>\n",
	sub { qq|<li value="$_[2]">$_[0]</li>\n| } ] });

The first argument to these subrefs is the text of the line itself, after it has been processed. (The indentation and tokens used to mark this as a list item are removed, and the rest of the line is checked for other line formattings.) The second argument is the indentation level. The subsequent arguments are captured variables in the regular expression used to find this list type. The regexp for ordered lists is:

qr/^([\dA-Za-z]+)\.\s*/;

Indentation is processed first, if applicable, and the indentation level (the length of the indentation removed) is stored. The line must contain one or more alphanumeric character followed by a single period and optional whitespace to be identified as an ordered list item. The contents of this last group, the value of the list item, is saved, and will be passed to the subref as the third argument.

Lists are automatically started and ended as necessary.

Because of the indentation issue, blocks must be processed in a specific order. The blockorder tag governs this order. It contains a reference to an array of the names of the appropriate blocks to process. If you add a block type, be sure to add an entry for it in blockorder:

my $html = format($text, {
	escaped       => [ '', '', '', '' ],
	blocks        => {
		invisible => qr!^--(.*?)--$!,
	},
	blockorder    =>
		[qw( header line ordered unordered code paragraph invisible )],
});

Finding blocks

Text::WikiFormat uses regular expressions to find blocks. These are kept in the %tags hash, under the blocks key. To change the regular expression to find code block items, use:

my $html     =  format($wikitext, {
	blocks   => { 
		code => qr/^:\s+/,
	},
	indented => {
		code => 1,
	},
);

This will require indentation and a colon to mark code lines. A potential shortcut is to use the indent tag to match or to change the indentation marker.

Note: if you want to mark a block type as non-indented, you cannot use an empty regex such as qr//. Use a mostly-empty, always-true regex such as qr/^/ instead.

Finding Blocks in the Correct Order

As intrepid bug reporter Tom Hukins pointed out in CPAN RT bug #671, the order in which Text::WikiFormat searches for blocks varies by platform and version of Perl. Because some block-finding regular expressions are more specific than others, what's intended to be one type of block may be caught by a different list type.

If you're adding new block types, be aware of this. The blockorder entry in %tags exists to force Text::WikiFormat to apply its regexes from most specific to least specific. It contains an array reference. By default, it looks for ordered lists first, unordered lists second, and code references at the end.

AUTHOR

chromatic, chromatic@wgz.org, with much input from the Jellybean team (including Jonathan Paulett). Kate L Pugh has also provided several patches, many failing tests, and is usually the driving force behind new features and releases. If you think this module is worth buying me a beer, she deserves at least half of it.

Tony Bowden, Tom Hukins, and Andy H. all suggested useful features that are now implemented.

Sam Vilain found a silly bug.

Blame me for the implementation.

BUGS

The link checker in format_line() may fail to detect existing links that do not follow HTML, XML, or SGML style. They may die with some SGML styles too. Sic transit gloria mundi.

TODO

• Find a nicer way to mark list as having unformatted lines

• Optimize format_line() to work on a list of lines

• Handle nested strong and emphasized markings better

OTHER MODULES

Brian "Ingy" Ingerson's CGI::Kwiki has a fairly nice parser.

John McNamara's Pod::Simple::Wiki looks like a good project.

Matt Sergeant keeps threatening to write a nice SAX-throwing Wiki formatter.

COPYRIGHT

Copyright (c) 2002 - 2003, chromatic. All rights reserved. This module is distributed under the same terms as Perl itself.

cpanm Text::WikiFormat

perl -MCPAN -e shell
install Text::WikiFormat