NAME

Mail::Message - general message object

CLASS INHERITANCE

Mail::Message has extra code in Mail::Message::Construct

Mail::Message is a Mail::Reporter

Mail::Message is extended by Mail::Box::Message Mail::Message::Dummy Mail::Message::Part

SYNOPSIS

use Mail::Box::Manager;
my $mgr    = Mail::Box::Manager->new;
my $folder = $mgr->open(folder => $MAIL);
my $msg    = $folder->message(2);    # $msg isa Mail::Message

$msg->decoded->print($outfile);

my Mail::Message $construct  = Mail::Message->new;
my Mail::Message $construct  = Mail::Message->build(...);
my Mail::Message::Head $head = $msg->head;
my Mail::Message::Body $body = $msg->decoded;
my $subject = $msg->get('subject');

DESCRIPTION

A Mail::Message object is a container for message information read from a file. Everything what is not folder related will be found here.

Complex message handling (like construction of replies) are handled by the Mail::Message::Construct package which is autoloaded. That package adds functionality to the Mail::Message objects.

The main methods are get() (to get information from a message header) and decoded() to get the intended content of a message.

METHODS

Initiation

new OPTIONS

OPTION               DEFAULT
body                 undef
body_type            'Mail::Message::Body::Lines'
field_type           undef
head                 undef
head_type            'Mail::Message::Head::Complete'
head_wrap            72
log                  'WARNINGS'
messageId            undef
modified             <false>
trace                'WARNINGS'
trusted              <false>

body => OBJECT: Instantiate the message with a body which has been created somewhere before the message is constructed. The OBJECT must be a sub-class of Mail::Message::Body.
body_type => CLASS: Default type of body to be created for readBody().
field_type => CLASS
head => OBJECT: Instantiate the message with a head which has been created somewhere before the message is constructed. The OBJECT must be a (sub-)class of Mail::Message::Head.
head_type => CLASS: Default type of head to be created for readHead().
head_wrap => INTEGER: The soft maximum line width of header lines in the folder to write.
log => LEVEL: See Mail::Reporter::new(log)
messageId => STRING: The id on which this message can be recognized. If none specified and not defined in the header --but one is needed-- there will be one assigned to the message to be able to pass unique message-ids between objects.
modified => BOOLEAN: Flags this message as being modified, from the beginning on. Usually, modification is auto-detected, but there may be reasons to be extra explicit.
trace => LEVEL: See Mail::Reporter::new(trace)
trusted => BOOLEAN: Is this message from a trusted source? If not, the content must be checked before use.

Constructing a Message

bounce OPTIONS

See Mail::Message::Construct::bounce()

build [MESSAGE|BODY], CONTENT

See Mail::Message::Construct::build()

buildFromBody BODY, HEADERS

See Mail::Message::Construct::buildFromBody()

coerce MESSAGE

(Class method) Coerce a MESSAGE into a Mail::Message. In some occasions, for instance where you add a message to a folder, this coercion is automatically called to ensure that the correct message type is stored.

The coerced message is returned on success, otherwise undef. The coerced message may be a reblessed version of the original message or a new object.

Valid MESSAGEs which can be coerced into Mail::Message objects are of type

MIME::Entity's, using Mail::Message::Convert::MimeEntity
Mail::Internet's, using Mail::Message::Convert::MimeEntity
any extension of Mail::Message is left untouched

Examples:

my $message = Mail::Message->new(...);
my $coerced = Mail::Box::Mbox::Message->coerce($message);
# now $coerced is a Mail::Box::Mbox::Message

It is better to use (when the message will be stored in that folder):

my $folder  = Mail::Box::Mbox->new;
my $coerced = $folder->coerce($message);
my $coerced = $folder->addMessage($message);

forward OPTIONS

See Mail::Message::Construct::forward()

forwardPostlude

See Mail::Message::Construct::forwardPostlude()

forwardPrelude

See Mail::Message::Construct::forwardPrelude()

forwardSubject STRING

See Mail::Message::Construct::forwardSubject()

read FILEHANDLE|SCALAR|REF-SCALAR|ARRAY-OF-LINES, OPTIONS

See Mail::Message::Construct::read()

reply OPTIONS

See Mail::Message::Construct::reply()

