/ 
Validator-LIVR-2.0
River stage one • 1 direct dependent • 1 total dependent
/ Validator::LIVR

NAME

Validator::LIVR - Lightweight validator supporting Language Independent Validation Rules Specification (LIVR)

SYNOPSIS

# Common usage
Validator::LIVR->default_auto_trim(1);

my $validator = Validator::LIVR->new({
    name      => 'required',
    email     => [ 'required', 'email' ],
    gender    => { one_of => ['male', 'female'] },
    phone     => { max_length => 10 },
    password  => [ 'required', {min_length => 10} ],
    password2 => { equal_to_field => 'password' }
});

if ( my $valid_data = $validator->validate($user_data) ) {
   save_user($valid_data);
} else {
   my $errors = $validator->get_errors();
   ...
}

# You can use modifiers separately or can combine them with validation:
my $validator = Validator::LIVR->new({
    email => [ 'required', 'trim', 'email', 'to_lc' ]
});

# Feel free to register your own rules
# You can use aliases(prefferable, syntax covered by the specification) for a lot of cases:

my $validator = Validator::LIVR->new({
    password => ['required', 'strong_password']
});

$validator->register_aliased_rule({
    name  => 'strong_password',
    rules => {min_length => 6},
    error => 'WEAK_PASSWORD'
});

# or you can write more sophisticated rules directly

my $validator = Validator::LIVR->new({
    password => ['required', 'strong_password']
});

$validator->register_rules( 'strong_password' =>  sub {
    return sub {
        my $value = shift;

        # We already have "required" rule to check that the value is present
        return if !defined($value) || $value eq '';

        return 'WEAK_PASSWORD' if length($value) < 6;
        return;
    }
} );


# If you want to stop on the first error
# you can overwrite all rules with your own which use exceptions
my $default_rules = Validator::LIVR->ger_default_rules();

while ( my ($rule_name, $rule_builder) = each %$default_rules ) {
    Validator::LIVR->register_default_rules($rule_name => sub {
        my $rule_validator = $rule_builder->(@_);

        return sub {
            my $error = $rule_validator->(@_);
            die $error if $error;
            return;
        }
    });
}

DESCRIPTION

Validator::LIVR lightweight validator supporting Language Independent Validation Rules Specification (LIVR)

See http://livr-spec.org for rules documentation.

Features:

  • Rules are declarative and language independent

  • Any number of rules for each field

  • Return together errors for all fields

  • Excludes all fields that do not have validation rules described

  • Has possibility to validatate complex hierarchical structures

  • Easy to describe and undersand rules

  • Returns understandable error codes(not error messages)

  • Easy to add own rules

  • Multipurpose (user input validation, configs validation, contracts programming etc)

CLASS METHODS

Validator::LIVR->new( $LIVR [, $IS_AUTO_TRIM] )

Contructor creates validator objects.

$LIVR - validations rules. Rules description is available here - https://github.com/koorchik/LIVR

$IS_AUTO_TRIM - asks validator to trim all values before validation. Output will be also trimmed. if $IS_AUTO_TRIM is undef than default_auto_trim value will be used.

Validator::LIVR->register_aliased_default_rule( $ALIAS )

$ALIAS - is a hash that contains: name, rules, error (optional).

Validator::LIVR->register_aliased_default_rule({
    name  => 'valid_address',
    rules => { nested_object => {
        country => 'required',
        city    => 'required',
        zip     => 'positive_integer'
    }}
});

Then you can use "valid\_address" for validation:

{
    address => 'valid_address'
}

You can register aliases with own errors:

Validator::LIVR->register_aliased_default_rule({
    name  => 'adult_age'
    rules => [ 'positive_integer', { min_number => 18 } ],
    error => 'WRONG_AGE'
});

All rules/aliases for the validator are equal. The validator does not distinguish "required", "list\_of\_different\_objects" and "trim" rules. So, you can extend validator with any rules/alias you like.

Validator::LIVR->register_default_rules( RULE_NAME => \&RULE_BUILDER, ... )

&RULE_BUILDER - is a subtorutine reference which will be called for building single rule validator.

Validator::LIVR->register_default_rules( my_rule => sub {
    my ($arg1, $arg2, $arg3, $rule_builders) =  @_;

    # $rule_builders - are rules from original validator
    # to allow you create new validator with all supported rules
    # my $validator = Validator::LIVR->new($livr)->register_rules(%$rule_builders)->prepare();

    return sub {
        my ( $value, $all_values, $output_ref ) = @_;

        if ($not_valid) {
            return "SOME_ERROR_CODE"
        }
        else {

        }

    }
});

Then you can use "my_rule" for validation:

