NAME

AnyEvent::Redis::RipeRedis - Non-blocking Redis client with auto reconnect feature

SYNOPSIS

use AnyEvent;
use AnyEvent::Redis::RipeRedis;

my $cv = AnyEvent->condvar();

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'localhost',
  port => '6379',
  password => 'your_password',
  encoding => 'utf8',

  on_connect => sub {
    print "Connected\n";
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
);

# Set value
$redis->set( 'bar', 'Some string', {
  on_done => sub {
    my $data = shift;
    print "$data\n";
    $cv->send();
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
    $cv->croak();
  },
} );

$cv->recv();

DESCRIPTION

AnyEvent::Redis::RipeRedis is a non-blocking Redis client with auto reconnect feature. It supports subscriptions, transactions, has simple API and it faster than AnyEvent::Redis.

Requires Redis 1.2 or higher and any supported event loop.

CONSTRUCTOR

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'localhost',
  port => '6379',
  password => 'your_password',
  connection_timeout => 5,
  reconnect => 1,
  encoding => 'utf8',

  on_connect => sub {
    print "Connected\n";
  },

  on_disconnect => sub {
    print "Disconnected\n";
  }

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
);

host

Server hostname (default: 127.0.0.1)

port

Server port (default: 6379)

password

Authentication password. If it specified, client sends AUTH command after establishing a connection. If it not specified, you can send AUTH command yourself.

connection_timeout

Connection timeout. If after this timeout client could not connect to the server, callback "on_error" will be called.

reconnect

If this parameter is TRUE, client in case of lost connection will automatically reconnect during executing next command. If this parameter is FALSE, client don't reconnect automaticaly. By default is TRUE.

encoding

Will be used to encode strings before sending them to the server and to decode strings after receiving them from the server. If this parameter not specified, encode and decode operations not performed.

on_connect

This callback will be called when connection will be established

on_disconnect

This callback will be called in case of disconnection

on_error

This callback will be called if occurred any errors

COMMAND EXECUTION

<command>( [ @cmd_args[, \%params ] ] )

# Increment
$redis->incr( 'foo', {
  on_done => sub {
    my $data = shift;
    print "$data\n";
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
} );

# Set value
$redis->set( 'bar', 'Some string' );

# Get value
$redis->get( 'bar', {
  on_done => sub {
    my $data = shift;
    print "$data\n";
  },
} );

# Push values
for ( my $i = 1; $i <= 3; $i++ ) {
  $redis->rpush( 'list', "element_$i", {
    on_done => sub {
      my $data = shift;
      print "$data\n";
    },
  } );
}

# Get list of values
$redis->lrange( 'list', 0, -1, {
  on_done => sub {
    my $data = shift;
    foreach my $val ( @{ $data } ) {
      print "$val\n";
    }
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
} );

Full list of Redis commands can be found here: http://redis.io/commands

SUBSCRIPTIONS

subscribe( @channels[, \%params ] )

Subscribe to channel by name

$redis->subscribe( qw( ch_foo ch_bar ), {
  on_done =>  sub {
    my $ch_name = shift;
    my $subs_num = shift;

    print "Subscribed: $ch_name. Active: $subs_num\n";
  },

  on_message => sub {
    my $ch_name = shift;
    my $msg = shift;

    print "$ch_name: $msg\n";
  },
} );

psubscribe( @patterns[, \%params ] )

Subscribe to group of channels by pattern

$redis->psubscribe( qw( info_* err_* ), {
  on_done =>  sub {
    my $ch_pattern = shift;
    my $subs_num = shift;

    print "Subscribed: $ch_pattern. Active: $subs_num\n";
  },

  on_message => sub {
    my $ch_name = shift;
    my $msg = shift;
    my $ch_pattern = shift;

    print "$ch_name ($ch_pattern): $msg\n";
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
} );

unsubscribe( @channels[, \%params ] )

Unsubscribe from channel by name

$redis->unsubscribe( qw( ch_foo ch_bar ), {
  on_done => sub {
    my $ch_name = shift;
    my $subs_num = shift;

    print "Unsubscribed: $ch_name. Active: $subs_num\n";
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
} );

punsubscribe( @patterns[, \%params ] )

Unsubscribe from group of channels by pattern

$redis->punsubscribe( qw( info_* err_* ), {
  on_done => sub {
    my $ch_pattern = shift;
    my $subs_num = shift;

    print "Unsubscribed: $ch_pattern. Active: $subs_num\n";
  },

  on_error => sub {
    my $err = shift;
    warn "$err\n";
  },
} );

CONNECTION VIA UNIX-SOCKET

Redis 2.2 and higher support connection via UNIX domain socket. To connect via a UNIX-socket in the parameter "host" you must specify "unix/", and in parameter "port" you must specify the path to the socket.

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'unix/',
  port => '/tmp/redis.sock',
);

SEE ALSO

AnyEvent, AnyEvent::Redis, Redis, Redis::hiredis

AUTHOR

Eugene Ponizovsky, <ponizovsky@gmail.com>

Special thanks to:

Alexey Shrub

Vadim Vlasov

Konstantin Uvarin

COPYRIGHT AND LICENSE

Copyright (c) 2012, Eugene Ponizovsky, <ponizovsky@gmail.com>. All rights reserved.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

cpanm AnyEvent::Redis::RipeRedis

perl -MCPAN -e shell
install AnyEvent::Redis::RipeRedis