replyPrelude [STRING|FIELD|ADDRESS]

See Mail::Message::Construct::replyPrelude()

replySubject STRING

See Mail::Message::Construct::replySubject()

The Message

clone

Create a copy of this message. Returned is a Mail::Message object. The head and body, the log and trace levels are taken. Labels are copied with the message, but the delete and modified flags are not.

BE WARNED: the clone of any kind of message (or a message part) will always be a Mail::Message object. For example, a Mail::Box::Message's clone is detached from the folder of its original. When you use Mail::Box::addMessage() with the cloned message at hand, then the clone will automatically be coerced into the right message type to be added.

See also the copyTo() and moveTo() methods.

Examples:

$copy = $msg->clone;

isDummy

Dummy messages are used to fill holes in linked-list and such, where only a message-id is known, but not the place of the header of body data.

This method is also available for Mail::Message::Dummy objects, where this will return true. On any extension of Mail::Message, this will return false.

isPart

Returns true if the message is a part of another message. This is the case for Mail::Message::Part extensions of Mail::Message. See parent() for examples.

messageId

Retrieve the message's id. Every message has a unique message-id. This id is used mainly for recognizing discussion threads.

modified [BOOLEAN]

Returns (optionally after setting) whether this message is flagged as being modified. The modification flag is set true when header lines are changed, the header or body replaced by a new one, or when labels are modified.

parent

If the message is a part of another message, parent returns the reference to the containing message. parent returns undef if the message is not a part, but rather the main message.

Examples:

my Mail::Message $msg = ...
return unless $msg->body->isMultipart;
my $part   = $msg->body->part(2);

return unless $part->body->isMultipart;
my $nested = $part->body->part(3);

$nested->parent;     # returns $part
$nested->toplevel;   # returns $msg
$msg->parent;        # returns undef
$msg->toplevel;      # returns $msg
$msg->isPart;        # returns false
$part->isPart;       # returns true

print [FILEHANDLE]

Print the message to the FILE-HANDLE, which defaults to the selected filehandle.

Examples:

$message->print(\*STDERR);
$message->print;

my $out = IO::File->new('out', 'w');
$message->print($out);

send [MAILER], OPTIONS

Transmit the message to anything outside this Perl program. Writing

my $mailer = Mail::Transport::SMTP->new(@smtpopts);
$message->send($mailer, @sendopts);

is a short for

my $mailer = Mail::Transport::SMTP->new(@smtpopts);
$mailer->send($message, @sendopts);

However, when the MAILER is not specified, one will be auto-generated via Mail::Transport::new(). This object will be re-used. For instance

$message->send(@sendopts);

is equivalent to

Mail::Transport->new->send($message, @sendopts);

The OPTIONS are mailer specific.

size

Returns the size of the whole message in bytes.

toplevel

Returns a reference to the main message, which will be the current message if the message is not part of another message. See parent() for examples.

The Header

get FIELD

Returns the value which is stored in the header FIELD with the specified name. If the field has multiple appearances in the header, the last instance is returned.

