/ 
MooseX-Role-Parameterized-0.16
River stage four • 90 direct dependents • 1572 total dependents
/ MooseX::Role::Parameterized

NAME

MooseX::Role::Parameterized - roles with composition parameters

SYNOPSIS

package Counter;
use MooseX::Role::Parameterized;

parameter name => (
    isa      => 'Str',
    required => 1,
);

role {
    my $p = shift;

    my $name = $p->name;

    has $name => (
        is      => 'rw',
        isa     => 'Int',
        default => 0,
    );

    method "increment_$name" => sub {
        my $self = shift;
        $self->$name($self->$name + 1);
    };

    method "reset_$name" => sub {
        my $self = shift;
        $self->$name(0);
    };
};

package MyGame::Weapon;
use Moose;

with Counter => { name => 'enchantment' };

package MyGame::Wand;
use Moose;

with Counter => { name => 'zapped' };

MooseX::Role::Parameterized::Tutorial

Stop! If you're new here, please read MooseX::Role::Parameterized::Tutorial for a much gentler introduction.

DESCRIPTION

Your parameterized role consists of two new things: parameter declarations and a role block.

Parameters are declared using the "parameter" keyword which very much resembles "has" in Moose. You can use any option that "has" in Moose accepts. The default value for the is option is ro as that's a very common case. Use is => 'bare' if you want no accessor. These parameters will get their values when the consuming class (or role) uses "with" in Moose. A parameter object will be constructed with these values, and passed to the role block.

The role block then uses the usual Moose::Role keywords to build up a role. You can shift off the parameter object to inspect what the consuming class provided as parameters. You use the parameters to customize your role however you wish.

There are many possible implementations for parameterized roles (hopefully with a consistent enough API); I believe this to be the easiest and most flexible design. Coincidentally, Pugs originally had an eerily similar design.

Why a parameters object?

I've been asked several times "Why use a parameter object and not just a parameter hashref? That would eliminate the need to explicitly declare your parameters."

The benefits of using an object are similar to the benefits of using Moose. You get an easy way to specify lazy defaults, type constraint, delegation, and so on. You get to use MooseX modules.

You also get the usual introspective and intercessory abilities that come standard with the metaobject protocol. Ambitious users should be able to add traits to the parameters metaclass to further customize behavior. Please let me know if you're doing anything viciously complicated with this extension. :)

CAVEATS

You must use this syntax to declare methods in the role block: method NAME => sub { ... };. This is due to a limitation in Perl. In return though you can use parameters in your methods!

"alias" in Moose::Role and "excludes" in Moose::Role are not yet supported. I'm completely unsure of whether they should be handled by this module. Until we figure out a plan, either declaring or providing a parameter named alias or excludes is an error.

AUTHOR

Shawn M Moore, sartak@gmail.com

EXAMPLES

Fey::Role::HasAliasName
Fey::Role::MakesAliasObjects
Fey::Role::SQL::Cloneable
Fey::Role::SetOperation
IM::Engine::PluggableConstructor
IM::Engine::RequiresPlugins
KiokuDB::Role::Scan
MooseX::RelatedClassRoles
MooseX::Role::Matcher
MooseX::Role::XMLRPC::Client
MooseX::WithCache
Net::Journyx::Object::Loadable
NetHack::Item::Role::IncorporatesStats
TAEB::Action::Role::Item
WWW::Mechanize::TreeBuilder

SEE ALSO

http://sartak.blogspot.com/2009/05/parameterized-roles.html

http://stevan-little.blogspot.com/2009/07/thoughts-on-parameterized-roles.html

http://sartak.org/talks/yapc-asia-2009/(parameterized)-roles/

COPYRIGHT AND LICENSE

Copyright 2007-2009 Infinity Interactive

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.