From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

NERDVANA / OpenGL-Sandbox-0.110 / lib / OpenGL / Sandbox / ContextShim / GLFW.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
—
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133

              
package OpenGL::Sandbox::ContextShim::GLFW;
use strict;
use warnings;
use Carp;
use Scalar::Util 'weaken';
use OpenGL::GLFW qw/ glfwInit glfwGetVersionString glfwTerminate NULL GLFW_TRUE GLFW_FALSE
        glfwGetPrimaryMonitor glfwCreateWindow glfwMakeContextCurrent glfwDestroyWindow
        glfwSwapInterval glfwSwapBuffers glfwPollEvents
        glfwWindowHint GLFW_VISIBLE GLFW_DECORATED GLFW_MAXIMIZED GLFW_DOUBLEBUFFER
        /;
use OpenGL::Sandbox qw/ glGetString GL_VERSION /;
# ABSTRACT: Create OpenGL context with OpenGL::GLFW
our $VERSION = '0.110'; # VERSION
# would use Moo, but I want to write my own constructor rather than store
# all these arguments as official attributes.
our $glfw_init;
our %instances;
sub new {
        my $class= shift;
        my %opts= ref $_[0] eq 'HASH'? %{$_[0]} : @_;
        ($glfw_init //= glfwInit)
                or croak "GLFW Initialization Failed";
        my $self= bless {}, $class;
         
        glfwWindowHint(GLFW_VISIBLE, ($opts{visible} // 1)? GLFW_TRUE : GLFW_FALSE);
        glfwWindowHint(GLFW_DECORATED, $opts{noframe}? GLFW_FALSE : GLFW_TRUE);
        #glfwWindowHint(GLFW_MAXIMIZED, $opts{fullscreen}? GLFW_TRUE : GLFW_FALSE);
         
        my $w= glfwCreateWindow(
                $opts{width} // 640, # width
                $opts{height} // 480, # height
                $opts{title} // 'OpenGL', # title
                $opts{fullscreen}? glfwGetPrimaryMonitor() : NULL, # monitor
                NULL # share_window
        ) or croak "glfwCreateWindow failed";
        $self->{window}= $w;
         
        glfwSetWindowPos($w, $opts{x}//0, $opts{y}//0)
                if $opts{x} || $opts{y};
         
        glfwMakeContextCurrent($w);
        glfwSwapInterval(1) if $opts{vsync} // 1;
         
        weaken($instances{$self}= $self);
        return $self;
}
sub DESTROY {
        my $self= shift;
        glfwDestroyWindow(delete $self->{window}) if defined $self->{window};
        delete $instances{$self};
}
END {
        for (values %instances) {
                glfwDestroyWindow(delete $_->{window}) if defined $_->{window};
        }
        glfwTerminate if $glfw_init;
}
sub window { shift->{window} }
sub context_info {
        my $self= shift;
        sprintf("OpenGL::GLFW %s, glfw version %s, OpenGL version %s\n",
                OpenGL::GLFW->VERSION, glfwGetVersionString(), glGetString(GL_VERSION));
}
sub swap_buffers {
        my $self= shift;
        if ($self->window) {
                glfwSwapBuffers($self->window);
                glfwPollEvents;
        }
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
OpenGL::Sandbox::ContextShim::GLFW - Create OpenGL context with OpenGL::GLFW
=head1 VERSION
version 0.110
=head1 DESCRIPTION
This class is loaded automatically if needed by L<OpenGL::Sandbox/make_context>.
It uses L<OpenGL::GLFW> to create an OpenGL context.
=head1 ATTRIBUTES
=head2 window
The GLFW window handle
=head1 METHODS
=head2 Standard ContextShim API:
=over 14
=item new
Accepting all the options of L<OpenGL::Sandbox/make_context>
=item context_info
=item swap_buffers
=back
=head1 AUTHOR
Michael Conrad <mike@nrdvana.net>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2019 by Michael Conrad.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut