/ 
Encode-1.32
River stage five • 1105 direct dependents • 33721 total dependents
/ encoding

NAME

encoding - allows you to write your script in non-asii or non-utf8

SYNOPSIS

use encoding "euc-jp"; # Jperl!

# or you can even do this if your shell supports euc-jp

> perl -Mencoding=euc-jp -e '...'

# or from the shebang line

#!/your/path/to/perl -Mencoding=euc-jp

# more control

# A simple euc-jp => utf-8 converter
use encoding "euc-jp", STDOUT => "utf8";  while(<>){print};

# "no encoding;" supported (but not scoped!)
no encoding;

ABSTRACT

Perl 5.6.0 has introduced Unicode support. You could apply substr() and regexes even to complex CJK characters -- so long as the script was written in UTF-8. But back then text editors that support UTF-8 was still rare and many users rather chose to writer scripts in legacy encodings, given up whole new feature of Perl 5.6.

With encoding pragma, you can write your script in any encoding you like (so long as the Encode module supports it) and still enjoy Unicode support. You can write a code in EUC-JP as follows;

my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
             #<-char-><-char->   # 4 octets
s/\bCamel\b/$Rakuda/;

And with use encoding "euc-jp" in effect, it is the same thing as the code in UTF-8 as follow.

my $Rakuda = "\x{99F1}\x{99DD}"; # who Unicode Characters
s/\bCamel\b/$Rakuda/;

The encoding pragma also modifies the file handle disciplines of STDIN, STDOUT, and STDERR to the specified encoding. Therefore,

use encoding "euc-jp";
my $message = "Camel is the symbol of perl.\n";
my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
$message =~ s/\bCamel\b/$Rakuda/;
print $message;

Will print "\xF1\xD1\xF1\xCC is the symbol of perl.\n", not "\x{99F1}\x{99DD} is the symbol of perl.\n".

You can override this by giving extra arguments. See below.

USAGE

use encoding [ENCNAME] ;

Sets the script encoding to ENCNAME and file handle disciplines of STDIN, STDOUT are set to ":encoding(ENCNAME)". Note STDERR will not be changed.

If no encoding is specified, the environment variable PERL_ENCODING is consulted. If no encoding can be found, Unknown encoding 'ENCNAME' error will be thrown.

Note that non-STD file handles remain unaffected. Use use open or binmode to change disciplines of those.

use encoding ENCNAME [ STDIN => ENCNAME_IN ...] ;

You can also individually set encodings of STDIN, STDOUT, and STDERR via STDFH => ENCNAME_FH form. In this case, you cannot omit the first ENCNAME.

no encoding;

Unsets the script encoding and the disciplines of STDIN, STDOUT are reset to ":raw".

CAVEATS

NOT SCOPED

The pragma is a per script, not a per block lexical. Only the last use encoding or matters, and it affects the whole script. Though <no encoding pragma is supported and use encoding can appear as many times as you want in a given script, the multiple use of this pragma is discouraged.

DO NOT MIX MULTIPLE ENCODINGS

Notice that only literals (string or regular expression) having only legacy code points are affected: if you mix data like this

\xDF\x{100}

the data is assumed to be in (Latin 1 and) Unicode, not in your native encoding. In other words, this will match in "greek":

"\xDF" =~ /\x{3af}/

but this will not

"\xDF\x{100}" =~ /\x{3af}\x{100}/

since the \xDF on the left will not be upgraded to \x{3af} because of the \x{100} on the left. You should not be mixing your legacy data and Unicode in the same string.

This pragma also affects encoding of the 0x80..0xFF code point range: normally characters in that range are left as eight-bit bytes (unless they are combined with characters with code points 0x100 or larger, in which case all characters need to become UTF-8 encoded), but if the encoding pragma is present, even the 0x80..0xFF range always gets UTF-8 encoded.

After all, the best thing about this pragma is that you don't have to resort to \x... just to spell your name in native encoding. So feel free to put your strings in your encoding in quotes and regexes.

EXAMPLE - Greekperl

use encoding "iso 8859-7";

# The \xDF of ISO 8859-7 (Greek) is \x{3af} in Unicode.

$a = "\xDF";
$b = "\x{100}";

printf "%#x\n", ord($a); # will print 0x3af, not 0xdf

$c = $a . $b;

# $c will be "\x{3af}\x{100}", not "\x{df}\x{100}".

# chr() is affected, and ...

print "mega\n"  if ord(chr(0xdf)) == 0x3af;

# ... ord() is affected by the encoding pragma ...

print "tera\n" if ord(pack("C", 0xdf)) == 0x3af;

# ... as are eq and cmp ...

print "peta\n" if "\x{3af}" eq  pack("C", 0xdf);
print "exa\n"  if "\x{3af}" cmp pack("C", 0xdf) == 0;

# ... but pack/unpack C are not affected, in case you still
# want back to your native encoding

print "zetta\n" if unpack("C", (pack("C", 0xdf))) == 0xdf;

KNOWN PROBLEMS

For native multibyte encodings (either fixed or variable length) the current implementation of the regular expressions may introduce recoding errors for longer regular expression literals than 127 bytes.

The encoding pragma is not supported on EBCDIC platforms. (Porters wanted.)

SEE ALSO

perlunicode, Encode, open