NAME

SNMP::Info::Bridge - SNMP Interface to SNMP data available through the BRIDGE-MIB (RFC1493)

AUTHOR

Max Baker

SYNOPSIS

my $bridge = new SNMP::Info (
                            AutoSpecify => 1,
                            Debug       => 1,
                            DestHost    => 'switch',
                            Community   => 'public',
                            Version     => 2
                            );

my $class = $bridge->class();
print " Using device sub class : $class\n";

# Grab Forwarding Tables
my $interfaces = $bridge->interfaces();
my $fw_mac     = $bridge->fw_mac();
my $fw_port    = $bridge->fw_port();
my $bp_index   = $bridge->bp_index();

foreach my $fw_index (keys %$fw_mac){
   my $mac   = $fw_mac->{$fw_index};
   my $bp_id = $fw_port->{$fw_index};
   my $iid   = $bp_index->{$bp_id};
   my $port  = $interfaces->{$iid};

   print "Port:$port forwarding to $mac\n";
}

List the spanning trees, then read each tree's ports with their state, role and designated bridge. Some devices serve a tree's ports only in an SNMP context of its own; this helper switches to one, as "SNMP Contexts" in SNMP::Info describes:

# Switch to $context; false where this session's SNMP version cannot
# reach it
sub enter_context {
    my ( $info, $context, $community ) = @_;

    return $info->update() if $context->{kind} eq 'none';
    if ( $info->snmp_ver() == 3 ) {
        return unless defined $context->{v3};
        return $info->update( Context => $context->{v3} );
    }
    return unless defined $context->{v2c};
    return $info->update(
        Community => sprintf( $context->{v2c}, $community ) );
}

# Read the list in the default context and keep it: update() clears
# the cache on every switch
my $community = $bridge->snmp_comm();    # before the first switch
my $trees     = $bridge->stp_trees() || {};
my $complete  = $bridge->stp_trees_complete();
if ( !defined $complete ) {
    print "The device serves no spanning tree\n";
}
elsif ( !$complete ) {
    print "The tree list may be missing trees\n";
}

# Read the ports in place where no tree needs a context; otherwise in
# every context a tree lists, merging the rows
my $switch = $bridge->context_kinds('stp');
my %tree_ports;    # tree key => { iid => port record }
foreach my $key ( sort keys %$trees ) {
    unless ($switch) {
        $tree_ports{$key} = { %{ $bridge->stp_tree_ports($key) || {} } };
        next;
    }
    foreach my $context ( @{ $trees->{$key}{contexts} } ) {
        # A context that cannot be entered is skipped silently, and
        # its tree is then listed with no ports
        enter_context( $bridge, $context, $community ) or next;
        my $ports = $bridge->stp_tree_ports($key) || {};
        $tree_ports{$key}{$_} = $ports->{$_} foreach keys %$ports;
    }
}
$bridge->update() if $switch;

foreach my $key ( sort keys %$trees ) {
    my $tree = $trees->{$key};
    printf "%s, %s: root %s\n", $key, $tree->{protocol} // 'unknown',
        $tree->{root} ? $tree->{root}{mac} : 'not served';
    print "  Some ports were not read\n" unless $tree->{ports_complete};

    my $ports = $tree_ports{$key} || {};
    foreach my $iid ( sort { $a <=> $b } keys %$ports ) {
        my $port = $ports->{$iid};
        my $designated = $port->{designated_bridge};
        printf "  %s: %s, %s, designated bridge %s\n",
            $interfaces->{$iid} // $iid,
            $port->{state} // 'no state',
            $port->{role}  // 'no role',
            $designated ? $designated->{mac} : 'not served';
    }
}

DESCRIPTION

BRIDGE-MIB is used by most Layer 2 devices, and holds information like the MAC Forwarding Table and Spanning Tree Protocol info.

Q-BRIDGE-MIB holds 802.1q information -- VLANs and Trunking. Cisco tends not to use this MIB, but some proprietary ones. HP and some nicer vendors use this. This is from RFC2674_q.

Create or use a subclass of SNMP::Info that inherits this class. Do not use directly.

For debugging you can call new() directly as you would in SNMP::Info

my $bridge = new SNMP::Info::Bridge(...);

Terms

These terms are used by "Spanning Tree Trees" and the classes that override it.

spanning tree, tree: One loop-free topology the device computes. A device can run several: one per MST instance, one per VLAN, or one per STP domain.
protocol: The spanning tree flavor the device runs, as stp_protocols() names it: 802.1D STP, 802.1w RSTP, 802.1s MSTP, or a vendor protocol with one tree per VLAN.
CIST: The common and internal spanning tree. Under MSTP it is instance 0, which every port belongs to; under STP and RSTP it is the device's one tree. Its key is cist.0.
MSTI: A multiple spanning tree instance: an MSTP tree, numbered from 1, that carries the VLANs mapped to it. Its key is msti.N.
PVST+, Rapid-PVST+: Per-VLAN spanning tree, based on 802.1D and on 802.1w: one tree per VLAN. Cisco and H3C devices key each tree vlan.N. Extreme devices run it in an STP domain.
VSTP: Juniper's VLAN Spanning Tree Protocol: one tree per VLAN, each served in its own context. Its key is vlan.N, or vlan.N@instance in a routing instance other than default.
STP domain: An Extreme spanning tree domain, which is one tree. Its key is domain.N.
tree key: The key of a tree in stp_trees(), in one of the forms above. Pass it to stp_tree_ports().
bridge ID: The priority and MAC address that identify a bridge in a tree.
root: The bridge with the lowest bridge ID in a tree. Every other bridge forwards toward it.
designated bridge, designated port: The bridge, and its port, that forwards toward the root for one LAN segment. A port whose designated bridge is another bridge connects to that bridge's designated port.
port role: A port's part in the tree under RSTP, MSTP and Rapid-PVST+: root, designated, alternate, backup or disabled. MSTP adds master, and Cisco devices also report boundary.
context: An SNMP context, as "SNMP Contexts" in SNMP::Info describes. Some devices serve a tree's ports only in a context other than the default context.
default context: The context a session reaches with the constructor's Community, or with an empty SNMPv3 Context. The tree list is read there.
edge port: A port to end stations rather than to other bridges, which goes straight to forwarding: the IEEE form of Cisco PortFast. i_edgeport_admin() and i_edgeport_oper() report it.

Inherited Classes

None.

Required MIBs

BRIDGE-MIB
Q-BRIDGE-MIB
RSTP-MIB

For Class Authors

A device class that reads a vendor's spanning tree overrides the public methods of "Spanning Tree Trees" with subs, and uses these private hooks and functions of this class.

_stp_default_is_common(): Returns 1 here: the BRIDGE-MIB tree is the device's common tree. Return 0 where it is not, such as where a tree runs per VLAN. This class then reports no tree, and stp_trees_complete() returns 0 (SNMP::Info::CiscoStpExtensions, SNMP::Info::Layer3::Foundry).
_stp_default_context_ok(): Returns 1 in the default context. In any other it sets error(), naming the calling method, and returns 0. Call it first in an override of stp_trees(), and of stp_protocols() where it reads the tree list.
_stp_dot1d_tree(): Returns the BRIDGE-MIB common tree record, whatever _stp_default_is_common() says, or nothing when no tree is served. Set protocol and measured on a copy (SNMP::Info::Layer3::H3C).
_stp_dot1d_port_rows($tree): Returns the BRIDGE-MIB port records of the session's current context, with tree_type and tree_id taken from $tree (SNMP::Info::Layer3::Juniper, for a VSTP tree).
_stp_tree_for_key($tree_key): Returns the record of $tree_key from stp_trees(). For a key not listed it sets error(), naming the calling method, and returns nothing.
_stp_walk_incomplete(@methods): Returns 1 when the last walk of any named table method was incomplete, else 0. A method not yet walked counts as complete, so call it after reading the columns. Name the columns that list the trees, so that stp_trees_complete() returns 0 when the list may be short.
_stp_own_bridge_id(): Returns the device's bridge ID in the BRIDGE-MIB tree, from dot1dStpPriority and dot1dBaseBridgeAddress.
_stp_edge_by_ifindex($self, $edge, $partial, $decode, $port_index): Maps edge port values keyed by bridge port to ifIndex through bp_index(), or through $port_index when given, read as 1 or 0 by $decode (default _stp_enabled). A class outside this class's inheritance calls it as a function, passing the object as $self (SNMP::Info::RapidCity).
Functions: SNMP::Info::Bridge::_stp_decode_bridge_id($id) and _stp_decode_port_id($id) turn a served bridge ID or port ID into the hashes stp_trees() and stp_tree_ports() return. _stp_bridge_id_from($priority, $mac) builds a bridge ID from its two parts. _stp_enabled($value) reads enabled(1), true(1) and their labels as 1, disabled(2) and false(2) as 0, else undef. Call them by full name.
The tree cache: Keep the tree list in $self->{_stp_trees}, and only when it is not empty. clear_cache(), and so update(), then resets it.
Protocol tests: Define hasSTP(), hasRSTP(), hasMSTP(), hasPVST(), hasRapidPVST() or hasVSTP() only for the protocols the class can read, each returning 1 or 0.
Contexts: Where a tree's ports are served in other contexts, answer context_kinds('stp') and snmp_context() through the hooks "SNMP Contexts" in SNMP::Info names.

