Sponsoring The Perl Toolchain Summit 2025: Help make this important event another success Learn more

KRYDE / Math-PlanePath-129 / t / ImaginaryBase.t 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132

              
#!/usr/bin/perl -w
# Copyright 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Kevin Ryde
# This file is part of Math-PlanePath.
#
# Math-PlanePath is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# Math-PlanePath is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with Math-PlanePath.  If not, see <http://www.gnu.org/licenses/>.
use 5.004;
use strict;
use Test;
plan tests => 311;
use lib 't';
use MyTestHelpers;
BEGIN { MyTestHelpers::nowarnings(); }
use Math::PlanePath::ImaginaryBase;
#------------------------------------------------------------------------------
# VERSION
{
  my $want_version = 129;
  ok ($Math::PlanePath::ImaginaryBase::VERSION, $want_version,
      'VERSION variable');
  ok (Math::PlanePath::ImaginaryBase->VERSION,  $want_version,
      'VERSION class method');
  ok (eval { Math::PlanePath::ImaginaryBase->VERSION($want_version); 1 },
      1,
      "VERSION class check $want_version");
  my $check_version = $want_version + 1000;
  ok (! eval { Math::PlanePath::ImaginaryBase->VERSION($check_version); 1 },
      1,
      "VERSION class check $check_version");
  my $path = Math::PlanePath::ImaginaryBase->new;
  ok ($path->VERSION,  $want_version, 'VERSION object method');
  ok (eval { $path->VERSION($want_version); 1 },
      1,
      "VERSION object check $want_version");
  ok (! eval { $path->VERSION($check_version); 1 },
      1,
      "VERSION object check $check_version");
}
#------------------------------------------------------------------------------
# n_start, x_negative, y_negative
{
  my $path = Math::PlanePath::ImaginaryBase->new;
  ok ($path->n_start, 0, 'n_start()');
  ok ($path->x_negative, 1, 'x_negative()');
  ok ($path->y_negative, 1, 'y_negative()');
}
#------------------------------------------------------------------------------
# random points
{
  my $radix = 2 + int(rand(20));
  my $path = Math::PlanePath::ImaginaryBase->new (radix => $radix);
  for (1 .. 100) {
    my $bits = int(rand(25));         # 0 to 25, inclusive
    my $n = int(rand(2**$bits)) + 1;  # 1 to 2^bits, inclusive
    my ($x,$y) = $path->n_to_xy ($n);
    my $rev_n = $path->xy_to_n ($x,$y);
    if (! defined $rev_n) { $rev_n = 'undef'; }
    ok ($rev_n, $n,
        "xy_to_n($x,$y) radix=$radix reverse to expect n=$n, got $rev_n");
    my ($n_lo, $n_hi) = $path->rect_to_n_range ($x,$y, $x,$y);
    ok ($n_lo <= $n, 1,
        "rect_to_n_range() radix=$radix reverse n=$n cf got n_lo=$n_lo");
    ok ($n_hi >= $n, 1,
        "rect_to_n_range() radix=$radix reverse n=$n cf got n_hi=$n_hi");
  }
}
#------------------------------------------------------------------------------
# cf A039724 negabinary
#    A039723 negadecimal
sub index_to_negaradix {
  my ($n, $radix) = @_;
  my $power = 1;
  my $ret = 0;
  while ($n) {
    my $digit = $n % $radix;  # low to high
    $n = int($n/$radix);
    $ret += $power * $digit;
    $power *= -$radix;
  }
  return $ret;
}
{
  require Math::PlanePath::ZOrderCurve;
  my $bad = 0;
  foreach my $radix (2, 3, 5, 10, 16) {
    my $zorder = Math::PlanePath::ZOrderCurve->new (radix => $radix);
    my $imbase = Math::PlanePath::ImaginaryBase->new (radix => $radix);
    foreach my $n (0 .. 256) {
      my ($zx,$zy) = $zorder->n_to_xy($n);
      my $nx = index_to_negaradix($zx,$radix);
      my $ny = index_to_negaradix($zy,$radix);
      my $in = $imbase->xy_to_n($nx,$ny);
      if ($n != $in) {
        $bad = 1;
      }
    }
  }
  ok ($bad, 0);
}
exit 0;