Dave Cross: Still Munging Data With Perl: Online event - Mar 17 Learn more

CROMEDOME / Dancer2-1.1.2 / lib / Dancer2 / Core / Role / DSL.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
—
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130

              
package Dancer2::Core::Role::DSL;
# ABSTRACT: Role for DSL
$Dancer2::Core::Role::DSL::VERSION = '1.1.2';
use Moo::Role;
use Dancer2::Core::Types;
use Carp 'croak';
use Scalar::Util qw();
with 'Dancer2::Core::Role::Hookable';
has app => ( is => 'ro', required => 1 );
has keywords => (
    is      => 'rw',
    isa     => HashRef,
    lazy    => 1,
    builder => '_build_dsl_keywords',
);
sub _build_dsl_keywords {
    my ($self) = @_;
    $self->can('dsl_keywords')
      ? $self->dsl_keywords
      : {};
}
sub register {
    my ( $self, $keyword, $is_global ) = @_;
    my $keywords = $self->keywords;
    my $pkg = ref($self);
    $pkg =~ s/__WITH__.+$//;
    if ( exists $keywords->{$keyword} ) {
        my $reg_pkg = $keywords->{$keyword}{'pkg'};
        $reg_pkg =~ s/__WITH__.+$//;
        $reg_pkg eq $pkg and return;
        croak "[$pkg] Keyword $keyword already registered by $reg_pkg";
    }
    $keywords->{$keyword} = { is_global => $is_global, pkg => $pkg };
}
sub dsl { $_[0] }
# exports new symbol to caller
sub export_symbols_to {
    my ( $self, $caller, $args ) = @_;
    my $exports = $self->_construct_export_map($args);
    ## no critic
    foreach my $export ( keys %{$exports} ) {
        no strict 'refs'; ## no critic (TestingAndDebugging::ProhibitNoStrict)
        my $existing = *{"${caller}::${export}"}{CODE};
        next if defined $existing;
        *{"${caller}::${export}"} = $exports->{$export};
    }
    ## use critic
    return keys %{$exports};
}
# private
sub _compile_keyword {
    my ( $self, $keyword, $opts ) = @_;
    my $code = $opts->{is_global}
               ? sub { $self->$keyword(@_) }
               : sub {
            croak "Function '$keyword' must be called from a route handler"
                unless defined $Dancer2::Core::Route::REQUEST;
            $self->$keyword(@_)
        };
    return $self->_apply_prototype($code, $opts);
}
sub _apply_prototype {
    my ($self, $code, $opts) = @_;
    # set prototype if one is defined for the keyword. undef => no prototype
    my $prototype;
    exists $opts->{'prototype'} and $prototype = $opts->{'prototype'};
    return Scalar::Util::set_prototype( \&$code, $prototype );
}
sub _construct_export_map {
    my ( $self, $args ) = @_;
    my $keywords = $self->keywords;
    my %map;
    foreach my $keyword ( keys %$keywords ) {
        # check if the keyword were excluded from importation
        $args->{ '!' . $keyword } and next;
        $map{$keyword} = $self->_compile_keyword( $keyword, $keywords->{$keyword} );
    }
    return \%map;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dancer2::Core::Role::DSL - Role for DSL
=head1 VERSION
version 1.1.2
=head1 AUTHOR
Dancer Core Developers
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2024 by Alexis Sukrieh.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut