DWHEELER / PGXN-Meta-Validator-v0.12.0 / bin / validate_pgxn_meta 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
—
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96

              
#!/usr/bin/perl -w
use strict;
use warnings;
use PGXN::Meta::Validator;
use Getopt::Long;
GetOptions(
    'help|h'    => \my $help,
    'man|m'     => \my $man,
    'version|v' => \my $version,
) or _pod2usage();
_pod2usage(
    ( $man ? ( '-sections' => '.+' ) : ()),
    '-exitval' => 0,
) if $help or $man;
if ($version) {
    require File::Basename;
    print File::Basename::basename($0), ' ',
        PGXN::Meta::Validator->VERSION, $/;
    exit;
}
my $file = shift or _pod2usage();
die "$file is not a valid, readable filename\n" unless -r $file;
my $pmv = PGXN::Meta::Validator->load_file($file);
if ($pmv->is_valid) {
    print "$file is OK\n";
    exit;
}
print "$file is invalid. Errors:\n  ",
    join("\n  ", $pmv->errors),
    "\n";
exit 1;
sub _pod2usage {
    require Pod::Usage;
    Pod::Usage::pod2usage(
        '-verbose'  => 99,
        '-sections' => '(?i:(Usage|Options))',
        '-exitval'  => 1,
        '-input'    => __FILE__,
        @_
    );
}
1;
__END__
=head1 Name
validate_pgxn_meta - Validate the structure of a PGXN F<META.json> file
=head1 Usage
  validate_pgxn_meta META.json
=head1 Options
  -h --help     Print a usage statement and exit.
  -M --man      Print the complete documentation and exit.
  -v --version  Print the version number and exit.
=head1 Output
If F<META.json> valid, the output will be:
  META.json is OK
If it's not valid, the output will look something like:
  META.json is invalid. Errors:
    Missing mandatory field, 'license' (license) [Validation: 1.0.0]
=head1 See Also
L<PGXN::Meta::Validator> is the class that does the actual validation, and may
be used programmatically.
=head1 Author
David E. Wheeler <david@kineticode.com>
=head1 Copyright and License
Copyright (c) 2011 David E. Wheeler. Some Rights Reserved.
This module is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.
=cut