GRAVATTJ / Util-Medley-0.040 / lib / Util / Medley / Spawn.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
—
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
—
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
—
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
—
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197

              
package Util::Medley::Spawn;
$Util::Medley::Spawn::VERSION = '0.040';
###############################################################################
use Modern::Perl;
use Moose;
use namespace::autoclean;
use Data::Printer alias => 'pdump';
use Carp;
use IPC::Run3 'run3';
use Kavorka '-all';
with 'Util::Medley::Roles::Attributes::Logger';
=head1 NAME
Util::Medley::Spawn - utility methods for system commands
=head1 VERSION
version 0.040
=head1 SYNOPSIS
...
=cut
###############################################################################
=head1 ATTRIBUTES
=head2 confessOnError (optional)
Toggle for to enable/disable confess on error.  Default is 1.
=cut
has confessOnError => (
        is      => 'rw',
        isa     => 'Bool',
        default => 1,
);
###############################################################################
=head1 METHODS
=head2 capture
Executes system command and returns the stdout, stderr, and exit values.  Will
write to log if enabled.
=over
=item usage:
 ($stdout, $stderr, $exit) = $util->capture($cmd, [$stdin], [$wantArrayRef])
  
 ($stdout, $stderr, $exit) = $util->capture(cmd   => $cmd, 
                                           [stdin => $stdin],
                                           [wantArrayRefs => $wantArrayRef])
  
=item args:
=over
=item cmd [ArrayRef|Str]
System command to invoke.  Can be an arrayref or a string.
=item stdin [ArrayRef|Str] (optional)
Stdin to pass to the command.
=item wantArrayRef [Bool]
If true, returns stdout and stderr as array refs instead of strings.  Default
is 0.
=back
=back
=cut
multi method capture(
        ArrayRef|Str :$cmd !,
        ArrayRef|Str :$stdin,
                Bool :$wantArrayRef
  )
{
        my $cmdStr;
        if ( ref($cmd) eq 'ARRAY' ) {
                $cmdStr = join( ' ', @$cmd );
        }
        else {
                $cmdStr = $cmd;
        }
        $self->Logger->verbose($cmdStr);
        my ( $stdout, $stderr, $exit );
        my $rc = run3 $cmd, \$stdin, \$stdout, \$stderr;
        $exit = $? >> 8;
        if ( !$rc or $exit ) {
                if ( $self->confessOnError ) {
                        my $msg =
                          sprintf
                          "run3 failed for cmd: exit=%s cmd='%s' stdout='%s' stderr='%s'",
                          $exit, $cmdStr, $stdout, $stderr;
                        confess $msg;
                }
        }
        chomp $stdout;
        chomp $stderr;
        if ($wantArrayRef) {
                return ( [ split( /\n/, $stdout ) ], [ split( /\n/, $stderr ) ],
                        $exit );
        }
        return ( $stdout, $stderr, $exit );
}
multi method capture(ArrayRef|Str $cmd, 
                     ArrayRef|Str $stdin
        ? )
{
        my %a;
        $a{cmd}   = $cmd;
        $a{stdin} = $stdin if $stdin;
        return $self->capture(%a);
}
=head2 spawn
Executes system command and returns the exit value.  Will write to log 
if enabled.
=over
=item usage:
 $exit = $util->spawn($cmd);
 $exit = $util->spawn(cmd => $cmd);
   
=item args:
=over
=item cmd [ArrayRef|Str]
System command to invoke.  Can be an arrayref or a string.
=back
=back
=cut
multi method spawn(ArrayRef|Str :$cmd! ) {
        if ( ref($cmd) eq 'ARRAY' ) {
                $self->Logger->verbose( join( ' ', @$cmd ) );
                system(@$cmd);
        }
        else {
                $self->Logger->verbose($cmd);
                system($cmd);
        }
        my $exit = $? >> 8;
        if ($exit) {
                if ( $self->confessOnError ) {
                        confess "last command failed with exit code $exit";
                }
        }
        return $exit;
}
multi method spawn(ArrayRef|Str $cmd) {
        return $self->spawn( cmd => $cmd );
}
##############################################
1;