{
    name1 => 'my_rule' # Call without parameters
    name2 => { 'my_rule' => $arg1 } # Call with one parameter.
    name3 => { 'my_rule' => [$arg1] } # Call with one parameter.
    name4 => { 'my_rule' => [ $arg1, $arg2, $arg3 ] } # Call with many parameters.
}

Here is "max_number" implemenation:

sub max_number {
    my $max_number = shift;

    return sub {
        my $value = shift;

        # We do not validate empty fields. We have "required" rule for this purpose
        return if !defined($value) || $value eq '';

        return 'TOO_HIGH' if $value > $max_number; # Return error message
        return; # returning undef means that there was no errors;
    };
}

Validator::LIVR->register_default_rules( max_number => \&max_number );

All rules for the validator are equal. It does not distinguish "required", "list_of_different_objects" and "trim" rules. So, you can extend validator with any rules you like.

Just look at the existing rules implementation:

All rules description is available here - https://github.com/koorchik/LIVR

Validator::LIVR->get_default_rules( )

returns hashref containing all default rule_builders for the validator. You can register new rule or update existing one with "register_rules" method.

Validator::LIVR->default_auto_trim($IS_AUTO_TRIM)

Enables or disables automatic trim for input data. If is on then every new validator instance will have auto trim option enabled

OBJECT METHODS

$VALIDATOR->validate(\%INPUT)

Validates user input. On success returns $VALID_DATA (contains only data that has described validation rules). On error return false.

my $VALID_DATA = $VALIDATOR->validate(\%INPUT)

if ($VALID_DATA) {

} else {
    my $errors = $VALIDATOR->get_errors();
}

$VALIDATOR->get_errors( )

Returns errors hash.

{
    "field1" => "ERROR_CODE",
    "field2" => "ERROR_CODE",
    ...
}

For example:

{
    "country"  => "NOT_ALLOWED_VALUE",
    "zip"      => "NOT_POSITIVE_INTEGER",
    "street"   => "REQUIRED",
    "building" => "NOT_POSITIVE_INTEGER"
},

$VALIDATOR->register_rules( RULE_NAME => \&RULE_BUILDER, ... )

&RULE_BUILDER - is a subtorutine reference which will be called for building single rule validator.

See "Validator::LIVR->register_default_rules" for rules examples.

$VALIDATOR->register_aliased_rule( $ALIAS )

$ALIAS - is a composite validation rule.

See "Validator::LIVR->register_aliased_default_rule" for rules examples.

$VALIDATOR->get_rules( )

returns hashref containing all rule_builders for the validator. You can register new rule or update existing one with "register_rules" method.

AUTHOR

Viktor Turskyi, <koorchik at cpan.org>

BUGS

Please report any bugs or feature requests to Github https://github.com/koorchik/Validator-LIVR

SUPPORT

You can find documentation for this module with the perldoc command.

perldoc Validator::LIVR

You can also look for information at:

ACKNOWLEDGEMENTS

LICENSE AND COPYRIGHT

Copyright 2012 Viktor Turskyi.

This program is free software; you can redistribute it and/or modify it under the terms of the the Artistic License (2.0). You may obtain a copy of the full license at:

http://www.perlfoundation.org/artistic_license_2_0

Any use, modification, and distribution of the Standard or Modified Versions is governed by this Artistic License. By using, modifying or distributing the Package, you accept this license. Do not use, modify, or distribute the Package, if you do not accept this license.

If your Modified Version has been derived from a Modified Version made by someone other than you, you are nevertheless required to ensure that your Modified Version complies with the requirements of this license.

This license does not grant you the right to use any trademark, service mark, tradename, or logo of the Copyright Holder.

This license includes the non-exclusive, worldwide, free-of-charge patent license to make, have made, use, offer to sell, sell, import and otherwise transfer the Package with respect to any patent claims licensable by the Copyright Holder that are necessarily infringed by the Package. If you institute patent litigation (including a cross-claim or counterclaim) against any party alleging that the Package constitutes direct or contributory patent infringement, then this Artistic License to you shall terminate on the date that such litigation is filed.

Disclaimer of Warranty: THE PACKAGE IS PROVIDED BY THE COPYRIGHT HOLDER AND CONTRIBUTORS "AS IS' AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES. THE IMPLIED WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE, OR NON-INFRINGEMENT ARE DISCLAIMED TO THE EXTENT PERMITTED BY YOUR LOCAL LAW. UNLESS REQUIRED BY LAW, NO COPYRIGHT HOLDER OR CONTRIBUTOR WILL BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING IN ANY WAY OUT OF THE USE OF THE PACKAGE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.