Dave Cross: Still Munging Data With Perl: Online event - Mar 17 Learn more

NPEREZ / Data-Morph-1.113280 / lib / Data / Morph / Backend / DBIC.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
—
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176

              
package Data::Morph::Backend::DBIC;
{
  $Data::Morph::Backend::DBIC::VERSION = '1.113280';
}
#ABSTRACT: Provides a Data::Morph backend for DBIx::Class
use Moose;
use Moose::Util::TypeConstraints;
use MooseX::Types::Moose(':all');
use MooseX::Params::Validate;
use Devel::PartialDump('dump');
use namespace::autoclean;
use DBIx::Class;
use Scalar::Util('weaken');
has result_set =>
(
    is => 'ro',
    isa => class_type('DBIx::Class::ResultSet'),
    required => 1,
);
has auto_insert =>
(
    is => 'ro',
    isa => Bool,
    default => 0,
);
has new_instance =>
(
    is => 'ro',
    isa => CodeRef,
    lazy => 1,
    builder => '_build_new_instance',
);
sub _build_new_instance
{
    my ($self) = @_;
    weaken($self);
    return sub { $self->result_set->new_result({}) };
}
sub epilogue
{
    my ($self, $obj) = @_;
    $obj->update_or_insert
        if $self->auto_insert;
}
with 'Data::Morph::Role::Backend' =>
{
    input_type => class_type('DBIx::Class::Row'),
    get_val => sub
    {
        my ($obj, $key) = @_;
        if($obj->can($key))
        {
            return $obj->$key;
        }
        elsif($obj->has_column($key))
        {
            return +{$obj->get_inflated_columns}->{$key};
        }
        else
        {
            die "Can't find '$key' column in: " . dump($obj);
        }
    },
    set_val => sub
    {
        my ($obj, $key, $value) = @_;
        if($obj->can($key))
        {
            $obj->$key($value);
        }
        elsif($obj->has_column($key))
        {
            return $obj->set_inflated_columns({$key => $value});
        }
        else
        {
            die "Can't find '$key' column in: " . dump($obj);
        }
    }
};
__PACKAGE__->meta->make_immutable();
1;
=pod
=head1 NAME
Data::Morph::Backend::DBIC - Provides a Data::Morph backend for DBIx::Class
=head1 VERSION
version 1.113280
=head1 DESCRIPTION
Data::Morph::Backend::DBIC implements a L<Data::Morph> backend that talks to a
database via DBIx::Class. New instances or rows are created from the passed in
L<DBIx::Class::ResultSet> to the constructor. Values are set and retrieved from
the row using the following logic: If there is an accessor, use it, if not, see
if it has a column, use inflated_columns methods, if not die. So directives
defined in the map for reading and writing should match either accessors or
column names
=head1 PUBLIC_ATTRIBUTES
=head2 result_set
    is: ro, isa: DBIx::Class::ResultSet, required: 1
This attribute holds the active ResultSet that should be used when creating new
rows
=head2 auto_insert
    is: ro, isa: Bool, default: false
During the execution of the L</epilogue>, this attribute is checked to see if
the newly created and populated instance should be inserted into the database
=head2 new_instance
    is: ro, isa: CodeRef, lazy: 1, builder: _build_new_instance
This attribute overrides what is provided in L<Data::Morph::Role::Backend> and
uses a builder method that returns a coderef that uses L</result_set> to return
a new row using L<DBIx::Class::ResultSet/new_result>
=head1 PUBLIC_METHODS
=head2 epilogue
    (DBIx::Class::Row)
This method implements L<Data::Morph::Role::Backend/epilogue>. It reads
L</auto_insert> to determine if the row should be inserted into the database.
=head1 PROTECTED_METHODS
=head2 _build_new_instance
This is the builder method for L</new_instance>. If special logic is needed in
creation of the instance factory, simply override or advise this method as
needed. By default, it returns a CodeRef that builds L<DBIx::Class::Row>
objects using L<DBIx::Class::ResultSet/new_result> upon the L</result_set>
=head1 AUTHOR
Nicholas R. Perez <nperez@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2011 by Nicholas R. Perez <nperez@cpan.org>.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
__END__