From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

MSCHWERN / Test-Simple-1.005000_005 / lib / Test / Builder / Tester / Streamer.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128

              
package Test::Builder::Tester::Streamer;
use TB2::Mouse;
extends 'TB2::Streamer::Debug';
# Test::Builder::Tester helper class to capture and test output
sub expect {
    my $self = shift;
    my $name = shift;
    my @checks = @_;
    foreach my $check (@checks) {
        $check = $self->_translate_Failed_check($check);
        push @{ $self->wanted->{$name} }, ref $check ? $check : "$check\n";
    }
}
sub _translate_Failed_check {
    my( $self, $check ) = @_;
    if( $check =~ /\A(.*)#     (Failed .*test) \((.*?) at line (\d+)\)\Z(?!\n)/ ) {
        $check = "/\Q$1\E#\\s+\Q$2\E.*?\\n?.*?\Qat $3\E line \Q$4\E.*\\n?/";
    }
    return $check;
}
##
# return true iff the expected data matches the got data
sub check {
    my $self = shift;
    my $name = shift;
    # turn off warnings as these might be undef
    local $^W = 0;
    my @checks = @{ $self->wanted->{$name} };
    my $got    = $self->read($name);
    foreach my $check (@checks) {
        $check = "\Q$check\E" unless( $check =~ s,^/(.*)/$,$1, or ref $check );
        return 0 unless $got =~ s/^$check//;
    }
    return length $got == 0;
}
##
# a complaint message about the inputs not matching (to be
# used for debugging messages)
has 'name2handle' =>
  is            => 'ro',
  isa           => 'HashRef',
  default       => sub {
      return {
          out       => 'STDOUT',
          err       => 'STDERR'
      }
  };
sub complaint {
    my $self   = shift;
    my $name   = shift;
    my $type   = $self->name2handle->{$name};
    my $got    = $self->output_for($name);
    my $wanted = join "\n", @{ $self->wanted->{$name} };
    # are we running in colour mode?
    if(Test::Builder::Tester::color()) {
        # get color
        eval { require Term::ANSIColor };
        unless($@) {
            # colours
            my $green = Term::ANSIColor::color("black") . Term::ANSIColor::color("on_green");
            my $red   = Term::ANSIColor::color("black") . Term::ANSIColor::color("on_red");
            my $reset = Term::ANSIColor::color("reset");
            # work out where the two strings start to differ
            my $char = 0;
            $char++ while substr( $got, $char, 1 ) eq substr( $wanted, $char, 1 );
            # get the start string and the two end strings
            my $start = $green . substr( $wanted, 0, $char );
            my $gotend    = $red . substr( $got,    $char ) . $reset;
            my $wantedend = $red . substr( $wanted, $char ) . $reset;
            # make the start turn green on and off
            $start =~ s/\n/$reset\n$green/g;
            # make the ends turn red on and off
            $gotend    =~ s/\n/$reset\n$red/g;
            $wantedend =~ s/\n/$reset\n$red/g;
            # rebuild the strings
            $got    = $start . $gotend;
            $wanted = $start . $wantedend;
        }
    }
    return "$type is:\n" . "$got\nnot:\n$wanted\nas expected";
}
##
# forget all expected and got data
has 'wanted' =>
  is            => 'rw',
  isa           => 'HashRef',
  default       => sub {
      return {
          out   => [],
          err   => [],
      }
  }
;
sub clear {
    my $self = shift;
    $self->SUPER::clear;
    %{$self->wanted} = ( out => [], err => [] );
    return;
}
1;