The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

KTHAKORE / SDL-Tutorial-Tetris-0.04 / lib / SDL / Tutorial / Tetris / Controller / Game.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
—
156
157
158
159
160
161
162
163
164
165
166
167
168
169

              
package SDL::Tutorial::Tetris::Controller::Game;
use strict;
use warnings;
use base 'SDL::Tutorial::Tetris::Base';
use Data::Dumper;
use Time::HiRes qw/time/;
use Readonly;
use SDL::Tutorial::Tetris::Model::Grid;
use SDL::Tutorial::Tetris::Model::Pieces;
Readonly my $STATE_PREPARING => 0;
Readonly my $STATE_RUNNING   => 1;
Readonly my $STATE_PAUSED    => 2;
sub init {
    my $self = shift;
    $self->{level} = 0.5;
    $self->{state} = $STATE_PREPARING;
    print "Game PREPARING ... \n" if $self->{GDEBUG};
    $self->_init_grid;
    $self->evt_manager->post({name => 'GridBuilt', grid => $self->{grid}});
    #$self->{player} =; For points, level so on
}
sub notify {
    my ($self, $event) = (@_);
    return if $event->{name} eq 'GridBuilt';
    print "Notify in GAME \n" if $self->{EDEBUG};
    my $state = $self->{state};
    my %event_method = (
        $STATE_PREPARING => {
            '*' => '_start',
        },
        $STATE_RUNNING   => {
            'CharactorMoveRequest' => '_charactor_move_request',
            'Tick'                 => '_tick',
        },
    );
    my $method = $event_method{$state}{$event->{name}} || $event_method{$state}{'*'};
    if ( defined $method ) {
        # call the event
        $self->$method($event);
    }
    #if we did not have a tick event then some other controller needs to do
    #something so game state is still beign process we cannot have new input
    #now
}
sub _charactor_move_request {
    my ($self, $event) = @_;
    print "Move charactor sprite \n" if $self->{GDEBUG};
    my ($mx, $my, $rot) = ($self->{posx}, $self->{posy}, $self->{pieceRotation});
    my %action_direction = (
        'ROTATE_C'        => sub { $rot++; $rot = $rot % 4; },
        'ROTATE_CC'       => sub { $rot--; $rot = $rot % 4; },
        'DIRECTION_DOWN'  => sub { $my++;                   },
        'DIRECTION_LEFT'  => sub { $mx--;                   },
        'DIRECTION_RIGHT' => sub { $mx++;                   },
    );
    my $action = $action_direction{ $event->{direction} };
    if (defined $action) {
        # do it
        $action->();
    }
    if ($self->{grid}->is_possible_movement($mx, $my, $self->{piece}, $rot)) {
        ($self->{posx}, $self->{posy}, $self->{pieceRotation}) = ($mx, $my, $rot);
        $self->evt_manager->post({name => 'CharactorMove'});
    }
}
sub _tick {
    my ($self, $event) = @_;
    return if (time - $self->{wait}) < $self->{level};
    $self->{wait} = time;
    if ($self->{grid}->is_possible_movement($self->{posx}, $self->{posy} + 1, $self->{piece}, $self->{pieceRotation})) {
        $self->{posy}++;
        $self->evt_manager->post({name => 'CharactorMove'});
    }
    else {
        $self->{grid}->store_piece($self->{posx}, $self->{posy}, $self->{piece}, $self->{pieceRotation});
        $self->_create_new_piece();
        $self->{level} -= (0.01) * $self->{grid}->delete_possible_lines;
        if ($self->{grid}->is_game_over()) {
            #make GameOver
            $self->evt_manager->post({name => 'Quit'});
        }
    }
}
sub _start {
    my $self = shift;
    $self->{state} = $STATE_RUNNING;
    print "Game RUNNING \n" if $self->{GDEBUG};
    $self->evt_manager->post({ name => 'GameStart', game => $self });
    $self->{wait} = time;
}
sub _init_grid {
    my $self = shift;
    $self->{grid} = SDL::Tutorial::Tetris::Model::Grid->new();
    ($self->{piece},$self->{pieceRotation}) = SDL::Tutorial::Tetris::Model::Pieces->random();
    my ($x,$y) = SDL::Tutorial::Tetris::Model::Pieces->init_xy($self->{piece}, $self->{pieceRotation});
    $self->{posx} = $self->{grid}->{width} / 2 + $x;
    $self->{posy} = $y;
    ($self->{next_piece}, $self->{next_rotation}) = SDL::Tutorial::Tetris::Model::Pieces->random();
    $self->{next_posx}     = ($self->{grid}->{width}) + 1;
    $self->{next_posy}     = 0;
}
sub _create_new_piece {
    my $self = shift;
    $self->{piece}         = $self->{next_piece};
    $self->{pieceRotation} = $self->{next_rotation};
    my ($x,$y) = SDL::Tutorial::Tetris::Model::Pieces->init_xy($self->{piece}, $self->{pieceRotation});
    $self->{posx} = $self->{grid}->{width} / 2 + $x;
    $self->{posy} = $y;
    #     //  Next piece
    ($self->{next_piece}, $self->{next_rotation}) = SDL::Tutorial::Tetris::Model::Pieces->random();
}
1;
__END__
=head1 NAME
SDL::Tutorial::Tetris::Controller::Game
=head1 DESCRIPTION
The C<Game> controller
=head2 init
Initialize game variables, like level and state.
=head2 notify