GLOBALS

These are methods that return scalar values from SNMP

$bridge->b_mac()

Returns the MAC Address of the root bridge port

(dot1dBaseBridgeAddress)

$bridge->b_ports()

Returns the number of ports in device

(dot1dBaseNumPorts)

$bridge->b_type()

Returns the type of bridging this bridge can perform, transparent and/or source route.

(dot1dBaseType)

$bridge->stp_ver()

Returns what version of STP the device is running.

(dot1dStpProtocolSpecification)

$bridge->stp_time()

Returns time since last topology change detected. (100ths/second)

(dot1dStpTimeSinceTopologyChange)

$bridge->stp_root()

Returns root of STP.

(dot1dStpDesignatedRoot)

$bridge->qb_vlans_max()

Maximum number of VLANS supported on this device.

(dot1qMaxSupportedVlans)

$bridge->qb_vlans()

Current number of VLANs that are configured in this device.

(dot1qNumVlans)

$bridge->qb_next_vlan_index()

The next available value for dot1qVlanIndex of a local VLAN entry in dot1qVlanStaticTable

(dot1qNextFreeLocalVlanIndex)

TABLE METHODS

These are methods that return tables of information in the form of a reference to a hash.

$bridge->i_vlan()

Returns a mapping between ifIndex and the PVID or default VLAN.

$vtp->i_untagged()

An alias for i_vlan.

$bridge->i_vlan_membership()

Returns reference to hash of arrays: key = ifIndex, value = array of VLAN IDs. These are the VLANs which are members of the egress list for the port.

Example:
my $interfaces = $bridge->interfaces();
my $vlans      = $bridge->i_vlan_membership();

foreach my $iid (sort keys %$interfaces) {
  my $port = $interfaces->{$iid};
  my $vlan = join(',', sort(@{$vlans->{$iid}}));
  print "Port: $port VLAN: $vlan\n";
}

$bridge->i_vlan_membership_untagged()

Returns reference to hash of arrays: key = ifIndex, value = array of VLAN IDs. These are the VLANs which are members of the untagged egress list for the port.

$bridge->qb_i_vlan_t()

Returns reference to hash: key = dot1dBasePort, value = either 'trunk' for tagged ports or the VLAN ID.

$bridge->qb_fdb_index()

Returns reference to hash: key = FDB ID, value = VLAN ID.

An FDB ID shared by several VLANs (shared VLAN learning) maps to undef.

$bridge->v_index()

Returns VLAN IDs

Forwarding Table (`dot1dTpFdbEntry`)

Some devices serve this table once per VLAN, each in its own SNMP context. Check with context_kinds() in SNMP::Info.

$bridge->fw_mac()

Returns reference to hash of forwarding table MAC Addresses

(dot1dTpFdbAddress)

$bridge->fw_port()

Returns reference to hash of forwarding table entries port interface identifier (iid)

(dot1dTpFdbPort)

$bridge->fw_status()

Returns reference to hash of forwarding table entries status

(dot1dTpFdbStatus)

Bridge Port Table (`dot1dBasePortEntry`)

$bridge->bp_index()

Returns reference to hash of bridge port table entries map back to interface identifier (iid)

(dot1dBasePortIfIndex)

$bridge->bp_port()

Returns reference to hash of bridge port table entries for a port which (potentially) has the same value of dot1dBasePortIfIndex as another port on the same bridge, this object contains the name of an object instance unique to this port.

(dot1dBasePortCircuit)

Spanning Tree Instance Globals

These are not part of a table, but return a hash reference to ease API compatibility with MST and PVST implementations indexed by a spanning tree instance id.

$bridge->stp_i_time()

Returns time since last topology change detected. (100ths/second)

(dot1dStpTimeSinceTopologyChange)

$bridge->stp_i_time()

Returns the total number of topology changes detected.

(dot1dStpTopChanges)

$bridge->stp_i_root()

Returns root of STP.

(dot1dStpDesignatedRoot)

$bridge->stp_i_root_port()

Returns the port number of the port that offers the lowest cost path to the root bridge.

(dot1dStpRootPort)

$bridge->stp_i_priority()

Returns the port number of the port that offers the lowest cost path to the root bridge.

(dot1dStpPriority)

Spanning Tree Protocol Table (`dot1dStpPortTable`)

Descriptions are straight from BRIDGE-MIB.my

$bridge->stp_p_id()

"The port number of the port for which this entry contains Spanning Tree Protocol management information."

(dot1dStpPort)

$bridge->stp_p_priority()

"The value of the priority field which is contained in the first (in network byte order) octet of the (2 octet long) Port ID. The other octet of the Port ID is given by the value of dot1dStpPort."

(dot1dStpPortPriority)

$bridge->stp_p_enable()

"The enabled/disabled status of the port."

(dot1dStpPortEnable)

$bridge->stp_p_state()

"The port's current state as defined by application of the Spanning Tree Protocol. This state controls what action a port takes on reception of a frame. If the bridge has detected a port that is malfunctioning it will place that port into the broken(6) state. For ports which are disabled (see dot1dStpPortEnable), this object will have a value of disabled(1)."

disabled(1)
blocking(2)
listening(3)
learning(4)
forwarding(5)
broken(6)

(dot1dStpPortState)

$bridge->stp_p_cost()

"The contribution of this port to the path cost of paths towards the spanning tree root which include this port. 802.1D-1990 recommends that the default value of this parameter be in inverse proportion to the speed of the attached LAN."

(dot1dStpPortPathCost)

$bridge->stp_p_root()

"The unique Bridge Identifier of the Bridge recorded as the Root in the Configuration BPDUs transmitted by the Designated Bridge for the segment to which the port is attached."

(dot1dStpPortDesignatedRoot)

$bridge->stp_p_bridge()

"The Bridge Identifier of the bridge which this port considers to be the Designated Bridge for this port's segment."

(dot1dStpPortDesignatedBridge)

$bridge->stp_p_port()

(dot1dStpPortDesignatedPort)

"The Port Identifier of the port on the Designated Bridge for this port's segment."

$bridge->i_stp_port()

Returns the mapping of (dot1dStpPortDesignatedPort) to the interface index (iid).

$bridge->i_stp_state()

Returns the mapping of (dot1dStpPortState) to the interface index (iid): the port state in the device's default spanning tree.

BRIDGE-MIB indexes spanning tree ports by port number alone, with no instance or VLAN. On a device running more than one tree (MSTP instances, a tree per VLAN, or vendor STP domains) this is the one tree the agent exposes in the polled context, not the port's state in every VLAN. Where a device class reports another tree here, its own documentation says which. See "Spanning Tree Trees" for every tree the device runs.

$bridge->i_edgeport_admin()

Returns 1 or 0 for each port by whether it is configured as an edge port (the IEEE equivalent of PortFast). Format is a hash reference with key = ifIndex, value = [1|0]. A port with no administrative value is absent.

(dot1dStpPortAdminEdgePort)

$bridge->i_edgeport_oper()

Returns 1 or 0 for each port by whether it currently operates as an edge port. Format is a hash reference with key = ifIndex, value = [1|0]. A port with no operational value is absent.

(dot1dStpPortOperEdgePort)

$bridge->i_stp_id()

Returns the mapping of (dot1dStpPort) to the interface index (iid).

$bridge->i_stp_bridge()

Returns the mapping of (dot1dStpPortDesignatedBridge) to the interface index (iid).

Spanning Tree Trees

These methods report each spanning tree the device runs, and each tree's ports with their state, role, designated bridge and designated port. The SYNOPSIS shows them in use, and "Terms" defines the terms.

Read the tree list in the default context, and keep it: update() clears the cache on every context switch.
Read a tree's ports in the contexts its record lists. Where context_kinds('stp') returns nothing, every tree's ports are read in the default context. See "SNMP Contexts" in SNMP::Info.
Every port record names its tree, so a row read in another context still says which tree it describes.

This class reports the BRIDGE-MIB tree as the one tree cist.0, with its protocol unknown. These classes read the vendor's trees instead, and their documentation says what they fill and from where: SNMP::Info::CiscoStpExtensions, SNMP::Info::Layer3::Extreme, SNMP::Info::Layer3::H3C, SNMP::Info::Layer3::Juniper and SNMP::Info::RapidCity. SNMP::Info::Layer3::Foundry and SNMP::Info::Layer3::HP9300 report no tree.

Some classes also define hasSTP(), hasRSTP(), hasMSTP(), hasPVST(), hasRapidPVST() or hasVSTP(), each 1 when the device runs that protocol and 0 otherwise. Where the device names its protocol the test reads that object; elsewhere the class infers it, as its documentation says. As with has_topo() in SNMP::Info, test can() before calling one.

$bridge->stp_protocols()

Returns a reference to an array of the spanning tree protocols the device reports, or nothing when none is known. A device class can report a protocol while stp_trees() is empty. The values:

stp: 802.1D STP.
rstp: 802.1w RSTP.
mstp: 802.1s MSTP.
pvst: PVST+, one 802.1D tree per VLAN.
rapid-pvst: Rapid-PVST+, one 802.1w tree per VLAN.
vstp: Juniper VSTP, one tree per VLAN (SNMP::Info::Layer3::Juniper).
dot1d: A BRIDGE-MIB tree is served, but no object says which protocol it runs.

This class returns ['dot1d'] when stp_trees() holds the BRIDGE-MIB tree, and nothing otherwise. Nothing does not mean the device runs no spanning tree: check stp_trees_complete().

$bridge->stp_trees()

Returns a reference to a hash of tree records, keyed by tree key. Returns nothing, with error() set, when the session is in a context other than the default context, since only the default context serves the whole list. The tree keys:

cist.0: The CIST: the one tree under STP and RSTP, instance 0 under MSTP.
msti.N: MST instance N.
vlan.N: The tree of VLAN N, under PVST+, Rapid-PVST+ or VSTP.
vlan.N@instance: The VSTP tree of VLAN N in the Juniper routing instance instance.
domain.N: Extreme STP domain N.

Each record has these fields:

type

cist, msti, vlan or domain, as in the key.

id

The number in the key: 0 for cist, the MST instance for msti, the VLAN id for vlan, the domain instance for domain.

protocol

The protocol this tree runs, as stp_protocols() names it, except dot1d. Undef when the device does not say.

measured

1 when this class's reading of that platform and protocol is known to match what the device reports, 0 when it is not verified. Always 0 in this class.

ports_complete

Whether stp_tree_ports(), read in every context in contexts, returns every port of the tree. Never undef.

1: Every port of the tree is returned.
0: Some ports may be missing: for example a port row has no ifIndex in bp_index(), the device serves no port rows for the tree, or a walk ended early. Each class lists its cases.

contexts

A reference to an array of the contexts that serve the tree's ports, in the order to read them. Read stp_tree_ports() in each, and merge the rows: each context can serve only some of the ports. Each entry is either:

{ kind => 'none' }: the default context.
A context as snmp_context() in SNMP::Info describes it, with kind, id, v2c and v3. A class can add a key, such as SNMP::Info::Layer3::Juniper's instance.

The array is empty when no context serves the tree's ports.

bridge

This device's bridge ID in the tree. Undef where the class cannot read it.

root

The bridge ID of the tree's root. Undef where the default context does not serve it.

vlan

The VLAN the tree runs for. Present only where the class fills it: Cisco PVST+ and Rapid-PVST+, H3C PVST, Juniper VSTP, and an Extreme domain with a carrier VLAN.

name

The domain name. Extreme only.

instance

The routing instance. Juniper VSTP only.

A bridge ID is a reference to a hash:

priority: The bridge priority, a multiple of 4096.
sys_id_ext: The system ID extension: the low 12 bits of the served priority, which most devices set to the VLAN or MST instance.
mac: The bridge MAC address.
raw: The bridge ID as served, eight octets in hex, colon separated.

An example record, the Rapid-PVST+ tree of VLAN 10 on a Cisco IOS switch:

'vlan.10' => {
    type           => 'vlan',
    id             => 10,
    vlan           => 10,
    protocol       => 'rapid-pvst',
    measured       => 1,
    ports_complete => 1,
    contexts       => [
        {
            kind => 'vlan',
            id   => 10,
            v2c  => '%s@10',
            v3   => 'vlan-10',
        },
    ],
    bridge => undef,
    root   => undef,
}

$bridge->stp_trees_complete()

Returns whether stp_trees() lists every tree the device runs:

1: The list is whole. A tree that is not listed does not run.
0: The list may be missing trees: the class does not read them, a walk that lists them was incomplete (see "Incomplete Walks" in SNMP::Info), or the session is in a context other than the default context. Treat the list as partial.
undef: The device serves no tree that this class reads.

This class never returns 1, since BRIDGE-MIB cannot show whether other trees run. It returns 0 when it reports the BRIDGE-MIB tree, and undef when that is not served. A device class that reads its trees returns 1 or 0, never undef.

$bridge->stp_vlan_map()

Returns reference to hash mapping each VLAN id to the key of the tree that carries it, as the device serves the map, or nothing where it serves none. This class serves none: one BRIDGE-MIB tree carries every VLAN.

$bridge->stp_tree_ports($tree_key)

Returns a reference to a hash of port records for the tree $tree_key, keyed by ifIndex, read in the session's current context. Returns nothing, with error() set, for a key that is not in stp_trees().

This class reads BRIDGE-MIB directly, but looks the key up in stp_trees(), which answers only in the default context, so it answers only there. A device class whose trees are served in other contexts reads them there, as its documentation says.

Each record has these fields:

tree_type, tree_id: The tree's type and id.
state: The port's state in the tree, as the device serves it. It is not normalized: BRIDGE-MIB serves disabled, blocking, listening, learning, forwarding or broken, and vendor MIBs can serve other labels, such as discarding. Undef when not served.
role: The port role: disabled, root, designated, alternate, backup, boundary or master. Undef when the device serves no role, or a value the class does not know.
role_raw: The role as served. Undef when not served.
enabled: 1 when the device runs spanning tree on the port, 0 when it does not, undef when not served.
designated_bridge: The bridge ID of the port's designated bridge, as in stp_trees(). Undef when not served.
designated_port: The port ID of the designated port, a reference to a hash: priority, the port priority; port, the port number on the designated bridge; and raw, the port ID as served. Undef when not served.

An example record, a port read in VLAN 10's context on the switch above:

3 => {
    tree_type         => 'vlan',
    tree_id           => 10,
    state             => 'blocking',
    role              => 'alternate',
    role_raw          => 'alternate',
    enabled           => 1,
    designated_bridge => {
        priority   => 32768,
        sys_id_ext => 10,
        mac        => '02:00:00:00:00:0b',
        raw        => '80:0a:02:00:00:00:00:0b',
    },
    designated_port => {
        priority => 128,
        port     => 3,
        raw      => '80:03',
    },
}

Q-BRIDGE Port VLAN Table (`dot1qPortVlanTable`)

$bridge->qb_i_vlan()

The PVID, the VLAN ID assigned to untagged frames or Priority-Tagged frames received on this port.

(dot1qPvid)

$bridge->qb_i_vlan_type()

Either admitAll or admitOnlyVlanTagged. This is a good spot to find trunk ports.

(dot1qPortAcceptableFrameTypes)

$bridge->qb_i_vlan_in_flt()

When this is true the device will discard incoming frames for VLANs which do not include this Port in its Member set. When false, the port will accept all incoming frames.

(dot1qPortIngressFiltering)

Q-BRIDGE VLAN Current Table (`dot1qVlanCurrentTable`)

$bridge->qb_cv_egress()

The set of ports which are assigned to the egress list for this VLAN.

(dot1qVlanCurrentEgressPorts)

$bridge->qb_cv_untagged()

The set of ports which should transmit egress packets for this VLAN as untagged.

(dot1qVlanCurrentUntaggedPorts)

$bridge->qb_cv_stat()

Status of the VLAN, other, permanent, or dynamicGvrp.

(dot1qVlanStatus)

Q-BRIDGE VLAN Static Table (`dot1qVlanStaticTable`)

$bridge->qb_v_name()

Human-entered name for vlans.

(dot1qVlanStaticName)

$bridge->qb_v_egress()

The set of ports which are assigned to the egress list for this VLAN.

(dot1qVlanStaticEgressPorts)

$bridge->qb_v_fbdn_egress()

The set of ports which are prohibited from being included in the egress list for this VLAN.

(dot1qVlanForbiddenEgressPorts)

$bridge->qb_v_untagged()

The set of ports which should transmit egress packets for this VLAN as untagged.

(dot1qVlanStaticUntaggedPorts)

$bridge->qb_v_stat()

active !

(dot1qVlanStaticRowStatus)

Q-BRIDGE Filtering Database Table (`dot1qFdbTable`)

$bridge->qb_fw_mac()

Returns reference to hash of forwarding table MAC Addresses

(dot1qTpFdbAddress)

$bridge->qb_fw_port()

Returns reference to hash of forwarding table entries port interface identifier (iid)

(dot1qTpFdbPort)

$bridge->qb_fw_vlan()

Returns reference to hash of forwarding table entries VLAN ID

Entries whose FDB ID is shared by several VLANs have an undef VLAN ID. Entries whose FDB ID has no mapping use the FDB ID as the VLAN ID.

$bridge->qb_fw_status()

Returns reference to hash of forwarding table entries status

(dot1qTpFdbStatus)

SET METHODS

These are methods that provide SNMP set functionality for overridden methods or provide a simpler interface to complex set operations. See "SETTING DATA VIA SNMP" in SNMP::Info for general information on set operations.

$bridge->set_i_vlan(vlan, ifIndex): Currently unsupported. Throws an error and returns.
$bridge->set_i_untagged(vlan, ifIndex): An alias for set_i_vlan.
$bridge->set_i_pvid(pvid, ifIndex): Currently unsupported. Throws an error and returns.
$bridge->set_add_i_vlan_tagged(vlan, ifIndex): Currently unsupported. Throws an error and returns.
$bridge->set_remove_i_vlan_tagged(vlan, ifIndex): Currently unsupported. Throws an error and returns.

To install SNMP::Info, copy and paste the appropriate command in to your terminal.

cpanm

cpanm SNMP::Info

CPAN shell

perl -MCPAN -e shell
install SNMP::Info

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	Go to GitHub issues (only if GitHub is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

AUTHOR

SYNOPSIS

DESCRIPTION

Terms

Inherited Classes

Required MIBs

For Class Authors

GLOBALS

TABLE METHODS

Forwarding Table (dot1dTpFdbEntry)

Bridge Port Table (dot1dBasePortEntry)

Spanning Tree Instance Globals

Spanning Tree Protocol Table (dot1dStpPortTable)

Spanning Tree Trees

Q-BRIDGE Port VLAN Table (dot1qPortVlanTable)

Q-BRIDGE VLAN Current Table (dot1qVlanCurrentTable)

Q-BRIDGE VLAN Static Table (dot1qVlanStaticTable)

Q-BRIDGE Filtering Database Table (dot1qFdbTable)