The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

SKAJI / Module-cpmfile-0.006 / lib / Module / cpmfile.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
—
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179

              
package Module::cpmfile;
use 5.008001;
use strict;
use warnings;
our $VERSION = '0.006';
use Module::cpmfile::Prereqs;
use Module::cpmfile::Util qw(merge_version _yaml_hash);
use YAML::PP ();
sub load {
    my ($class, $file) = @_;
    my ($hash) = YAML::PP->new->load_file($file);
    $class->new($hash);
}
sub new {
    my ($class, $hash) = @_;
    my $prereqs = Module::cpmfile::Prereqs->new($hash->{prereqs});
    my %feature;
    for my $id (sort keys %{ $hash->{features} || +{} }) {
        my $description = $hash->{features}{$id}{description};
        my $prereqs = Module::cpmfile::Prereqs->new($hash->{features}{$id}{prereqs});
        $feature{$id} = { description => $description, prereqs => $prereqs };
    }
    bless { prereqs => $prereqs, features => \%feature, _mirrors => [] }, $class;
}
sub from_cpanfile {
    my ($class, $cpanfile) = @_;
    my %feature;
    for my $feature ($cpanfile->features) {
        my $id = $feature->{identifier};
        my $description = $feature->{description};
        my $prereqs = Module::cpmfile::Prereqs->from_cpanmeta($feature->{prereqs});
        $feature{$id} = { description => $description, prereqs => $prereqs };
    }
    my $prereqs = Module::cpmfile::Prereqs->from_cpanmeta($cpanfile->prereqs);
    for my $p ($prereqs, map { $_->{prereqs} } values %feature) {
        $p->walk(undef, undef, sub {
            my (undef, undef, $package, $original_options) = @_;
            my $additional_options = $cpanfile->options_for_module($package) || +{};
            if (%$additional_options) {
                %$original_options = (%$original_options, %$additional_options);
            }
        });
    }
    my $mirrors = $cpanfile->mirrors;
    bless { prereqs => $prereqs, features => \%feature, _mirrors => $mirrors }, $class;
}
sub from_cpanmeta {
    my ($class, $cpanmeta) = @_;
    my %feature;
    for my $id (keys %{$cpanmeta->optional_features}) {
        my $f = $cpanmeta->optional_features->{$id};
        my $description = $f->{description};
        my $prereqs = Module::cpmfile::Prereqs->from_cpanmeta($f->{prereqs});
        $feature{$id} = { description => $description, prereqs => $prereqs };
    }
    my $prereqs = Module::cpmfile::Prereqs->from_cpanmeta($cpanmeta->prereqs);
    bless { prereqs => $prereqs, features => \%feature, _mirrors => [] }, $class;
}
sub prereqs {
    my $self = shift;
    $self->{prereqs};
}
sub features {
    my $self = shift;
    if (%{$self->{features}}) {
        return $self->{features};
    }
    return;
}
sub _feature_prereqs {
    my ($self, $ids) = @_;
    my @prereqs;
    for my $id (@{ $ids || [] }) {
        my $feature = $self->{features}{$id};
        next if !$feature || !$feature->{prereqs};
        push @prereqs, $feature->{prereqs}
    }
    @prereqs;
}
sub effective_requirements {
    my ($self, $feature_ids, $phases, $types) = @_;
    my %req;
    for my $prereqs ($self->{prereqs}, $self->_feature_prereqs($feature_ids)) {
        $prereqs->walk($phases, $types, sub {
            my (undef, undef, $package, $options) = @_;
            if (exists $req{$package}) {
                my $v1 = $req{$package}{version} || 0;
                my $v2 = $options->{version} || 0;
                my $version  = merge_version $v1, $v2;
                $req{$package} = +{
                    %{$req{$package}},
                    %$options,
                    $version ? (version => $version) : (),
                };
            } else {
                $req{$package} = $options;
            }
        });
    }
    \%req;
}
sub to_string {
    my $self = shift;
    my @out;
    push @out, $self->prereqs->to_string;
    if (my $features = $self->features) {
        push @out, "features:";
        for my $id (sort keys %$features) {
            my $feature = $features->{$id};
            push @out, "  $id:";
            if (my $desc = $feature->{description}) {
                push @out, _yaml_hash({ description => $desc }, "    ");
            }
            if (my $prereqs = $feature->{prereqs}) {
                push @out, $prereqs->to_string("    ");
            }
        }
    }
    ( join "\n", @out ) . "\n";
}
1;
__END__
=encoding utf-8
=head1 NAME
Module::cpmfile - Parse cpmfile
=head1 SYNOPSIS
  use Module::cpmfile;
  my $cpmfile = Module::cpmfile->load("cpm.yml");
  my $reqs = $cpmfile->effective_requirements(undef, ["runtime"], ["requires"]);
=head1 DESCRIPTION
THIS IS EXPERIMENTAL.
cpmfile (usually saved as C<cpm.yml>) is yet another file format for describing module dependencies,
and Module::cpmfile helps you parse it.
The JSON Schema for cpmfile is available at L<jsonschema.json|https://github.com/skaji/cpmfile/blob/main/jsonschema.json>.
cpmfile will be used mainly by L<App::cpm>.
=head1 SEE ALSO
L<cpanfile>
L<Module::CPANfile>
L<App::cpm>
=head1 AUTHOR
Shoichi Kaji <skaji@cpan.org>
=head1 COPYRIGHT AND LICENSE
Copyright 2021 Shoichi Kaji <skaji@cpan.org>
This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
=cut