The field name is case insensitive. Only the `body' of the field is returned, not the comment (after ';'). If you need more complex handing of fields, then call

Examples:

print $msg->get('Content-Type'), "\n";

Is equivalent to:

print $msg->head->get('Content-Type')->body, "\n";

head [HEAD]

Return (optionally after setting) the HEAD of this message. The head must be an (sub-)class of Mail::Message::Head. When the head is added, status information is taken from it and transformed into labels. More labels can be added by the LABELS hash. They are added later.

Example:

my $head = $msg->head(new Mail::Message::Head);

Header Shortcuts

bcc

Returns the addresses which are specified on the 'Resent-Bcc' header line, or, if that line does not exists, on the 'Bcc' header line. A list of Mail::Address objects is returned.

Bcc stands for Blind Carbon Copy: destinations of the message which are not listed in the messages actually sent. So, this field will be empty for received messages, but may be present in messages you construct yourself.

cc

Returns the addresses which are specified on the 'Resent-Cc' header line, or, if that line does not exists, on the 'Cc' header line. A list of Mail::Address objects is returned.

date

Returns the last Date header line as string.

Examples:

my $date = $message->date;

destinations

Returns a list of Mail::Address objects which contains the combined info of active To, Cc, and Bcc addresses. Doubles are removed.

from

Returns the address of the sender. This can only be one address. Of this is a bounced message, the Mail::Address representation of the Resent-From line is returned. Otherwise, the From line is scanned. If that line is not present, the Sender line is probed. Otherwise, undef is returned.

Example:

my $from = $message->from;

guessTimestamp

Return an estimate on the time this message was sent. The data is derived from the header, where it can be derived from the date and received lines. For MBox-like folders you may get the date from the from-line as well.

This method may return undef if the header is not parsed or only partially known. If you require a time, then use the timestamp() method, described below.

Examples:

print "Receipt ", ($message->timestamp || 'unknown'), "\n";

nrLines

Returns the number of lines used for the whole message.

subject

Returns the message's subject, just as short-cut for writing

$message->get('subject')

timestamp

Get a timestamp, doesn't matter how much work it is. If it is impossible to get a time from the header-lines, the current time-of-living is taken.

to

Returns the addresses which are specified on the 'Resent-To' header line, or, if that line does not exists, on the 'To' header line. A list of Mail::Address objects is returned.

Examples:

my @to = $message->to;

The Body

body [BODY]

Return the body of this message. BE WARNED that this returns you an object which may be encoded: use decoded() to get a body with usable data.

With options, a new BODY is set for this message. The body must be an (sub-)class of Mail::Message::Body. In this case, information from the specified body will be copied into the header. The body object will be encoded if needed, because messages written to file or transmitted shall not contain binary data. The converted body is returned.

When BODY is undef, the current message body will be dissected from the message. All relation will be cut. The body is returned, and can be connected to a different message.

Examples:

my $body      = $msg->body;
my @encoded   = $msg->body->lines;

my $new       = Mail::Message::Body->new(mime_type => 'text/html');
my $converted = $msg->body($new);

decoded OPTIONS

Decodes the body of this message, and returns it as a body object. If there was no encoding, the body object as read from file is passed on, however, some more work will be needed when a serious encoding is encountered. The OPTIONS control how the conversion takes place.

OPTION               DEFAULT
keep                 <false>
result_type          <type of body>

keep => BOOLEAN: Controls whether the decoded result will be kept. If not, the decoding may be performed more than once. However, it will consume extra resources...
result_type => BODYTYPE: Specifies which kind of body should be used for the final result, and eventual intermediate conversion stages. It is not sure that this will be the type of the body returned. BODYTYPE extends Mail::Message::Body.

Examples:

$message->decoded->print(\*OUT);
$message->decoded->print;

my $dec = $message->body($message->decoded);
my $dec = $message->decoded(keep => 1);   # same

encode OPTIONS

Encode the message to a certain format. Read the details in the dedicated manual page Mail::Message::Body::Encode. The OPTIONS which can be specified here are those of the Mail::Message::Body::encode() method.

isMultipart

Check whether this message is a multipart message (has attachments). To find this out, we need at least the header of the message; there is no need to read the body of the message to detect this.

parts ['ALL'|'ACTIVE'|'DELETED'|'RECURSE'|FILTER]

Returns the parts of this message. Usually, the term part is used with multipart messages: messages which are encapsulated in the body of a message. To abstract this concept: this method will return you all header-body combinations which are stored within this message. Objects returned are Mail::Message's and Mail::Message::Part's.

The option default to 'ALL', which will return the message itself for single-parts, the nested content of a message/rfc822 object, respectively the parts of a multipart without recursion. In case of 'RECURSE', the parts of multiparts will be collected recursively. This option cannot be combined with the other options, which you may want: it that case you have to test yourself.

'ACTIVE' and 'DELETED' check for the deleted flag on messages and message parts. The FILTER is a code reference, which is called for each message and message part (implies RECURSE).

Examples:

my @parts = $msg->parts;           # $msg not multipart: returns ($msg)
my $parts = $msg->parts('ACTIVE'); # returns ($msg)

$msg->delete;
my @parts = $msg->parts;           # returns ($msg)
my $parts = $msg->parts('ACTIVE'); # returns ()

Access to the Message

file: See Mail::Message::Construct::file()
lines: See Mail::Message::Construct::lines()
string: See Mail::Message::Construct::string()

Labels

label LABEL [,VALUE [LABEL, VALUE] ]

Return the value of the LABEL, optionally after setting it to VALUE. If the VALUE is undef then the label is removed. You may specify a list of LABEL-VALUE pairs at once. In the latter case, the first VALUE is returned.

Labels are used to store knowledge about handling of the message within the folder. Flags about whether a message was read, replied to, or (in some cases) scheduled for deletion.

Some labels are taken from the header's Status and X-Status lines, however folder types like MH define a separate label file.

Examples:

print $message->label('seen');
if($message->label('seen')) {...};
$message->label(seen => 1);

labels

Returns all known labels. In SCALAR context, it returns the knowledge as reference to a hash. This is a reference to the original data, but you shall *not* change that data directly: call label for changes!

In LIST context, you get a list of names which are defined. Be warned that they will not all evaluate to true, although most of them will.

Reading and Writing [internals]

DESTROY

When a message is to accessible anymore by any user's reference, Perl will call DESTROY for final clean-up. In this case, the head and body are released, and de-registered for the folder. You shall not call this yourself!

isDelayed

Check whether the message is delayed (not yet read from file). Returns true or false, dependent on the body type.

labelsToStatus

When the labels were changes, there may be an effect for the Status and/or X-Status header-lines. Whether this update has to take place depends on the type of folder.

readBody PARSER, HEAD [, BODYTYPE]

Read a body of a message. The PARSER is the access to the folder's file, and the HEAD is already read. Information from the HEAD is used to create expectations about the message's length, but also to determine the mime-type and encodings of the body data.

The BODYTYPE determines which kind of body will be made and defaults to the value specified by the body_type option at message creation (see new()). BODYTYPE may be the name of a body class, or a reference to a routine which returns the body's class when passed the HEAD as only argument.

readFromParser PARSER, [BODYTYPE]

Read one message from file. The PARSER is opened on the file. First readHeader() is called, and the head is stored in the message. Then readBody() is called, to produce a body. Also the body is added to the message without decodings being done.

The optional BODYTYPE may be a body class or a reference to a code which returns a body-class based on the header.

readHead PARSER [,CLASS]

Read a head into an object of the specified CLASS. The CLASS defaults to the head_type option specified at creation of the message (see new()). The PARSER is the access to the folder's file.

statusToLabels

Update the labels according the status lines in the header.

storeBody BODY

Where the body() method can be used to set and get a body, with all the necessary checks, this method is bluntly adding the specified body to the message. No conversions, not checking.

takeMessageId [STRING]

Take the message-id from the STRING, or create one when the undef is specified. If not STRING nor undef is given, the current header of the message is requested for the value of the 'Message-ID' field.

Angles (if present) are removed from the id.

Logging and Tracing

errors: See Mail::Reporter::errors()
log [LEVEL [,STRINGS]]: See Mail::Reporter::log()
printStructure [INDENT]: See Mail::Message::Construct::printStructure()
report [LEVEL]: See Mail::Reporter::report()
reportAll [LEVEL]: See Mail::Reporter::reportAll()
trace [LEVEL]: See Mail::Reporter::trace()
warnings: See Mail::Reporter::warnings()

Other Methods

AUTOLOAD: See Mail::Reporter::AUTOLOAD()
inGlobalDestruction: See Mail::Reporter::inGlobalDestruction()
logPriority LEVEL: See Mail::Reporter::logPriority()
logSettings: See Mail::Reporter::logSettings()
notImplemented: See Mail::Reporter::notImplemented()

AUTHOR

Mark Overmeer (mark@overmeer.net) with the help of many.

VERSION

This code is beta, version 2.019.

To install Mail::Box, copy and paste the appropriate command in to your terminal.

cpanm

cpanm Mail::Box

CPAN shell

perl -MCPAN -e shell
install Mail::Box

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

CLASS INHERITANCE

SYNOPSIS

DESCRIPTION

METHODS

Initiation

Constructing a Message

The Message

The Header

Header Shortcuts

The Body

Access to the Message

Labels

Reading and Writing [internals]

Logging and Tracing

Other Methods

SEE ALSO

AUTHOR

VERSION

Module Install Instructions