MIYAGAWA / App-CPAN-Fresh-0.04 / lib / App / CPAN / Fresh.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
—
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185

              
package App::CPAN::Fresh;
use strict;
use 5.008_001;
our $VERSION = '0.04';
use base qw(App::Cmd::Simple);
use Carp;
use CPAN::Inject;
use Time::Piece;
use File::Temp;
use JSON;
use LWP::UserAgent;
use URI;
my $duration = 2 * 24 * 60 * 60;
sub opt_spec {
    return (
        [ "install|i", "install the module" ],
        [ "list|l", "list the recent uploads" ],
        [ "help|h", "displays usage info" ],
    );
}
sub execute {
    my($self, $opt, $args) = @_;
    if ($opt->{list} && $args->[0]) {
        $self->search($args->[0]);
    } elsif ($opt->{list}) {
        $self->recent;
    } elsif ($opt->{help} || !@$args) {
        $self->usage;
    } else {
        $self->install($args);
    }
}
sub recent {
    my $self = shift;
    my $res = $self->call("/feed/cpan");
    $self->display_results($res);
}
sub search {
    my($self, $q) = @_;
    my $res = $self->call("/search", { q => "$q group:cpan" });
    $self->display_results($res);
}
sub usage {
    require Pod::Usage;
    Pod::Usage::pod2usage(0);
}
sub install {
    my($self, $dists) = @_;
    my @install;
    for my $dist (@$dists) {
        my $path = $self->inject($dist);
        if ($path) {
            push @install, $path;
        } else {
            print "$dist is not found or not in the fresh uploads. Falling back to your mirror.\n";
            push @install, $dist;
        }
    }
    if (@install) {
        require CPAN;
        CPAN::Shell->install(@install);
    }
}
sub inject {
    my($self, $dist) = @_;
    $dist =~ s/::/-/g;
    my $res = $self->call("/search", { q => "$dist group:cpan" });
    for my $entry (@{$res->{entries}}) {
        my $info = $self->parse_entry($entry->{body}, $entry->{date}) or next;
        if ($info->{dist} eq $dist) {
            return $self->do_inject($info);
        }
    }
    return;
}
sub do_inject {
    my($self, $info) = @_;
    my $dir = File::Temp::tempdir(CLEANUP => 1);
    my $local = "$dir/$info->{dist}-$info->{version}.tar.gz";
    my $res = $self->new_ua->mirror($info->{url}, $local);
    if ($res->is_error) {
        croak "Fetching $info->{url} failed: ", $res->status_line;
    }
    CPAN::Inject->from_cpan_config->add(file => $local);
}
sub display_results {
    my($self, $res) = @_;
    for my $entry (@{$res->{entries}}) {
        my $info = $self->parse_entry($entry->{body}, $entry->{date}) or next;
        printf "%s-%s (%s)\n", $info->{dist}, $info->{version}, $info->{author};
    }
}
sub parse_entry {
    my($self, $body, $date) = @_;
    my $time = Time::Piece->strptime($date, "%Y-%m-%dT%H:%M:%SZ") or return;
    if (time - $time->epoch > $duration) {
        # entry found, but it's old
        return;
    }
    if ($body =~ /^([\w\-]+) ([0-9\._]*) by (.+?) - <a.*href="(http:.*?\.tar\.gz)"/) {
        return {
            dist    => $1,
            version => $2,
            author  => $3,
            url     => $4,
        };
    }
    return;
}
sub new_ua {
    my $self = shift;
    LWP::UserAgent->new(agent => "cpanf/$VERSION", env_proxy => 1);
}
sub call {
    my($self, $method, $opts) = @_;
    my $uri = URI->new("http://friendfeed-api.com/v2$method");
    $uri->query_form(%$opts) if $opts;
    my $ua  = $self->new_ua;
    my $res = $ua->get($uri);
    if ($res->is_error) {
        croak "HTTP error: ", $res->status_line;
    }
    JSON::decode_json($res->content);
}
1;
__END__
=encoding utf-8
=for stopwords
=head1 NAME
App::CPAN::Fresh - backend for I<cpanf> command
=head1 DESCRIPTION
App::CPAN::Fresh is a backend for I<cpanf> command.
=head1 AUTHOR
Tatsuhiko Miyagawa E<lt>miyagawa@bulknews.netE<gt>
=head1 LICENSE
This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
=head1 SEE ALSO
L<cpanf>
=cut