Programmer avec PerlQt

Germain Garand traduit par Stéphane Payrard

Ce document décrit l'interface Perl au toolkit Qt 3.x. Contacter l'auteur à <germain@ebooksfrance.com> ou le traducteur à <stef@mongueurs.net>. Vous trouverez le document original sur le site <perlqt.infonium.com|"http://perlqt.infonium.com">

Introduction

PerlQt-3, crée par Ashley Winters, est une interface perl aux composants graphiques fournis par Qt3.

Le toolkit Qt 3.0 auquel perlQt accède à été écrit en C++ par la société Trolltech: Trolltech.

PerlQt3 est fondé sur la librairie SMOKE, une surcouche fine indépendante du langage. Cette couche a été générée à partir des fichiers d'en tête de Qt par Richard Dale's kalyptus grâce au module de David Faure.

Le présent document décrit les principes de la programmation PerlQt. Vous devez maîtriser la programmation orientée objet en Perl pour le lire. Une connaissance de C++ est recommandée mais non requise. Avec celle de l'anglais, elle vous facilitera la consultation des manuels en ligne de Qt. Ladite documentation est la seule référence qui fasse autorité. La translation de la doc en son équivalent Perl devrait être facile car l'API objet PerlQt-3 est proche de l'API objet originelle en C++.

Installation

Conditions requises

Pour compiler et utiliser PerlQt, vous devez avoir:

• un système conforme à la norme POSIX.

• Perl >= v5.6.0

• Qt >= v3.0

• SmokeQt 1.0 La librarie SMOKE (Scripting Meta Object Kompiler) fait partie du module KDE's kdebindings. Vous pouvez vérifier si une version précompilée de ce module existe pour votre système. Mais perlQt inclut une copie, donc la version précompilée n'est pas nécessaire.

L'installation de Perl et de Qt sont en dehors du sujet du présent document. Se référer aux documentations respectives de ces logiciels.

Compilation de PerlQt

Suivez simplement la procédure standard du système GNU Autoconf.

./configure

N.B : Si la variable d'environnement QTDIR n'est pas définie, vous devrez peut-être spécifier manuellement l'emplacement de Qt à l'aide de l'option :

--with-qtdir=/emplacement/de/Qt

Si la bibliothèque SMOKE est manquante, configure générera ses sources dans un sous-répertoire (4 minutes pour un ordinateur moyen).

make

(40 minutes en moyenne).

make install

Cela installera PerlQt et Puic.

Le lieu d'installation préféré de SMOKE et de PUIC est le système de fichiers de KDE3. Si KDE3 n'est pas installé (ou que la variable KDEDIR n'est pas définie), spécifier ce lieu avec l'option --prefix de configure's. Ainsi :

./configure --prefix=/usr

Anatomie de PerlQt

Un programme Qt typique utilisant des composants GUI est fondé sur une boucle événementielle.

Cela signifie qu'un tel programme n'est plus vu comme un contrôle de flux séquentiel où vous gérez vous-même chaque évènement (tels que le clic de la souris ou l'enfoncement d'une touche).

Au lieu de cela, vous créez un objet Qt::Application et les composants du GUI qu'il utilise, puis vous définissez les méthodes d'objet à appeler lors de l'occurrence d'un évènement, puis démarrez la boucle évènementielle.

C'est tout. Qt gérera les évènements et les multiplexera vers les routines appropriées.

Voyons un programme PerlQt minimal.

Hello World

1: use Qt;
2: my $a = Qt::Application(\@ARGV);
3: my $hello = Qt::PushButton("Hello World!", undef);
4: $hello->resize(160, 25);
5: $a->setMainWidget($hello);
6: $hello->show;
7: exit $a->exec;

Ce programme charge d'abord le module Qt [line 1] puis crée l'objet application $a en lui passant une référence au tableau @ARGV contenant les arguments de la ligne de commande [l.2]. Cet objet application est unique pour un interpréteur Perl donné et peut être ensuite accédé par la fonction pure Qt::app().

La ligne 3, crée un PushButton orphelin (c.à.d sans parent: non contenu dans un autre widget) dont nous passons la valeur undef comme argument pour le parent. undef est l'équivalent perlQt d'un pointeur null en C++.

Après les instructions de "mise en page" [l.4], nous indiquons à l'objet application que le widget principal est ce PushButton... Ainsi, il saura que fermer la fenêtre associée à ce widget signifie: sortir de l'application.

Pour rendre ce widget visible (qui est par défaut caché), on appelle la méthode show [l.6] et lance la boucle événementielle [l.7].

Sommaire de la syntaxe :

1. Les classes PerlQt sont accessibles par le préfixe Qt:: au lieu du Q initial des classes Qt en C++. En consultant la documentation Qt, vous devez donc mentalement changer le nom d'une clasee QFoo en Qt::Foo.

2. De manière similaire à C++, un objet est créé par l'appel d'un constructeur de même nom que la classe dont il est une méthode.

   Vous ne devez donc pas dire new Qt::Foo or Qt::Foo->new() contrairement à l'usage commun en Perl.

   Vous écrivez donc simplement:

   my $object = Qt::<classname>(arg_1, ..., arg_n);

   Un constructeur sans argument s'énonce encore plus brièvement :

   my $object = Qt::<classname>;

3. Comme déjà dit, l'équivalent Perl d'un pointeur C++ est le mot-clé Perl undef.

   Les pointeurs sont les arguments précédés par le caractère * dans la documentation Qt (Par exemple: "QWidget* widget").

L'héritage et les objets

Avant d'expliquer comment les routines Perl peuvent être appelées de Qt, parlons du mécanisme d'héritage vu de PerlQt.

PerlQt est conçu pour allier la simplicité de Qt à la puissance et à la flexibilité de Perl. Pour ce faire, PerlQt étend le paradigme objet de Perl pour mimer Qt et son mécanisme de métaobjets.

Un Widget perso

Réécrivons le programme "Hello World!" avec une version perso de PushButton:

 1: use strict;
 2:
 3: package Button;
 4: use Qt;
 5: use Qt::isa qw(Qt::PushButton);
 6:
 7: sub NEW
 8: {
 9:   shift->SUPER::NEW(@_[0..2]);
10:   resize(130, 40);
11: }
12:
13: 1;
14:
15: package main;
16:
17: use Qt;
18: use Button;
19:
20: my $a = Qt::Application(\@ARGV);
21: my $w = Button("Hello World!", undef);
22: $a->setMainWidget($w);
23: $w->show;
24: exit $a->exec;

Pour implanter notre propre version de PushButton, nous créons un nouveau package [l.3] et importons Qt [l.4].

Nous utilisons le pragma Qt::isa [l.5] pour déclarer notre widget comme sous-classe de PushButton. Ce pragma accepte une liste de une ou plusieurs classes dont dérive la classe à définir.

Créons maintenant un constructeur pour notre nouveau widget en écrivant une routine appelée NEW (notez les majuscules qui marquent une méthode différente du constructeur "new" usuel). Le constructeur PerlQt est appelé implicitement comme ligne 21.

Note widget doit d'abord appeler le constructeur de sa classe de base (ici: Qt::PushButton) on line 9, avec tous les arguments que nous avons reçus.

Nous créons ainsi un objet instance de notre classe. Cette objet est accessible par la fonction this (Attention: ce n'est pas la variable $this mais simplement this).

Chaque fois que nous invoquons une méthode à partir de notre package nous pouvons écrire indifféremment method() ou this->method();

L'utilisation d'attributs

Lors de la construction d'un objet composite, vous pouvez simplement créer ses différents composants à l'intérieur de variables de scope lexical (c.à.d déclarées par my) puisque les widgets sont seulement détruits par leur parent et non nécessairement quand leur conteneur disparaît du scope.

En d'autres termes, PerlQt utilise le système de comptage de références pour gérer la destruction des objets.

Souvent cependant, vous souhaiterez accéder aux composants de votre objet depuis un tout autre endroit que celui où vous l'avez créé (par exemple pour modifier une légende de bouton dynamiquement). Dans ce cas, la syntaxe traditionnelle de perl propose de stocker une référence à ces composants dans la table associative (hash) de l'objet lui-même. Mais cette syntaxe s'avère peu pratique à l'usage et beaucoup trop libre - il n'y a pas de vérification à la compilation de sorte que vous pouvez accéder à des clefs non existantes sans déclencher d'erreur.

En lieu et place de cette syntaxe, PerlQt introduit le concept d'attributs.

Les attributs sont de simples variables perl, écrites sans le signe dollar initial, et pouvant contenir toute donnée qui est une propriété de votre objet. Leur principal avantage est de fournir une syntaxe très rapide et vérifiable à la compilation.

Pour définir et pouvoir utiliser de nouveaux attributs, il suffit d'utiliser le pragma use Qt::attributes, suivi d'une liste des noms d'attributs souhaités. Ainsi:

 1: use strict;
 2:
 3: package Button;
 4: use Qt;
 5: use Qt::isa qw(Qt::PushButton);
 6: use Qt::attributes qw(
 7:     itsTime
 8:     pData
 9: );
10:
11: sub NEW
12: {
13:   shift->SUPER::NEW(@_[0..2]);
14:   itsTime = Qt::Time;
15:   itsTime->start;
16:   pData->{'key'} = " Foo ";
17: }
18:
19: sub resizeEvent
20: {
21:    setText( "w: ". width() ." h: ". height() .
22:             "\nt: ". itsTime->elapsed . pData->{'key'} );
23: }
24:
25: 1;

L'attribut itsTime est déclaré à la ligne 7 et initialisé par un objet Qt::Time à la ligne 14.

Puisque nous réimplémentons la fonction virtuelle "resizeEvent" [l.19], chaque fois que le widget principal est redimensionné, cette fonction "resizeEvent" sera déclenchée et le texte de notre Button mis à jour avec les valeurs venant de l'objet [1.21] et les attributs que nous avons définis [1.22].

Récapitulation

• Pour hériter d'une classe Qt, un package doit contenir un pragma use Qt::isa.

  Ainsi:

  use Qt::isa "Qt::widget";

• Le constructeur d'objet est nommé NEW et est appelé implicitement. Vous ne devez donc pas dire:

  my $o = MyButton->NEW("Hello");

  Mais bien :

  my $o = MyButton("Hello");

• A l'intérieur d'un package, on accéde l'instance courante par la fonction this.

  Quand une fonction membre est appelée, les arguments sont accessibles par le tableau @_, mais le premier élément de @_ n'est pas une référence à l'objet contrairement à l'usage commun en Perl.

  Vous ne pouvez donc pas dire :

  sub myMember
  {
    my $moi = shift;
    my $arg = shift;
    $arg->doThat($moi);
    $moi->doIt;
  }

  Écrivez plutôt :

  sub myMember
  {
    my $arg = shift;
    $arg->doThat(this);
    doIt();
  }

  De plus, si vous voulez appeler une méthode dans une classe de base à partir d'une classe dérivée, utilisez l'attribut spécial SUPER :

  sub exemple
  {
    print "Appel de la méthode 'exemple' dans la classe de base";
    SUPER->exemple(@_)
  }

  Notez aussi que la construction :

  this->SUPER::Exemple(@_);

  est possible, mais qu'elle passe l'objet comme premier argument.

• Lorsque vous devez stocker dans votre package un objet contenu, vous devez le définir comme attribut :

   use Qt::attributes qw(
  	firstAttribute
  	...
  	lastAttribute);

  Il sera alors disponible comme accesseur :

  firstAttribute = myContainedWidget( this );
  firstAttribute->resize( 100, 100 );

  NB: Pour ceux qui souhaitent en savoir plus, les attributs sont implémentés à l'aide de sub lvalue, c'est à dire de fonctions assignables. En interne, elles ne font que pointer sur la clef de hachage correspondante dans l'objet this, ce qui rend les tournures "unAttribut->fonction()" et "this->{'unAttribut'}->fonction()" strictement équivalentes.

• Pour réimplémenter une fonction virtuelle, créez simplement une sub de même nom que l'objet.

Signaux et Slots

Voyons maintenant comment les objets Qt peuvent communiquer entre eux de manière à ce qu'un événement concernant un objet puisse déclencher l'exécution d'une routine en un quelconque endroit de votre programme.

Dans d'autres toolkits, les callbacks (appels en retour) sont généralement utilisés à cet effet. Mais Qt dispose d'un mécanisme beaucoup plus puissant et plus flexible : les Signaux et Slots.

On peut se le représenter comme le cablage entre les composants d'une chaîne Hi-Fi. Un amplificateur, par exemple, émet des signaux de sortie sans chercher à savoir si des enceintes lui sont connectées ou non. Un magnétophone peut attendre un signal sur sa prise d'entrée pour commencer à enregistrer, et il ne cherchera pas non plus à savoir s'il est l'unique destinataire de ce signal ou s'il est aussi reçu par un graveur de CD ou écouté au casque.

Un composant Qt se comporte comme notre amplificateur ou notre magnétophone. Il a des sorties ou Signaux et des entrées ou Slots. Chaque sortie (signal) est connectable à un nombre illimité d'entrées (slots). La sortie d'un composant peut être potentiellement branchée à tout entrée d'un composant (y compris lui-même),

La syntaxe de ce système de connexion est soit:

Qt::Object::connect( envoyeur, SIGNAL 'mon_signal(types_d_arguments)', recepteur, SLOT 'monslot(types_d_arguments)');

soit:

unObjet->connect( envoyeur, SIGNAL 'mon_signal(types_d_arguments)', SLOT 'monslot(types_d_arguments)');

Dans le second cas, le récepteur est omis car c'est l'objet lui-même,

Ce mécanisme est extensible à volonté par la déclaration de nouveaux Signaux et Slots par l'usage des pragma use Qt::signals et use Qt::slots.

Chaque slot déclaré appellera la routine correspondante de votre objet. Chaque signal déclaré peut être déclenché via le mot-clé emit.

Réécrivons encore notre exemple pour illustrer nos propos :

 1: use strict;
 2:
 3: package Button;
 4: use Qt;
 5: use Qt::isa qw(Qt::PushButton);
 6: use Qt::attributes qw(itsTime);
 7: use Qt::slots
 8:     aEteClicke => [],
 9:     changement     => ['int', 'int'];
10: use Qt::signals
11:     changeLe   => ['int', 'int'];
12:
13: sub NEW
14: {
15:   shift->SUPER::NEW(@_[0..2]);
16:   itsTime = Qt::Time;
17:   itsTime->start;
18:   this->connect(this, SIGNAL 'clicked()', SLOT 'aEteClicke()');
19:   this->connect(this, SIGNAL 'changeLe(int,int)', SLOT 'changement(int,int)');
20: }
21:
22: sub aEteClicke
23: {
24:    my $w = width();
25:    my $h = height();
26:    setText( "w: $w h: $h\nt: ". itsTime->elapsed );
27:    emit changeLe($w, $h);
28: }
29:
30: sub changement
31: {
32:    my ($w, $h) = @_;
33:    print STDERR "w: $w h: $h \n";
34: }
35:
36: 1;

Nous définissons dans ce package deux nouveaux slots et un nouveau signal.

La documentation Qt nous dit que tout PushButton clické émet un signal clicked() ; nous le connectons donc à notre nouveau slot [ligne 18].

Nous connectons aussi notre signal ChangeLe à notre slot changement.

Ainsi, quand on appuie (clique) sur notre Button , le signal clicked() est émit et déclenche le slot aEteClicke(). aEteClicke() émet à son tour le signal changeLe(int,int)[l.27], appelant de ce fait le slot changement(int,int), avec deux arguments.

Développement rapide (RAD) avec Qt Designer et Puic

Introduction

Aussi puissant et intuitif que Qt soit, écrire un GUI complet est une corvée.

Heureusement, Qt est fourni avec un constructeur de GUI sophistiqué appelé Qt Designer qui est quasiment un environnement de développement intégré. Il comporte la gestion de Projets, la création d'un GUI par des actions de "drag and drop", un butineur d'objet complet, l'interconnexion graphique de signaux et de slots, et plus encore.

L'information générée par Qt Designer's est en format XML et peut donc être parsée par différentes commandes comme dont puic (le compilateur d'interface utilisateur PerlQt).

Supposons que vous avez déja construit un fichier d'interface avec Qt Designer, la transcription en un programme PerlQt se fait par la simple exécution de la commande :

puic -x -o program.pl program.ui

Cela génèrera le package défini dans votre fichier ui et un package principal à fins de test,

Vous pouvez préférer :

puic -o package.pm program.ui

Cela ne générera que le package qui pourra être utilisé par un programme séparé.

Inclure des Images

Il y a deux manières d'inclure des images ou icônes:

• Inclusion Inline

  A cette fin, nous devons sélectionner "Edit->Form Settings->Pixmaps->Save inline" dans Qt Designer et executer ensuite:

  puic -x -o F<program.pl> F<program.ui>

• Image Collection

  Cette stratégie est plus complexe, mais plus propre et plus puissante.

  puic -o F<Collection.pm> -embed F<unique_identifier> F<image-1> ... F<image-n>

  Ajoutez l'instruction use Collection.pm dans le package principal de votre programme.

  Si vous avez créé un fichier projet dans Qt Designer et ajouté toutes les images dans un groupe (par "Project->Image Collection"), vous disposez ensuite de ces images dans le répertoire où votre fichier projet (*.pro) est stocké, dans le sous-répertoire image. Vous pouvez alors générer la collection d'images par:

  puic -o F<Collection.pm> -embed F<identifier> images/*

  Vous pouvez utiliser autant de collections d'images que vous voulez dans un programme en ajoutant simplement une instruction use pour chaque collection.

Travailler avec des fichiers .ui

Souvent, vous voudrez regénérez votre interface utilisateur à à cause d'une modification ou extension de votre design initial. C'est donc une mauvais idée d'écrire votre code dans le fichier Perl autogénéré car vous risquerez d'écraser le code que vous avez écrit manuellement ou vous devrez faire des copier-coller intensifs.

Voici une meilleure méthode :

• Écrire l'implantaton de slots dans le Designer

  Dans Qt Designer, selectionnez l'onglet Source dans l'explorateur d'objets (Object Explorer). Vous pouvez ainsi voir représentées sous forme d'arbre les classes que vous avez générées. Maintenant, si vous cliquez deux fois sur l'entrée Slots/public, un dialogue vous demande si vous voulez créer un nouveau slot pour votre module. Une fois cela fait, le nouveau slot apparait à l'intérieur de l'arbre l'explorateur d'objet; cliquer dessus vous amènera à votre fichier <Votre Classe>.ui.h où vous pouvez écrire l'implémentation de votre slot.

  Par défaut, il devrait ressembler à ceci :

  void Form1::newSlot()
  {
  
  }

  La déclaration du slot est réellement du code C++, mais ignorons cela et écrivons du code Perl entre les deux accolades en faisant bien attention d'indenter notre code avec au moins un espace.

  void Form1::newSlot()
  {
      print STDERR "Hello world from Form1::newSlot();
      if(this->foo())
      {
          # faire quelque chose
      }
  }

  Notre code Perl ainsi écrit sera sauvé dans le fichier ui.h et puic prendra soin de le placer dans notre programme final.

  Ici, après l'exécution de puic sur le ficier Form1.ui, vous devriez avoir:

  sub newSlot
  {
      print STDERR "Hello world from Form1::newSlot();
      if(this->foo())
      {
          # faire quelque chose
      }
  }

• Sous-classez votre GUI

  En utilisant l'option -subimpl de puic, vous pouvez générer un module dérivé qui hérite l'interface utilisateur originelle.

  Typiquement, vous générez le module dérivé une fois, et écrivez votre code dans ce module dérivé. Ainsi, quand vous devez modifier votre module GUI, regénérez le module dont il dérive et il héritera les changements.

  Pour générer le module de base :

  puic -o Form1.pm form1.ui

  (faîtes cela aussi souvent que nécessaire: n'éditez jamais manuellement form1.ui puisqu'il serait écrasé)

  Pour générer le GUI dérivé :

  puic -o Form2.pm -subimpl Form2 form1.ui

  ou

  puic -o program.pl -x -subimpl Form2 form1.ui

  (faites cela une fois et travaillez avec le fichier résultant)

Crédits

PerlQt-3 est (c) 2002 Ashley Winters

Kalyptus et l'engin de génération Smoke sont (c) David Faure and Richard Dale

Puic is (c) TrollTech AS., Phil Thompson et Germain Garand,

Ledit logiciel est délivré sous la GNU Public Licence v.2 or later.

Appendice: Comment utiliser la Documentation Qt

Lorsque vous voulez utiliser depuis PerlQt une classe ou méthode décrite dans la documentation Qt, vous devez suivre des règles de translation simples décrites ci-dessous

Noms de classe

• Les noms de classes utilisent le préfixe Qt:: au lieu de Q pour être conforme à l'usage Perl. Ainsi: QComboBox est nommé Qt::ComboBox dans PerlQt.

Fonctions

• Les fonctions décrites comme static sont accédées directement et non à travers un objet. Ainsi la fonction statique Foo de la classe QBar peut être accédée de PerlQt par

  Qt::Bar::Foo( arg-1,...,arg-n);

• Les fonctions décrites comme members ou Signals sont accessibles à travers l'objet par l'opérateur -> . Par exemple:

  $widget->show;

  Il n'y a pas de différence fondamentale entre les méthodes et les signaux, néanmoins PerlQt fournit le mot-clé emit comme une mnémonique pratique pour rendre clair que vous émettez un signal :

  emit $button->clicked;

Arguments

• Par valeur

  Lorsqu'un argument n'est pas précédé par un des caractères & or *, il est passé par valeur. Pour tous les types basiques tels que int, char, float and double, PerlQt convertira automatiquement les valeurs litérales et scalaires dans le type correspondants C++.

  Ainsi pour le prototype d'un constructeur écrit dans la documentation comme ceci: QSize ( int w, int h )

  Vous écrirez :

  Qt::Size(8, 12);

• Par référence

  Lorsqu'un argument est précédé par le caractère &, Il est une référence à un objet ou à un type. Vous pouvez alors fournir un nom de variable ou un objet temporaire :

  $keyseq = Qt::keySequence( &Qt::CTRL + &Qt::F3 );
  $widget->setAccel( $keyseq );

  ou

  $widget->setAccel(Qt::keySequence( &Qt::CTRL + &Qt::F3 );

  Si l'argument n'est pas qualifié par const (constante), l'argument est un objet qui peut être altéré par la méthode, vous devez donc passer une variable.

• Par pointeur

  Lorsqu'un argument est précédé par le caractère *, un pointeur vers un objet ou un type est attendu. En PerlQt, vous pouvez fournir un nom de variable ou le mot clé undef à la place du pointer Null.

  De plus, si l'argument est const, l'objet passé en argument est en lecture seule: il ne peut pas être modifié.

Énumérations

Les Énumerations sont une forme d'alias pour des valeurs numériques dont il serait autrement difficile de se souvenir:

Exemple C++:

enum Strange { Apple, Orange, Lemon }

Ici, Strange est le type (au sens de C++) de l'énumération, et Apple, Orange et Lemon ses valeurs possible , qui sont des aliases pour des nombres (ici 0, 1 et 2)

L'accès aux valeurs d'énumération en Perl Qt est un appel de fonction statique.

Donc, si vous voulez éviter des prblèmes de lisibilité, nous vous recommandons l'usage d'une syntaxe alternative d'appel de fonction pour marquer l'utilisation d'un alias d'énumération: &fonction.

Revenons à notre exemple Strange.

Si nous rencontrons sa définition dans la classe QFruits, vous écrirez en PerlQt :

$pomme_plus_orange = &Qt::Fruit::Pomme + &Qt::Fruit::Orange;

cpanm Ast

perl -MCPAN -e shell
install Ast