/ 
Catalyst-Runtime-5.80002
River stage three • 608 direct dependents • 682 total dependents
/ Catalyst::Test

NAME

Catalyst::Test - Test Catalyst Applications

SYNOPSIS

# Helper
script/test.pl

# Tests
use Catalyst::Test 'TestApp';
my $content  = get('index.html');           # Content as string
my $response = request('index.html');       # HTTP::Response object
my($res, $c) = ctx_request('index.html');      # HTTP::Response & context object

use HTTP::Request::Common;
my $response = request POST '/foo', [
    bar => 'baz',
    something => 'else'
];

# Run tests against a remote server
CATALYST_SERVER='http://localhost:3000/' prove -r -l lib/ t/

# Tests with inline apps need to use Catalyst::Engine::Test
package TestApp;

use Catalyst;

sub foo : Global {
        my ( $self, $c ) = @_;
        $c->res->output('bar');
}

__PACKAGE__->setup();

package main;

use Catalyst::Test 'TestApp';
use Test::More tests => 1;

ok( get('/foo') =~ /bar/ );

# mock virtual hosts
use Catalyst::Test 'MyApp', { default_host => 'myapp.com' };
like( get('/whichhost'), qr/served by myapp.com/ );
like( get( '/whichhost', { host => 'yourapp.com' } ), qr/served by yourapp.com/ );
{
    local $Catalyst::Test::default_host = 'otherapp.com';
    like( get('/whichhost'), qr/served by otherapp.com/ );
}

DESCRIPTION

This module allows you to make requests to a Catalyst application either without a server, by simulating the environment of an HTTP request using HTTP::Request::AsCGI or remotely if you define the CATALYST_SERVER environment variable. This module also adds a few catalyst specific testing methods as displayed in the method section.

The </get> and </request> functions take either a URI or an HTTP::Request object.

METHODS

$content = get( ... )

Returns the content.

my $content = get('foo/bar?test=1');

Note that this method doesn't follow redirects, so to test for a correctly redirecting page you'll need to use a combination of this method and the request method below:

my $res = request('/'); # redirects to /y
warn $res->header('location');
use URI;
my $uri = URI->new($res->header('location'));
is ( $uri->path , '/y');
my $content = get($uri->path);

$res = request( ... );

Returns a HTTP::Response object. Accepts an optional hashref for request header configuration; currently only supports setting 'host' value.

my $res = request('foo/bar?test=1');
my $virtual_res = request('foo/bar?test=1', {host => 'virtualhost.com'});

FUNCTIONS

($res, $c) = ctx_request( ... );

Works exactly like Catalyst::Test::request, except it also returns the catalyst context object, $c. Note that this only works for local requests.

$res = Catalyst::Test::local_request( $AppClass, $url );

Simulate a request using HTTP::Request::AsCGI.

$res = Catalyst::Test::remote_request( $url );

Do an actual remote request using LWP.

action_ok

Fetches the given url and check that the request was successful

action_redirect

Fetches the given url and check that the request was a redirect

action_notfound

Fetches the given url and check that the request was not found

content_like

Fetches the given url and matches the content against it.

contenttype_is

Check for given mime type

SEE ALSO

Catalyst, Test::WWW::Mechanize::Catalyst, Test::WWW::Selenium::Catalyst, Test::More, HTTP::Request::Common

AUTHORS

Catalyst Contributors, see Catalyst.pm

COPYRIGHT

This program is free software, you can redistribute it and/or modify it under the same terms as Perl itself.