/ 
Constant-Generate-0.04
River stage two • 6 direct dependents • 12 total dependents
/ Constant::Generate

NAME

Constant::Generate - Common tasks for symbolic constants

SYNOPSIS

Simplest use

use Constant::Generate [qw(CONST_FOO CONST_BAR) ];
printf("FOO=%d, BAR=%d\n", CONST_FOO, CONST_BAR);

Bitflags:

use Constant::Generate qw(ANNOYING STRONG LAZY), type => 'bitflags';
my $state = (ANNOYING|LAZY);
$state & STRONG == 0;

With reverse mapping:

use Constant::Generate
	[qw(CLIENT_IRSSI CLIENT_XCHAT CLIENT_PURPLE)],
	type => "bitflags",
	mapname => "client_type_to_str";

my $client_type = CLIENT_IRSSI | CLIENT_PURPLE;

print client_type_to_str($client_type); #prints 'CLIENT_IRSSI|CLIENT_PURPLE';

Generate reverse maps, but do not generate values. also, push to exporter

#Must define @EXPORT_OK and tags beforehand

our @EXPORT_OK;
our %EXPORT_TAGS;

use Constant::Generate {
	O_RDONLY => 00,
	O_WRONLY => 01,
	O_RDWR	 => 02,
	O_CREAT  => 0100
}, tag => "openflags", "export_ok" => \@EXPORT_OK;

my $oflags = O_RDWR|O_CREAT;
print openflags_to_str($oflags); #prints 'O_RDWR|O_CREAT';

DESCRIPTION

Constant::Generate provides useful utilities for handling, debugging, and generating opaque, 'magic-cookie' type constants as well as value-significant constants.

At its simplest interface, it will generate a simple enumeration of names passed to it on import.

Read import options to use

USAGE

All options and configuration for this module are specified at import time.

The canonical usage of this module is

use Constant::Generate $symspec, %options;

Symbol Specifications

This is passed as the first argument to import and can exist as a reference to either a hash or an array. In the case of an array reference, the array will just contain symbol names whose values will be automatically assigned in order, with the first symbol being 0 and each subsequent symbol incrementing on the value of the previous. The default starting value can be modified using the start_at option (see "Options").

If the symbol specification is a hashref, then keys are symbol names and values are the symbol values, similar to what constant uses.

By default, symbols are assumed to correlate to a single independent integer value, and any reverse mapping performed will only ever map a symbol value to a single symbol name.

For bitflags, it is possible to specify type = 'bitfield'> in the "Options" which will modify the auto-generation of the constants as well as provide suitable output for reverse mapping functions.

Options

The second argument to the import function is a hash of options.

type

This specifies the type of constant used in the enumeration for the first argument as well as the generation of reverse mapping functions. Valid values are ones matching the regular expression /bit/i for bitfield values, and ones matching /int/i for simple integer values.

If type is not specified, it defaults to integer values.

start_at

Only valid for auto-generated values. This specifies the starting value for the first constant of the enumeration. If the enumeration is a bitfield, then the value is a factor by which to left-shift 1, thus

use Constant::Generate [qw(OPT_FOO OPT_BAR)], type => "bitfield";

OPT_FOO == 1 << 0;
OPT_BAR == 1 << 1;
#are true

and so on.

For non-bitfield values, this is simply a counter:

use Constant::Generate [qw(CONST_FOO CONST_BAR)], start_at => 42;

CONST_FOO == 42;
CONST_BAR == 43;
tag

Specify a tag to use for the enumeration.

This tag is used to generate the reverse mapping function, and is also the key under which symbols will be exported via %EXPORT_TAGS.

mapname

Specify the name of the reverse mapping function for the enumeration. If this is omitted, it will default to the form

$tag . "_to_str";

where $tag is the "tag" option passed. If neither are specified, then a reverse mapping function will not be generated

export, export_ok, export_tags

This group of options specifies the usage and modification of @EXPORT, @EXPORT_OK and %EXPORT_TAGS respectively, which are used by Exporter.

Values for these options should either be simple scalar booleans, or reference objects corresponding to the appropriate variables.

If references are not used as values for these options, Constant::Generate will expect you to have defined these modules already, and otherwise die.

EXPORTING

This module also allows you to define a 'constants' module of your own, from which you can export constants to other files in your package. Figuring out the right exporter parameters is quite hairy, and the export options can natually be a bit tricky.

In order to succesfully export symbols made by this module, you must specify either -export_ok or -export as hash options to import. These correspond to the like-named variables documented by Exporter.

Additionally, export tags can be specified only if one of the export flags is set to true (again, following the behavior of Exporter). The auto-export feature is merely one of syntactical convenience, but these three forms are effectively equivalent

Nicest way:

use base qw(Exporter);
our (@EXPORT, %EXPORT_TAGS);
use Constant::Generate
	[qw(FOO BAR BAZ)],
	-export => 1,
	-tag => "some_constants"
;

A bit more explicit:

use base qw(Exporter);
use Constant::Generate
	[qw(FOO BAR BAZ)],
	-export => \our @EXPORT,
	-export_tags => \our %EXPORT_TAGS,
	-tag => "some_constants",
	-mapname => "some_constants_to_str",
;

Or DIY

use base qw(Exporter);
our @EXPORT;
my @SYMS;
BEGIN {
	@SYMS = qw(FOO BAR BAZ);
}

use Constant::Generate \@SYMS, -mapname => "some_constants_to_str";

push @EXPORT, @SYMS, "some_constants_to_str";
$EXPORT_TAGS{'some_constants'} = [@SYMS, "some_constants_to_str"];

etc.