NAME

AnyEvent::Redis::RipeRedis - Flexible non-blocking Redis client with reconnect feature

SYNOPSIS

use AnyEvent;
use AnyEvent::Redis::RipeRedis qw( :err_codes );

my $cv = AnyEvent->condvar();

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'localhost',
  port => '6379',
  password => 'your_password',
  encoding => 'utf8',

  on_connect => sub {
    print "Connected to Redis server\n";
  },

  on_disconnect => sub {
    print "Disconnected from Redis server\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;
    warn "$err_msg. Error code: $err_code\n";
  },
);

# Set value
$redis->set( 'foo', 'Some string', {
  on_done => sub {
    my $data = shift;

    print "$data\n";
    $cv->send();
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  }
} );

$cv->recv();

$redis->disconnect();

DESCRIPTION

AnyEvent::Redis::RipeRedis is a non-blocking flexible Redis client with reconnect feature. It supports subscriptions, transactions, has simple API and it faster than AnyEvent::Redis.

Requires Redis 1.2 or higher, and any supported event loop.

CONSTRUCTOR

new()

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'localhost',
  port => '6379',
  password => 'your_password',
  database => 7,
  lazy => 1,
  connection_timeout => 5,
  reconnect => 1,
  encoding => 'utf8',

  on_connect => sub {
    print "Connected to Redis server\n";
  },

  on_disconnect => sub {
    print "Disconnected from Redis server\n";
  },

  on_connect_error => sub {
    my $err_msg = shift;
    warn "$err_msg\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    warn "$err_msg. Error code: $err_code\n";
  },
);

host

Server hostname (default: 127.0.0.1)

port

Server port (default: 6379)

password

Authentication password. If it specified, then AUTH command will be send immediately to the server after successfully connection and after every successfully reconnection.

database

Database index. If it set, then client will be switched to specified database immediately after successfully connection and after every successfully reconnection.

Default database index is 0.

connection_timeout

Connection timeout. If after this timeout client could not connect to the server, callback on_error is called. By default used kernel's connection timeout.

lazy

If this parameter is set, then connection will be established, when you will send a first command to the server. By default connection establishes after calling method new.

reconnect

If this parameter is TRUE and connection to the Redis server was lost, then client will try to reconnect to server while executing next command. Client try to reconnect only once and if fails, calls on_error callback. If you need several attempts of reconnection, just retry command from on_error callback as many times, as you need. This feature made client more responsive.

By default is TRUE.

encoding

Used to encode an decode strings during input/output operations. Not set by default.

on_connect => $cb->()

Callback on_connect is called, when connection is successfully established. Not set by default.

on_disconnect => $cb->()

Callback on_disconnect is called, when connection is closed by any reason. Not set by default.

on_connect_error => $cb->( $err_msg )

Callback on_connect_error is called, when the connection could not be established. If this collback isn't specified, then on_error callback is called.

on_error => $cb->( $err_msg, $err_code )

Callback on_error is called, when any error occurred. If callback is no set, client just print error message to STDERR.

COMMAND EXECUTION

<command>( [ @args[, \%params ] ] )

# Set value
$redis->set( 'foo', 'Some string' );

# Increment
$redis->incr( 'bar', {
  on_done => sub {
    my $data = shift;

    print "$data\n";
  },
} );

# Get list of values
$redis->lrange( 'list', 0, -1, {
  on_done => sub {
    my $data = shift;

    foreach my $val ( @{ $data } ) {
      print "$val\n";
    }
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  },
} );

Full list of Redis commands can be found here: http://redis.io/commands

on_done => $cb->( [ $data ] ): Callback on_done is called, when response successfully received.
on_error => $cb->( $err_msg, $err_code ): Callback on_error is called, when any error occurred.

SUBSCRIPTIONS

Subscribe to channels by name.

$redis->subscribe( qw( ch_foo ch_bar ), {
  on_done =>  sub {
    my $ch_name = shift;
    my $subs_num = shift;

    print "Subscribed: $ch_name. Active: $subs_num\n";
  },

  on_message => sub {
    my $ch_name = shift;
    my $msg = shift;

    print "$ch_name: $msg\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  },
} );

on_done => $cb->( $ch_name, $sub_num ): Callback on_done is called, when subscription is done.
on_message => $cb->( $ch_name, $msg ): Callback on_message is called, when published message is successfully received.
on_error => $cb->( $err_msg, $err_code ): Callback on_error is called, when any error occurred.

psubscribe( @patterns[, \%params ] )

Subscribe to group of channels by pattern.

$redis->psubscribe( qw( info_* err_* ), {
  on_done =>  sub {
    my $ch_pattern = shift;
    my $subs_num = shift;

    print "Subscribed: $ch_pattern. Active: $subs_num\n";
  },

  on_message => sub {
    my $ch_name = shift;
    my $msg = shift;
    my $ch_pattern = shift;

    print "$ch_name ($ch_pattern): $msg\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  },
} );

on_done => $cb->( $ch_pattern, $sub_num ): Callback on_done is called, when subscription is done.
on_message => $cb->( $ch_name, $msg, $ch_pattern ): Callback on_message is called, when published message is successfully received.
on_error => $cb->( $err_msg, $err_code ): Callback on_error is called, when any error occurred.

unsubscribe( @channels[, \%params ] )

Unsubscribe from channels by name.

$redis->unsubscribe( qw( ch_foo ch_bar ), {
  on_done => sub {
    my $ch_name = shift;
    my $subs_num = shift;

    print "Unsubscribed: $ch_name. Active: $subs_num\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  },
} );

on_done => $cb->( $ch_name, $sub_num ): Callback on_done is called, when unsubscription is done.
on_error => $cb->( $err_msg, $err_code ): Callback on_error is called, when any error occurred.

punsubscribe( @patterns[, \%params ] )

Unsubscribe from group of channels by pattern.

$redis->punsubscribe( qw( info_* err_* ), {
  on_done => sub {
    my $ch_pattern = shift;
    my $subs_num = shift;
    print "Unsubscribed: $ch_pattern. Active: $subs_num\n";
  },

  on_error => sub {
    my $err_msg = shift;
    my $err_code = shift;

    $cv->croak( "$err_msg. Error code: $err_code" );
  },
} );

on_done => $cb->( $ch_pattern, $sub_num ): Callback on_done is called, when unsubscription is done.
on_error => $cb->( $err_msg, $err_code ): Callback on_error is called, when any error occurred.

CONNECTION VIA UNIX-SOCKET

Redis 2.2 and higher support connection via UNIX domain socket. To connect via a UNIX-socket in the parameter host you have to specify unix/, and in the parameter port you have to specify the path to the socket.

my $redis = AnyEvent::Redis::RipeRedis->new(
  host => 'unix/',
  port => '/tmp/redis.sock',
);

LUA SCRIPTS EXECUTION

Redis 2.6 and higher support execution of the Lua scripts on the server side. To execute a Lua script you can use one of the commands EVAL or EVALSHA, or you can use special method eval_cached().

eval_cached( $script, $numkeys[, [ @keys, ] [ @args, ] \%params ] );

When you call eval_cached() method, client first evaluate SHA1 hash for the Lua script and cache it in memory. Then client optimistically send EVALSHA command under the hood. If NO_SCRIPT error will be returned, client send EVAL command.

If you call eval_cached() method with the same Lua script, client get SHA1 hash for this script from cache and don't evaluate it repeatedly.

$redis->eval_cached( 'return { KEYS[1], KEYS[2], ARGV[1], ARGV[2] }',
    2, 'key1', 'key2', 'first', 'second', {
  on_done => sub {
    my $data = shift;
    foreach my $val ( @{ $data } ) {
      print "$val\n";
    }
  }
} );

ERROR CODES

Error codes can be used for programmatic handling of errors.

1  - E_CANT_CONN
2  - E_LOADING_DATASET
3  - E_IO
4  - E_CONN_CLOSED_BY_REMOTE_HOST
5  - E_CONN_CLOSED_BY_CLIENT
6  - E_NO_CONN
7  - E_INVALID_PASS
8  - E_OPRN_NOT_PERMITTED
9  - E_OPRN_ERROR
10 - E_UNEXPECTED_DATA
11 - E_NO_SCRIPT

E_CANT_CONN

Can't connect to server.

E_LOADING_DATASET

Redis is loading the dataset in memory.

E_IO

Input/Output operation error. Connection closed.

E_CONN_CLOSED_BY_REMOTE_HOST

Connection closed by remote host.

E_CONN_CLOSED_BY_CLIENT

Connection closed unexpectedly by client.

Error occur, if at time of disconnection in client queue were uncompleted commands.

E_NO_CONN

No connection to the server.

Error occur, if at time of command execution connection has been closed by any reason and parameter reconnect was set to FALSE.

E_INVALID_PASS

Invalid password.

E_OPRN_NOT_PERMITTED

Operation not permitted. Authentication required.

E_OPRN_ERROR

Operation error. Usually returned by the Redis server.

E_UNEXPECTED_DATA

Client received unexpected data from server.

E_NO_SCRIPT

No matching script. Use EVAL command.

To use these constants you have to import them.

use AnyEvent::Redis::RipeRedis qw( :err_codes );

DISCONNECTION

When the connection to the server is no longer needed you can close it in three ways: call method disconnect(), send QUIT command or you can just "forget" any references to an AnyEvent::Redis::RipeRedis object, but in this case client object destroying silently without calling any callbacks including on_disconnect callback to avoid unexpected behavior.

disconnect()

Method for synchronous disconnection.

$redis->disconnect();

AUTHOR

Eugene Ponizovsky, <ponizovsky@gmail.com>

Special thanks

Alexey Shrub
Vadim Vlasov
Konstantin Uvarin

COPYRIGHT AND LICENSE

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

To install AnyEvent::Redis::RipeRedis, copy and paste the appropriate command in to your terminal.

cpanm

cpanm AnyEvent::Redis::RipeRedis

CPAN shell

perl -MCPAN -e shell
install AnyEvent::Redis::RipeRedis

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)