NAME

HTML::Widgets::NavMenu - A Perl Module for Generating HTML Navigation Menus

SYNOPSIS

use HTML::Widgets::NavMenu;

my $nav_menu =
    HTML::Widgets::NavMenu->new(
        'path_info' => "/me/",
        'current_host' => "default",
        'hosts' =>
        {
            'default' =>
            {
                'base_url' => "http://www.hello.com/"
            },
        },
        'tree_contents' =>
        {
            'host' => "default",
            'text' => "Top 1",
            'title' => "T1 Title",
            'expand_re' => "",
            'subs' =>
            [
                {
                    'text' => "Home",
                    'url' => "",
                },
                {
                    'text' => "About Me",
                    'title' => "About Myself",
                    'url' => "me/",
                },
            ],
        },
    );

my $results = $nav_menu->render();

my $nav_menu_html = join("\n", @{$results->{'html'}});

DESCRIPTION

This module generates a navigation menu for a site. It can also generate a complete site map, a path of leading components, and also keeps track of navigation links ("Next", "Prev", "Up", etc.) You can start from the example above and see more examples in the tests, and complete working sites in the Subversion repositories at http://opensvn.csie.org/shlomif/homepage/ and http://opensvn.csie.org/perlbegin/perl-begin/.

USAGE

my $nav_menu = HTML::Widgets::NavMenu->new(@args)

To use this module call the constructor with the following named arguments:

hosts

This should be a hash reference that maps host-IDs to another hash reference that contains information about the hosts. An HTML::Widgets::NavMenu navigation menu can spread across pages in several hosts, which will link from one to another using relative URLs if possible and fully-qualified (i.e: http://) URLs if not.

Currently the only key required in the hash is the base_url one that points to a string containing the absolute URL to the sub-site. The base URL may have trailing components if it does not reside on the domain's root directory.

An optional key that is required only if you wish to use the "site_abs" url_type (see below), is trailing_url_base, which denotes the component of the site that appears after the hostname. For http://www.myhost.com/~myuser/ it is /~myuser/.

Here's an example for a minimal hosts value:

'hosts' =>
{
    'default' =>
    {
        'base_url' => "http://www.hello.com/",
        'trailing_url_base' => "/",
    },
},

And here's a two-hosts value from my personal site, which is spread across two sites:

'hosts' =>
{
    't2' =>
    {
        'base_url' => "http://www.shlomifish.org/",
        'trailing_url_base' => "/",
    },
    'vipe' =>
    {
        'base_url' => "http://vipe.technion.ac.il/~shlomif/",
        'trailing_url_base' => "/~shlomif/",
    },
},

current_host

This parameter indicate which host-ID of the hosts in hosts is the one that the page for which the navigation menu should be generated is. This is important so cross-site and inner-site URLs will be handled correctly.

path_info

This is the path relative to the host's base_url of the currently displayed page. The path should start with a "/"-character, or otherwise a re-direction excpetion will be thrown (this is done to aid in using this module from within CGI scripts).

tree_contents

This item gives the complete tree for the navigation menu. It is a nested Perl data structure, whose syntax is fully explained in the section "The Input Tree of Contents".

ul_classes

This is an optional parameter whose value is a reference to an array that indicates the values of the class="" arguments for the <ul> tags whose depthes are the indexes of the array.

For example, assigning:

'ul_classes' => [ "FirstClass", "second myclass", "3C" ],

Will assign "FirstClass" as the class of the top-most ULs, "second myclass" as the classes of the ULs inner to it, and "3C" as the class of the ULs inner to the latter ULs.

If classes are undef, the UL tag will not contain a class parameter.

no_leading_dot

When this parameter is set to 1, the object will try to generate URLs that do not start with "./" when possible. That way, the generated markup will be a little more compact. This option is not enabled by default for backwards compatibility, but is highly recommended.

A complete invocation of an HTML::Widgets::NavMenu constructor can be found in the SYNOPSIS above.

After you _init an instance of the navigation menu object, you need to get the results using the render function.

$results = $nav_menu->render()

render() should be called after a navigation menu object is constructed to prepare the results and return them. It returns a hash reference with the following keys:

'html'

This key points to a reference to an array that contains the tags for the HTML. One can join these tags to get the full HTML. It is possible to delimit them with newlines, if one wishes the markup to be easier to read.

'leading_path'

This is a reference to an array of node description objects. These indicate the intermediate pages in the site that lead from the front page to the current page. The methods supported by the class of these objects is described below under "The Node Description Component Class".

'nav_links_obj'

This points to a hash reference whose keys are link IDs for the Firefox "Site Navigation Toolbar" ( http://www.bolwin.com/software/snb.shtml ) and compatible programs, and its values are Node Description objects. (see "The Node Description Class" below). Here's a sample code that renders the links as <link rel=...> into the page header:

my $nav_links = $results->{'nav_links_obj'};
# Sort the keys so their order will be preserved
my @keys = (sort { $a cmp $b } keys(%$nav_links));
foreach my $key (@keys)
{
    my $value = $nav_links->{$key};
    my $url = CGI::escapeHTML($value->direct_url());
    my $title = CGI::escapeHTML($value->title());
    print {$fh} "<link rel=\"$key\" href=\"$url\" title=\"$title\" />\n";
}

'nav_links'

This points to a hash reference whose keys are link IDs compatible with the Firefox Site Navigation ( http://cdn.mozdev.org/linkToolbar/ ) and its values are the URLs to these links. This key/value pair is provided for backwards compatibility with older versions of HTML::Widgets::NavMenu. In new code, one is recommended to use 'nav_links_obj' instead.

This sample code renders the links as <link rel=...> into the page header:

my $nav_links = $results->{'nav_links'};
# Sort the keys so their order will be preserved
my @keys = (sort { $a cmp $b } keys(%$nav_links));
foreach my $key (@keys)
{
    my $url = $nav_links->{$key};
    print {$fh} "<link rel=\"$key\" href=\"" .
        CGI::escapeHTML($url) . "\" />\n";
}

$results = $nav_menu->render_jquery_treeview()

Renders a fully expanded tree suitable for input to JQuery's treeview plugin: http://bassistance.de/jquery-plugins/jquery-plugin-treeview/ - otherwise the same as render() .

$text = $nav_menu->gen_site_map()

This function can be called to generate a site map based on the tree of contents. It returns a reference to an array containing the tags of the site map.

$url = $nav_menu->get_cross_host_rel_url_ref({...})

This function can be called to calculate a URL to a different part of the site. It accepts four named arguments, passed as a hash-ref:

'host': This is the host ID
'host_url': This is URL within the host.
'url_type': 'rel', 'full_abs' or 'site_abs'.
'url_is_abs': A flag that indicates if 'host_url' is already absolute.

$url = $nav_menu->get_cross_host_rel_url(...)

This is like get_cross_host_rel_url_ref() except that the arguments are clobbered into the arguments list. It is kept here for compatibility sake.

The Input Tree of Contents

The input tree is a nested Perl data structure that represnets the tree of the site. Each node is respresented as a Perl hash reference, with its sub-nodes contained in an array reference of its 'subs' value. A non-existent 'subs' means that the node is a leaf and has no sub-nodes.

The top-most node is mostly a dummy node, that just serves as the father of all other nodes.

Following is a listing of the possible values inside a node hash and what their respective values mean.

'host'

This is the host-ID of the host as found in the 'hosts' key to the navigation menu object constructor. It implicitly propagates downwards in the tree. (i.e: all nodes of the sub-tree spanning from the node will implicitly have it as their value by default.)

Generally, a host must always be specified and so the first node should specify it.

'url'

This contains the URL of the node within the host. The URL should not contain a leading slash. This value does not propagate further.

The URL should be specified for every nodes except separators and the such.

'text'

This is the text that will be presented to the user as the text of the link inside the navigation bar. E.g.: if 'text' is "Hi There", then the link will look something like this:

<a href="my-url/">Hi There</a>

<b>Hi There</b>

if it's the current page. Not that this text is rendered into HTML as is, and so should be escaped to prevent HTML-injection attacks.

'title'

This is the text of the link tag's title attribute. It is also not processed and so the user of the module should make sure it is escaped if needed, to prevent HTML-injection attacks. It is optional, and if not specified, no title will be presented.

'subs'

This item, if specified, should point to an array reference containing the sub-nodes of this item, in order.

'separator'

This key if specified and true indicate that the item is a separator, which should just leave a blank line in the HTML. It is best to accompany it with 'skip' (see below).

If 'separator' is specified, it is usually meaningless to specify all other node keys except 'skip'.

'skip'

This key if true, indicates that the node should be skipped when traversing site using the Mozilla navigation links. Instead the navigation will move to the next or previous nodes.

'hide'

This key if true indicates that the item should be part of the site's flow and site map, but not displayed in the navigation menu.

'role'

This indicates a role of an item. It is similar to a CSS class, or to DocBook's "role" attribute, only induces different HTML markup. The vanilla HTML::Widgets::NavMenu does not distinguish between any roles, but see HTML::Widgets::NavMenu::HeaderRole.

'expand'

This specifies a predicate (a Perl value that is evaluated to a boolean value, see "Predicate Values" below.) to be matched against the path and current host to determine if the navigation menu should be expanded at this node. If it does, all of the nodes up to it will expand as well.

'show_always'

This value if true, indicates that the node and all nodes below it (until 'show_always' is explicitly set to false) must be always displayed. Its function is similar to 'expand_re' but its propagation semantics the opposite.

'url_type'

This specifies the URL type to use to render this item. It can be:

1. "rel" - the default. This means a fully relative URL (if possible), like "../../me/about.html".

2. "site_abs" - this uses a URL absolute to the site, using a slash at the beginning. Like "/~shlomif/me/about.html". For this to work the current host needs to have a 'trailing_url_base' value set.

3. "full_abs" - this uses a fully qualified URL (e.g: with http:// at the beginning, even if both the current path and the pointed path belong to the same host. Something like http://www.shlomifish.org/me/about.html.

'rec_url_type'

This is similar to 'url_type' only it recurses, to the sub-tree of the node. If both 'url_type' and 'rec_url_type' are specified for a node, then the value of 'url_type' will hold.

'url_is_abs'

This flag, if true, indicates that the URL specified by the 'url' key is an absolute URL like http://www.myhost.com/ and should not be treated as a path within the site. All links to the page associated with this node will contain the URL verbatim.

Note that using absolute URLs as part of the site flow is discouraged because once they are accessed, the navigation within the primary site is lost. A better idea would be to create a separate page within the site, that will link to the external URL.

li_id

This is the HTML ID attribute that will be assigned to the specific <li> tag of the navigation menu. So if you have:

'tree_contents' =>
{
    'host' => "default",
    'text' => "Top 1",
    'title' => "T1 Title",
    'expand_re' => "",
    'subs' =>
    [
        {
            'text' => "Home",
            'url' => "",
        },
        {
            'text' => "About Me",
            'title' => "About Myself",
            'url' => "me/",
            'li_id' => 'about_me',
        },
    ],
},

Then the HTML for the About me will look something like:

<li id="about_me">
<a href="me/ title="About Myself">About Me</a>
</li>

Predicate Values

An explicitly specified predicate value is a hash reference that contains one of the following three keys with their appropriate values:

'cb' => \&predicate_func

This specifies a sub-routine reference (or "callback" or "cb"), that will be called to determine the result of the predicate. It accepts two named arguments - 'path_info' which is the path of the current page (without the leading slash) and 'current_host' which is the ID of the current host.

Here is an example for such a callback:

sub predicate_cb1
{
    my %args = (@_);
    my $host = $args{'current_host'};
    my $path = $args{'path_info'};
    return (($host eq "true") && ($path eq "mypath/"));
}

're' => $regexp_string

This specifies a regular expression to be matched against the path_info (regardless of what current_host is), to determine the result of the predicate.

'bool' => [ 0 | 1 ]

This specifies the constant boolean value of the predicate.

Note that if 'cb' is specified then both 're' and 'bool' will be ignored, and 're' over-rides 'bool'.

Orthogonal to these keys is the 'capt' key which specifies whether this expansion "captures" or not. This is relevant to the behaviour in the breadcrumbs' trails, if one wants the item to appear there or not. The default value is true.

If the predicate is not a hash reference, then HTML::Widgets::NavMenu will try to guess what it is. If it's a sub-routine reference, it will be an implicit callback. If it's one of the values "0", "1", "yes", "no", "true", "false", "True", "False" it will be considered a boolean. If it's a different string, a regular expression match will be attempted. Else, an excpetion will be thrown.

Here are some examples for predicates:

# Always expand.
'expand' => { 'bool' => 1, };

# Never expand.
'expand' => { 'bool' => 0, };

# Expand under home/
'expand' => { 're' => "^home/" },

# Expand under home/ when the current host is "foo"
sub expand_path_home_host_foo
{
    my %args = (@_);
    my $host = $args{'current_host'};
    my $path = $args{'path_info'};
    return (($host eq "foo") && ($path =~ m!^home/!));
}

'expand' => { 'cb' => \&expand_path_home_host_foo, },

The Node Description Class

When retrieving the leading path or the nav_links_obj, an array of objects is returned. This section describes the class of these objects, so one will know how to use them.

Basically, it is an object that has several accessors. The accessors are:

host: The host ID of this node.
host_url: The URL of the node within the host. (one given in its 'url' key).
label: The label of the node. (one given in its 'text' key). This is not SGML-escaped.
title: The title of the node. (that can be assigned to the URL 'title' attribute). This is not SGML-escaped.
direct_url: A direct URL (usable for inclusion in an A tag ) from the current page to this page.
url_type: This is the url_type (see above) that holds for this node.

AUTHORS

Shlomi Fish, <shlomif@cpan.org>, http://www.shlomifish.org/ .

THANKS

Thanks to Yosef Meller (http://search.cpan.org/~yosefm/) for writing the module HTML::Widget::SideBar on which initial versions of this modules were based. (albeit his code is no longer used here).

COPYRIGHT AND LICENSE

You can use, modify and distribute this module under the terms of the MIT X11 license. ( http://www.opensource.org/licenses/mit-license.php ).

To install HTML::Widgets::NavMenu, copy and paste the appropriate command in to your terminal.

cpanm

cpanm HTML::Widgets::NavMenu

CPAN shell

perl -MCPAN -e shell
install HTML::Widgets::NavMenu

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)