/ 
Mail-DKIM-0.33_7
River stage one • 3 direct dependents • 7 total dependents
/ Mail::DKIM::Signer

NAME

Mail::DKIM::Signer - generates a DKIM signature for a message

SYNOPSIS

use Mail::DKIM::Signer;

# create a signer object
my $dkim = Mail::DKIM::Signer->new(
                Algorithm => "rsa-sha1",
                Method => "relaxed",
                Domain => "example.org",
                Selector => "selector1",
                KeyFile => "private.key",
           );

# read an email from a file handle
$dkim->load(*STDIN);

# or read an email and pass it into the signer, one line at a time
while (<STDIN>)
{
    # remove local line terminators
    chomp;
    s/\015$//;

    # use SMTP line terminators
    $dkim->PRINT("$_\015\012");
}
$dkim->CLOSE;

# what is the signature result?
my $signature = $dkim->signature;

CONSTRUCTOR

new() - construct an object-oriented signer

# create a signer using the default policy
my $dkim = Mail::DKIM::Signer->new(
                Algorithm => "rsa-sha1",
                Method => "relaxed",
                Domain => "example.org",
                Selector => "selector1",
                KeyFile => "private.key",
           );

# create a signer using a custom policy
my $dkim = Mail::DKIM::Signer->new(
                Policy => $policyfn,
           );

The "default policy" is to create a DKIM signature using the specified parameters, but only if the message's sender matches the domain. The following parameters can be passed to this new() method to influence the resulting signature: Algorithm, Method, Domain, Selector, KeyFile, Identity, Timestamp.

If you want different behavior, you can provide a "signer policy" instead. A signer policy is a subroutine or class that determines signature parameters after the message's headers have been parsed. See the section "SIGNER POLICIES" below for more information.

See Mail::DKIM::SignerPolicy for more information about policy objects.

In addition to the parameters demonstrated above, the following are recognized:

Key

rather than using KeyFile, use Key to use an already-loaded Mail::DKIM::PrivateKey object.

METHODS

PRINT() - feed part of the message to the signer

$dkim->PRINT("a line of the message\015\012");

Feeds content of the message being signed into the signer. The API is designed this way so that the entire message does NOT need to be read into memory at once.

CLOSE() - call this when finished feeding in the message

$dkim->CLOSE;

This method finishes the canonicalization process, computes a hash, and generates a signature.

add_signature() - used by signer policy to create a new signature

$dkim->add_signature(new Mail::DKIM::Signature(...));

Signer policies can use this method to specify complete parameters for the signature to add, including what type of signature. For more information, see Mail::DKIM::SignerPolicy.

algorithm() - get or set the selected algorithm

$alg = $dkim->algorithm;

$dkim->algorithm("rsa-sha1");

domain() - get or set the selected domain

$alg = $dkim->domain;

$dkim->domain("example.org");

load() - load the entire message from a file handle

$dkim->load($file_handle);

Reads a complete message from the designated file handle, feeding it into the signer. The message must use <CRLF> line terminators (same as the SMTP protocol).

headers() - determine which headers to put in signature

my $headers = $dkim->headers;

This is a string containing the names of the header fields that will be signed, separated by colons.

key() - get or set the private key object

my $key = $dkim->key;

$dkim->key(Mail::DKIM::PrivateKey->load(File => "private.key"));

If you use this method to specify a private key, do not use "key_file()".

key_file() - get or set the filename containing the private key

my $filename = $dkim->key_file;

$dkim->key_file("private.key");

If you use this method to specify a private key file, do not use "key()".

method() - get or set the selected canonicalization method

$alg = $dkim->method;

$dkim->method("relaxed");

message_originator() - access the "From" header

my $address = $dkim->message_originator;

Returns the "originator address" found in the message, as a Mail::Address object. This is typically the (first) name and email address found in the From: header. If there is no From: header, then an empty Mail::Address object is returned.

To get just the email address part, do:

my $email = $dkim->message_originator->address;

See also "message_sender()".

message_sender() - access the "From" or "Sender" header

my $address = $dkim->message_sender;

Returns the "sender" found in the message, as a Mail::Address object. This is typically the (first) name and email address found in the Sender: header. If there is no Sender: header, it is the first name and email address in the From: header. If neither header is present, then an empty Mail::Address object is returned.

To get just the email address part, do:

my $email = $dkim->message_sender->address;

The "sender" is the mailbox of the agent responsible for the actual transmission of the message. For example, if a secretary were to send a message for another person, the "sender" would be the secretary and the "originator" would be the actual author.

selector() - get or set the current key selector

$alg = $dkim->selector;

$dkim->selector("alpha");

signature() - access the generated signature object

my $signature = $dkim->signature;

Returns the generated signature. The signature is an object of type Mail::DKIM::Signature. If multiple signatures were generated, this method returns the last one.

The signature should be prepended to the message to make the resulting message. At the very least, it should precede any headers that were signed.

signatures() - access list of generated signature objects

my @signatures = $dkim->signatures;

Returns all generated signatures, as a list.

SIGNER POLICIES

The new() constructor takes an optional Policy argument. This can be a Perl object or class with an apply() method, or just a simple subroutine reference. The method/subroutine will be called with the signer object as an argument. The policy is responsible for checking the message and specifying signature parameters. The policy must return a nonzero value to create the signature, otherwise no signature will be created. E.g.,

my $policyfn = sub {
    my $dkim = shift;

    # specify signature parameters
    $dkim->algorithm("rsa-sha1");
    $dkim->method("relaxed");
    $dkim->domain("example.org");
    $dkim->selector("mx1");

    # return true value to create the signature
    return 1;
};

Or the policy object can actually create the signature, using the add_signature method within the policy object. If you add a signature, you do not need to return a nonzero value. This mechanism can be utilized to create multiple signatures, or to create the older DomainKey-style signatures.

my $policyfn = sub {
    my $dkim = shift;
    $dkim->add_signature(
            new Mail::DKIM::Signature(
                    Algorithm => "rsa-sha1",
                    Method => "relaxed",
                    Headers => $dkim->headers,
                    Domain => "example.org",
                    Selector => "mx1",
            ));
    $dkim->add_signature(
            new Mail::DKIM::DkSignature(
                    Algorithm => "rsa-sha1",
                    Method => "nofws",
                    Headers => $dkim->headers,
                    Domain => "example.org",
                    Selector => "mx1",
            ));
    return;
};

If no policy is specified, the default policy is used. The default policy signs every message using the domain, algorithm, method, and selector specified in the new() constructor.

SEE ALSO

Mail::DKIM::SignerPolicy

AUTHOR

Jason Long, <jlong@messiah.edu>

COPYRIGHT AND LICENSE

Copyright (C) 2006-2007 by Messiah College

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.6 or, at your option, any later version of Perl 5 you may have available.