/ 
Mutex-1.007
River stage one • 2 direct dependents • 6 total dependents
/ Mutex

NAME

Mutex - Various locking implementations supporting processes and threads

VERSION

This document describes Mutex version 1.007

SYNOPSIS

use Mutex;

my $mutex = Mutex->new;

{
    use MCE::Flow max_workers => 4;

    mce_flow sub {
        $mutex->lock;

        # access shared resource
        my $wid = MCE->wid; MCE->say($wid); sleep 1;

        $mutex->unlock;
    };
}

{
    use MCE::Hobo;

    MCE::Hobo->create('work', $_) for 1..4;
    MCE::Hobo->waitall;
}

{
    use threads;

    threads->create('work', $_)   for 5..8;
    $_->join for ( threads->list );
}

sub work {
    my ($id) = @_;
    $mutex->lock;

    # access shared resource
    print $id, "\n";
    sleep 1;

    $mutex->unlock;
}

DESCRIPTION

This module, a standalone version of MCE::Mutex, implements locking methods that can be used to coordinate access to shared data from multiple workers spawned as processes or threads.

The inspiration for this module came from reading Mutex for Ruby.

API DOCUMENTATION

Mutex->new ( )

Mutex->new ( impl => "Channel" )

Mutex->new ( impl => "Flock", [ path => "/tmp/file.lock" ] )

Mutex->new ( path => "/tmp/file.lock" )

Creates a new mutex.

Channel locking (the default), unless path is given, is through a pipe or socket depending on the platform. The advantage of channel locking is not having to re-establish handles inside new processes and threads.

For Fcntl-based locking, it is the responsibility of the caller to remove the tempfile, associated with the mutex, when path is given. Otherwise, it establishes a tempfile internally including removal on scope exit.

$mutex->impl ( void )

Returns the implementation used for the mutex.

$m1 = Mutex->new( );
$m1->impl();   # Channel

$m2 = Mutex->new( path => /tmp/my.lock );
$m2->impl();   # Flock

$m3 = Mutex->new( impl => "Channel" );
$m3->impl();   # Channel

$m4 = Mutex->new( impl => "Flock" );
$m4->impl();   # Flock

$mutex->lock ( void )

$mutex->lock_exclusive ( void )

Attempts to grab an exclusive lock and waits if not available. Multiple calls to mutex->lock by the same process or thread is safe. The mutex will remain locked until mutex->unlock is called.

The method lock_exclusive is an alias for lock.

( my $mutex = Mutex->new( path => $0 ) )->lock_exclusive;

$mutex->lock_shared ( void )

Like lock_exclusive, but attempts to grab a shared lock instead. For non-Fcntl implementations, lock_shared is an alias for lock.

$mutex->unlock ( void )

Releases the lock. A held lock by an exiting process or thread is released automatically.

$mutex->synchronize ( sub { ... }, @_ )

$mutex->enter ( sub { ... }, @_ )

Obtains a lock, runs the code block, and releases the lock after the block completes. Optionally, the method is wantarray aware.

my $val = $mutex->synchronize( sub {
    # access shared resource
    return 'scalar';
});

my @ret = $mutex->enter( sub {
    # access shared resource
    return @list;
});

The method enter is an alias for synchronize.

$mutex->timedwait ( timeout )

Blocks until obtaining an exclusive lock. A false value is returned if the timeout is reached, and a true value otherwise. The default is 1 second when omitting timeout.

my $mutex = Mutex->new( path => $0 );

# terminate script if a previous instance is still running

exit unless $mutex->timedwait( 2 );

...

REQUIREMENTS

Perl 5.8.1 or later.

AUTHOR

Mario E. Roy, <marioeroy AT gmail DOT com>

COPYRIGHT AND LICENSE

Copyright (C) 2017-2022 by Mario E. Roy

Mutex is released under the same license as Perl.

See https://dev.perl.org/licenses/ for more information.