Sponsoring The Perl Toolchain Summit 2025: Help make this important event another success Learn more

MMCLERIC / Ubic-1.50_01 / bin / ubic-periodic 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
—
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118

              
#!/usr/bin/env perl
package ubic_periodic;
{
  $ubic_periodic::VERSION = '1.50_01';
}
# ABSTRACT: run given command every N seconds
use strict;
use warnings;
use Getopt::Long 2.33;
use Pod::Usage;
return 1 if caller;
my $period = 60;
my $stdout;
my $stderr;
my $rotate_logs;
GetOptions(
    'period=i' => \$period,
    'stdout=s'  => \$stdout,
    'stderr=s'  => \$stderr,
    'rotate-logs!' => \$rotate_logs,
) or pod2usage(2);
pod2usage(2) unless @ARGV == 1;
my $command = shift @ARGV;
sub xunlink {
    my $file = shift;
    unlink $file or die "Can't unlink '$file': $!";
}
sub xrename {
    my ($from, $to) = @_;
    rename $from => $to or die "Can't rename '$from' to '$to': $!";
}
sub touch {
    my $file = shift;
    open my $fh, '>', $file or die "Can't touch '$file': $!";
}
sub rotate {
    my $file = shift;
    my $time = time;
    return unless -e $file;
    unless (-e "$file.1") {
        touch("$file.1");
    }
    my $mtime = (stat "$file.1")[9];
    if ($time - $mtime >= 86400) {
        # it's time to rotate!
        if (-e "$file.2") {
            xunlink("$file.2");
        }
        xrename("$file.1" => "$file.2");
        xrename($file => "$file.1");
    }
}
while (1) {
    my $start_time = time;
    if ($rotate_logs) {
        rotate($stdout);
        rotate($stderr);
    }
    # we reopen logs on every loop, so we don't have to restart periodic service on logrotate
    if ($stdout) {
        open STDOUT, '>>', $stdout or die "Can't open stdout: $!";
    }
    if ($stderr) {
        open STDERR, '>>', $stderr or die "Can't open stderr: $!";
    }
    system($command); # no, we don't check for failures
    my $time = time;
    if ($time - $start_time < $period) {
        sleep $start_time + $period - $time;
    }
}
__END__
=pod
=head1 NAME
ubic_periodic - run given command every N seconds
=head1 VERSION
version 1.50_01
=head1 SYNOPSIS
    ubic-periodic --period=60 --stdout=/var/log/ubic/watchdog.log --stderr=/var/log/ubic/watchdog.err.log ubic-watchdog
=head1 AUTHOR
Vyacheslav Matyukhin <mmcleric@yandex-team.ru>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2013 by Yandex LLC.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut