NAME

Unicode::Collate - Unicode Collation Algorithm

SYNOPSIS

use Unicode::Collate;

#construct
$Collator = Unicode::Collate->new(%tailoring);

#sort
@sorted = $Collator->sort(@not_sorted);

#compare
$result = $Collator->cmp($a, $b); # returns 1, 0, or -1.

# If %tailoring is false (i.e. empty),
# $Collator should do the default collation.

DESCRIPTION

This module is an implementation of Unicode Technical Standard #10 (UTS #10) "Unicode Collation Algorithm."

Constructor and Tailoring

The new method returns a collator object.

$Collator = Unicode::Collate->new(
   UCA_Version => $UCA_Version,
   alternate => $alternate,
   backwards => $levelNumber, # or \@levelNumbers
   entry => $element,
   hangul_terminator => $term_primary_weight,
   ignoreName => qr/$ignoreName/,
   ignoreChar => qr/$ignoreChar/,
   katakana_before_hiragana => $bool,
   level => $collationLevel,
   normalization  => $normalization_form,
   overrideCJK => \&overrideCJK,
   overrideHangul => \&overrideHangul,
   preprocess => \&preprocess,
   rearrange => \@charList,
   table => $filename,
   undefName => qr/$undefName/,
   undefChar => qr/$undefChar/,
   upper_before_lower => $bool,
   variable => $variable,
);

UCA_Version

If the tracking version number of the older UCA is given, the older behavior of that tracking version is emulated on collating. If omitted, the return value of UCA_Version() is used.

The supported tracking version: 8, 9, or 11.

This parameter may be removed in the future version, as switching the algorithm would affect the performance.

backwards

-- see 3.1.2 French Accents, UTS #10.

backwards => $levelNumber or \@levelNumbers

Weights in reverse order; ex. level 2 (diacritic ordering) in French. If omitted, forwards at all the levels.

entry

-- see 3.1 Linguistic Features; 3.2.1 File Format, UTS #10.

Overrides a default order or defines additional collation elements

entry => <<'ENTRIES', # use the UCA file format
00E6 ; [.0861.0020.0002.00E6] [.08B1.0020.0002.00E6] # ligature <ae> as <a><e>
0063 0068 ; [.0893.0020.0002.0063]      # "ch" in traditional Spanish
0043 0068 ; [.0893.0020.0008.0043]      # "Ch" in traditional Spanish
ENTRIES

NOTE: The code point in the UCA file format (before ';') must be a Unicode code point, but not a native code point. So 0063 must always denote U+0063, but not a character of "\x63".

hangul_terminator

-- see Condition B.2. in 7.1.4 Trailing Weights, UTS #10.

If a true value is given (non-zero but should be positive), it will be added as a terminator primary weight to the end of every standard Hangul syllable. Secondary and any higher weights for terminator are set to zero. If the value is false or hangul_terminator key does not exist, insertion of terminator weights will not be performed.

Boundaries of Hangul syllables are determined according to conjoining Jamo behavior in the Unicode Standard and HangulSyllableType.txt.

Implementation Note: Addition of a terminator primary weight is limited to a boundary between collation elements. Non-conjoining Hangul letters (Compatibility Jamo, halfwidth Jamo, and enclosed letters) are not automatically terminated with a terminator primary weight.

ignoreName

ignoreChar

-- see Completely Ignorable, 3.2.2 Variable Weighting, UTS #10.

Makes the entry in the table completely ignorable; i.e. as if the weights were zero at all level.

E.g. when 'a' and 'e' are ignorable, 'element' is equal to 'lament' (or 'lmnt').

level

-- see 4.3 Form a sort key for each string, UTS #10.

Set the maximum level. Any higher levels than the specified one are ignored.

Level 1: alphabetic ordering
Level 2: diacritic ordering
Level 3: case ordering
Level 4: tie-breaking (e.g. in the case when variable is 'shifted')

ex.level => 2,

If omitted, the maximum is the 4th.

normalization

-- see 4.1 Normalize each input string, UTS #10.

If specified, strings are normalized before preparation of sort keys (the normalization is executed after preprocess).

A form name Unicode::Normalize::normalize() accepts will be applied as $normalization_form. Acceptable names include 'NFD', 'NFC', 'NFKD', and 'NFKC'. See Unicode::Normalize::normalize() for detail. If omitted, 'NFD' is used.

normalization is performed after preprocess (if defined).

Furthermore, special values, undef and "prenormalized", can be used, though they are not concerned with Unicode::Normalize::normalize().

If undef (not a string "undef") is passed explicitly as the value for this key, any normalization is not carried out (this may make tailoring easier if any normalization is not desired). Under (normalization => undef), only contiguous contractions are resolved; e.g. A-cedilla-ring would be primary equal to A, even if A-ring (and A-ring-cedilla) is ordered after Z. In this point, (normalization => undef, preprocess => sub { NFD(shift) }) is not equivalent to (normalization => 'NFD').

In the case of (normalization => "prenormalized"), any normalization is not performed, but non-contiguous contractions with combining characters are performed. Therefore (normalization => 'prenormalized', preprocess => sub { NFD(shift) }) is equivalent to (normalization => 'NFD'). If source strings are finely prenormalized, (normalization => 'prenormalized') may save time for normalization.

Except (normalization => undef), Unicode::Normalize is required (see also CAVEAT).

overrideCJK

-- see 7.1 Derived Collation Elements, UTS #10.

By default, CJK Unified Ideographs are ordered in Unicode codepoint order (but CJK Unified Ideographs [U+4E00 to U+9FA5] are lesser than CJK Unified Ideographs Extension [U+3400 to U+4DB5 and U+20000 to U+2A6D6].

Through overrideCJK, ordering of CJK Unified Ideographs can be overrided.

ex. CJK Unified Ideographs in the JIS code point order.

overrideCJK => sub {
    my $u = shift;             # get a Unicode codepoint
    my $b = pack('n', $u);     # to UTF-16BE
    my $s = your_unicode_to_sjis_converter($b); # convert
    my $n = unpack('n', $s);   # convert sjis to short
    [ $n, 0x20, 0x2, $u ];     # return the collation element
},

ex. ignores all CJK Unified Ideographs.

overrideCJK => sub {()}, # CODEREF returning empty list

 # where ->eq("Pe\x{4E00}rl", "Perl") is true
 # as U+4E00 is a CJK Unified Ideograph and to be ignorable.

If undef is passed explicitly as the value for this key, weights for CJK Unified Ideographs are treated as undefined. But assignment of weight for CJK Unified Ideographs in table or entry is still valid.

overrideHangul

-- see 7.1 Derived Collation Elements, UTS #10.

By default, Hangul Syllables are decomposed into Hangul Jamo. But the mapping of Hangul Syllables may be overrided.

This tag works like overrideCJK, so see there for examples.

If you want to override the mapping of Hangul Syllables, the Normalization Forms D and KD are not appropriate (they will be decomposed before overriding).

If undef is passed explicitly as the value for this key, weight for Hangul Syllables is treated as undefined without decomposition into Hangul Jamo. But definition of weight for Hangul Syllables in table or entry is still valid.

preprocess

-- see 5.1 Preprocessing, UTS #10.

If specified, the coderef is used to preprocess before the formation of sort keys.

ex. dropping English articles, such as "a" or "the". Then, "the pen" is before "a pencil".

preprocess => sub {
      my $str = shift;
      $str =~ s/\b(?:an?|the)\s+//gi;
      return $str;
   },

preprocess is performed before normalization (if defined).

rearrange

-- see 3.1.3 Rearrangement, UTS #10.

Characters that are not coded in logical order and to be rearranged. By default,

rearrange => [ 0x0E40..0x0E44, 0x0EC0..0x0EC4 ],

If you want to disallow any rearrangement, pass undef or [] (a reference to an empty list) as the value for this key.

According to the version 9 of UCA, this parameter shall not be used; but it is not warned at present.

table

-- see 3.2 Default Unicode Collation Element Table, UTS #10.

You can use another element table if desired. The table file must be put into a directory where Unicode/Collate.pm is installed. E.g. in perl/lib/Unicode/Collate directory when you have perl/lib/Unicode/Collate.pm.

By default, the filename "allkeys.txt" is used.

If undef is passed explicitly as the value for this key, no file is read (but you can define collation elements via entry).

A typical way to define a collation element table without any file of table:

$onlyABC = Unicode::Collate->new(
    table => undef,
    entry => << 'ENTRIES',
0061 ; [.0101.0020.0002.0061] # LATIN SMALL LETTER A
0041 ; [.0101.0020.0008.0041] # LATIN CAPITAL LETTER A
0062 ; [.0102.0020.0002.0062] # LATIN SMALL LETTER B
0042 ; [.0102.0020.0008.0042] # LATIN CAPITAL LETTER B
0063 ; [.0103.0020.0002.0063] # LATIN SMALL LETTER C
0043 ; [.0103.0020.0008.0043] # LATIN CAPITAL LETTER C
ENTRIES
 );

undefName

undefChar

-- see 6.3.4 Reducing the Repertoire, UTS #10.

Undefines the collation element as if it were unassigned in the table. This reduces the size of the table. If an unassigned character appears in the string to be collated, the sort key is made from its codepoint as a single-character collation element, as it is greater than any other assigned collation elements (in the codepoint order among the unassigned characters). But, it'd be better to ignore characters unfamiliar to you and maybe never used.

katakana_before_hiragana

upper_before_lower

-- see 6.6 Case Comparisons; 7.3.1 Tertiary Weight Table, UTS #10.

By default, lowercase is before uppercase and hiragana is before katakana.

If the tag is made true, this is reversed.

NOTE: These tags simplemindedly assume any lowercase/uppercase or hiragana/katakana distinctions must occur in level 3, and their weights at level 3 must be same as those mentioned in 7.3.1, UTS #10. If you define your collation elements which violate this requirement, these tags don't work validly.

variable

alternate

-- see 3.2.2 Variable Weighting, UTS #10.

(the title in UCA version 8: Alternate Weighting)

This key allows to variable weighting for variable collation elements, which are marked with an ASTERISK in the table (NOTE: Many punction marks and symbols are variable in allkeys.txt).

variable => 'blanked', 'non-ignorable', 'shifted', or 'shift-trimmed'.

These names are case-insensitive. By default (if specification is omitted), 'shifted' is adopted.

'Blanked'        Variable elements are made ignorable at levels 1 through 3;
                 considered at the 4th level.

'Non-ignorable'  Variable elements are not reset to ignorable.

'Shifted'        Variable elements are made ignorable at levels 1 through 3
                 their level 4 weight is replaced by the old level 1 weight.
                 Level 4 weight for Non-Variable elements is 0xFFFF.

'Shift-Trimmed'  Same as 'shifted', but all FFFF's at the 4th level
                 are trimmed.

For backward compatibility, alternate can be used as an alias for variable.

Methods for Collation

@sorted = $Collator->sort(@not_sorted)

Sorts a list of strings.

$result = $Collator->cmp($a, $b)

Returns 1 (when $a is greater than $b) or 0 (when $a is equal to $b) or -1 (when $a is lesser than $b).

$result = $Collator->eq($a, $b)

$result = $Collator->ne($a, $b)

$result = $Collator->lt($a, $b)

$result = $Collator->le($a, $b)

$result = $Collator->gt($a, $b)

$result = $Collator->ge($a, $b)

They works like the same name operators as theirs.

eq : whether $a is equal to $b.
ne : whether $a is not equal to $b.
lt : whether $a is lesser than $b.
le : whether $a is lesser than $b or equal to $b.
gt : whether $a is greater than $b.
ge : whether $a is greater than $b or equal to $b.

$sortKey = $Collator->getSortKey($string)

-- see 4.3 Form a sort key for each string, UTS #10.

Returns a sort key.

You compare the sort keys using a binary comparison and get the result of the comparison of the strings using UCA.

$Collator->getSortKey($a) cmp $Collator->getSortKey($b)

   is equivalent to

$Collator->cmp($a, $b)

$sortKeyForm = $Collator->viewSortKey($string)

use Unicode::Collate;
my $c = Unicode::Collate->new();
print $c->viewSortKey("Perl"),"\n";

# output:
# [0B67 0A65 0B7F 0B03 | 0020 0020 0020 0020 | 0008 0002 0002 0002 | FFFF FFFF FFFF FFFF]
#  Level 1               Level 2               Level 3               Level 4

 (If C<UCA_Version> is 8, the output is slightly different.)

Methods for Searching

DISCLAIMER: If preprocess or normalization tag is true for $Collator, calling these methods (index, match, gmatch, subst, gsubst) is croaked, as the position and the length might differ from those on the specified string. (And rearrange and hangul_terminator tags are neglected.)

The match, gmatch, subst, gsubst methods work like m//, m//g, s///, s///g, respectively, but they are not aware of any pattern, but only a literal substring.

$position = $Collator->index($string, $substring[, $position])

($position, $length) = $Collator->index($string, $substring[, $position])

If $substring matches a part of $string, returns the position of the first occurrence of the matching part in scalar context; in list context, returns a two-element list of the position and the length of the matching part.

If $substring does not match any part of $string, returns -1 in scalar context and an empty list in list context.

e.g. you say

my $Collator = Unicode::Collate->new( normalization => undef, level => 1 );
                                   # (normalization => undef) is REQUIRED.
my $str = "Ich muß studieren Perl.";
my $sub = "MÜSS";
my $match;
if (my($pos,$len) = $Collator->index($str, $sub)) {
    $match = substr($str, $pos, $len);
}

and get "muß" in $match since "muß" is primary equal to "MÜSS".

$match_ref = $Collator->match($string, $substring)

($match) = $Collator->match($string, $substring)

If $substring matches a part of $string, in scalar context, returns a reference to the first occurrence of the matching part ($match_ref is always true if matches, since every reference is true); in list context, returns the first occurrence of the matching part.

If $substring does not match any part of $string, returns undef in scalar context and an empty list in list context.

e.g.

    if ($match_ref = $Collator->match($str, $sub)) { # scalar context
	print "matches [$$match_ref].\n";
    } else {
	print "doesn't match.\n";
    }

     or 

    if (($match) = $Collator->match($str, $sub)) { # list context
	print "matches [$match].\n";
    } else {
	print "doesn't match.\n";
    }

@match = $Collator->gmatch($string, $substring)

If $substring matches a part of $string, returns all the matching parts (or matching count in scalar context).

If $substring does not match any part of $string, returns an empty list.

$count = $Collator->subst($string, $substring, $replacement)

If $substring matches a part of $string, the first occurrence of the matching part is replaced by $replacement ($string is modified) and return $count (always equals to 1).

$replacement can be a CODEREF, taking the matching part as an argument, and returning a string to replace the matching part (a bit similar to s/(..)/$coderef->($1)/e).

$count = $Collator->gsubst($string, $substring, $replacement)

If $substring matches a part of $string, all the occurrences of the matching part is replaced by $replacement ($string is modified) and return $count.

$replacement can be a CODEREF, taking the matching part as an argument, and returning a string to replace the matching part (a bit similar to s/(..)/$coderef->($1)/eg).

e.g.

my $Collator = Unicode::Collate->new( normalization => undef, level => 1 );
                                   # (normalization => undef) is REQUIRED.
my $str = "Camel ass came\x{301}l CAMEL horse cAm\0E\0L...";
$Collator->gsubst($str, "camel", sub { "<b>$_[0]</b>" });

# now $str is "<b>Camel</b> ass <b>came\x{301}l</b> <b>CAMEL</b> horse <b>cAm\0E\0L</b>...";
# i.e., all the camels are made bold-faced.

Other Methods

%old_tailoring = $Collator->change(%new_tailoring)

Change the value of specified keys and returns the changed part.

$Collator = Unicode::Collate->new(level => 4);

$Collator->eq("perl", "PERL"); # false

%old = $Collator->change(level => 2); # returns (level => 4).

$Collator->eq("perl", "PERL"); # true

$Collator->change(%old); # returns (level => 2).

$Collator->eq("perl", "PERL"); # false

Not all (key,value)s are allowed to be changed. See also @Unicode::Collate::ChangeOK and @Unicode::Collate::ChangeNG.

In the scalar context, returns the modified collator (but it is not a clone from the original).

$Collator->change(level => 2)->eq("perl", "PERL"); # true

$Collator->eq("perl", "PERL"); # true; now max level is 2nd.

$Collator->change(level => 4)->eq("perl", "PERL"); # false

$version = $Collator->version()

Returns the version number (a string) of the Unicode Standard which the table file used by the collator object is based on. If the table does not include a version line (starting with @version), returns "unknown".

UCA_Version()

Returns the tracking version number of UTS #10 this module consults.

Base_Unicode_Version()

Returns the version number of UTS #10 this module consults.

EXPORT

None by default.

CAVEAT

Use of the normalization parameter requires the Unicode::Normalize module.

If you need not it (say, in the case when you need not handle any combining characters), assign normalization => undef explicitly.

-- see 6.5 Avoiding Normalization, UTS #10.

Conformance Test

The Conformance Test for the UCA is provided in http://www.unicode.org/reports/tr10/CollationTest.html and http://www.unicode.org/reports/tr10/CollationTest.zip

For CollationTest_SHIFTED.txt, a collator via Unicode::Collate->new( ) should be used; for CollationTest_NON_IGNORABLE.txt, a collator via Unicode::Collate->new(variable => "non-ignorable", level => 3).

Unicode::Normalize is required to try The Conformance Test.

AUTHOR

SADAHIRO Tomoyuki, <SADAHIRO@cpan.org>

http://homepage1.nifty.com/nomenclator/perl/

Copyright(C) 2001-2003, SADAHIRO Tomoyuki. Japan. All rights reserved.

This library is free software; you can redistribute it
and/or modify it under the same terms as Perl itself.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)