/ 
Mojolicious-2.64
River stage four • 995 direct dependents • 1115 total dependents
/ Mojo::IOLoop

NAME

Mojo::IOLoop - Minimalistic reactor for non-blocking TCP clients and servers

SYNOPSIS

use Mojo::IOLoop;

# Listen on port 3000
Mojo::IOLoop->server({port => 3000} => sub {
  my ($loop, $stream) = @_;

  $stream->on(read => sub {
    my ($stream, $chunk) = @_;

    # Process input
    say $chunk;

    # Got some data, time to write
    $stream->write('HTTP/1.1 200 OK');
  });
});

# Connect to port 3000
my $id = Mojo::IOLoop->client({port => 3000} => sub {
  my ($loop, $err, $stream) = @_;

  $stream->on(read => sub {
    my ($stream, $chunk) = @_;

    # Process input
    say "Input: $chunk";
  });

  # Write request
  $stream->write("GET / HTTP/1.1\r\n\r\n");
});

# Add a timer
Mojo::IOLoop->timer(5 => sub {
  my $loop = shift;
  $loop->drop($id);
});

# Start loop if necessary
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

DESCRIPTION

Mojo::IOLoop is a very minimalistic reactor based on Mojo::Reactor, it has been reduced to the absolute minimal feature set required to build solid and scalable non-blocking TCP clients and servers.

Optional modules EV, IO::Socket::IP and IO::Socket::SSL are supported transparently and used if installed. Individual features can also be disabled with the MOJO_NO_IPV6 and MOJO_NO_TLS environment variables.

A TLS certificate and key are also built right in to make writing test servers as easy as possible. Also note that for convenience the PIPE signal will be set to IGNORE when Mojo::IOLoop is loaded.

ATTRIBUTES

Mojo::IOLoop implements the following attributes.

client_class

my $class = $loop->client_class;
$loop     = $loop->client_class('Mojo::IOLoop::Client');

Class to be used for opening TCP connections with the client method, defaults to Mojo::IOLoop::Client. Note that this attribute is EXPERIMENTAL and might change without warning!

lock

my $cb = $loop->lock;
$loop  = $loop->lock(sub {...});

A locking callback that decides if this loop is allowed to accept new incoming connections, used to sync multiple server processes. The callback should return true or false. Note that exceptions in this callback are not captured.

$loop->lock(sub {
  my ($loop, $blocking) = @_;

  # Got the lock, listen for new connections
  return 1;
});

max_accepts

my $max = $loop->max_accepts;
$loop   = $loop->max_accepts(1000);

The maximum number of connections this loop is allowed to accept before shutting down gracefully without interrupting existing connections, defaults to 0. Setting the value to 0 will allow this loop to accept new connections indefinitely. Note that this attribute is EXPERIMENTAL and might change without warning!

max_connections

my $max = $loop->max_connections;
$loop   = $loop->max_connections(1000);

The maximum number of parallel connections this loop is allowed to handle before stopping to accept new incoming connections, defaults to 1000. Setting the value to 0 will make this loop stop accepting new connections and allow it to shutdown gracefully without interrupting existing connections.

reactor

my $reactor = $loop->reactor;
$loop       = $loop->reactor(Mojo::Reactor->new);

Low level event reactor, usually a Mojo::Reactor or Mojo::Reactor::EV object. Note that this attribute is EXPERIMENTAL and might change without warning!

server_class

my $class = $loop->server_class;
$loop     = $loop->server_class('Mojo::IOLoop::Server');

Class to be used for accepting TCP connections with the server method, defaults to Mojo::IOLoop::Server. Note that this attribute is EXPERIMENTAL and might change without warning!

stream_class

my $class = $loop->stream_class;
$loop     = $loop->stream_class('Mojo::IOLoop::Stream');

Class to be used by client and server methods for I/O streams, defaults to Mojo::IOLoop::Stream. Note that this attribute is EXPERIMENTAL and might change without warning!

unlock

my $cb = $loop->unlock;
$loop  = $loop->unlock(sub {...});

A callback to free the accept lock, used to sync multiple server processes. Note that exceptions in this callback are not captured.

METHODS

Mojo::IOLoop inherits all methods from Mojo::Base and implements the following new ones.

client

my $id =
  Mojo::IOLoop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client({address => '127.0.0.1', port => 3000}, sub {...});

Open TCP connection with client_class, which is usually Mojo::IOLoop::Client, takes the same arguments as "connect" in Mojo::IOLoop::Client. Note that this method is EXPERIMENTAL and might change without warning!

Mojo::IOLoop->client({port => 3000} => sub {
  my ($loop, $err, $stream) = @_;
  ...
});

delay

my $delay = Mojo::IOLoop->delay;
my $delay = $loop->delay;
my $delay = $loop->delay(sub {...});

Get Mojo::IOLoop::Delay object to synchronize events and subscribe to event "finish" in Mojo::IOLoop::Delay if optional callback is provided.

# Synchronize multiple events
my $delay = Mojo::IOLoop->delay(sub { say 'BOOM!' });
for my $i (1 .. 10) {
  $delay->begin;
  Mojo::IOLoop->timer($i => sub {
    say 10 - $i;
    $delay->end;
  });
}

# Wait for events if necessary
$delay->wait unless Mojo::IOLoop->is_running;

drop

Mojo::IOLoop->drop($id);
$loop->drop($id);

Drop anything with an id. Connections will be dropped gracefully by allowing them to finish writing all data in their write buffers.

generate_port

my $port = Mojo::IOLoop->generate_port;
my $port = $loop->generate_port;

Find a free TCP port, this is a utility function primarily used for tests.

is_running

my $success = Mojo::IOLoop->is_running;
my $success = $loop->is_running;

Check if loop is running.

exit unless Mojo::IOLoop->is_running;

one_tick

Mojo::IOLoop->one_tick;
$loop->one_tick;
$loop->one_tick('0.25');
$loop->one_tick(0);

Run reactor for roughly one tick and try not to block longer than the given amount of time in seconds.

recurring

my $id = Mojo::IOLoop->recurring(0 => sub {...});
my $id = $loop->recurring(3 => sub {...});

Create a new recurring timer, invoking the callback repeatedly after a given amount of time in seconds.

# Run multiple reactors next to each other
my $loop2 = Mojo::IOLoop->new;
Mojo::IOLoop->recurring(0 => sub { $loop2->one_tick(0) });

server

my $id = Mojo::IOLoop->server(port => 3000, sub {...});
my $id = $loop->server(port => 3000, sub {...});
my $id = $loop->server({port => 3000}, sub {...});

Accept TCP connections with server_class, which is usually Mojo::IOLoop::Server, takes the same arguments as "listen" in Mojo::IOLoop::Server. Note that this method is EXPERIMENTAL and might change without warning!

Mojo::IOLoop->server({port => 3000} => sub {
  my ($loop, $stream, $id) = @_;
  ...
});

singleton

my $loop = Mojo::IOLoop->singleton;

The global Mojo::IOLoop singleton, used to access a single shared loop object from everywhere inside the process.

# Many methods also allow you to take shortcuts
Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
Mojo::IOLoop->start;

start

Mojo::IOLoop->start;
$loop->start;

Start the loop, this will block until stop is called or no events are being watched anymore.

stop

Mojo::IOLoop->stop;
$loop->stop;

Stop the loop immediately, this will not interrupt any existing connections and the loop can be restarted by running start again.

stream

my $stream = Mojo::IOLoop->stream($id);
my $stream = $loop->stream($id);
my $id     = $loop->stream($stream);

Get Mojo::IOLoop::Stream object for id or turn object into a connection. Note that this method is EXPERIMENTAL and might change without warning!

# Increase inactivity timeout for connection to 300 seconds
Mojo::IOLoop->stream($id)->timeout(300);

timer

my $id = Mojo::IOLoop->timer(5 => sub {...});
my $id = $loop->timer(5 => sub {...});
my $id = $loop->timer(0.25 => sub {...});

Create a new timer, invoking the callback after a given amount of time in seconds.

DEBUGGING

You can set the MOJO_IOLOOP_DEBUG environment variable to get some advanced diagnostics information printed to STDERR.

MOJO_IOLOOP_DEBUG=1

SEE ALSO

Mojolicious, Mojolicious::Guides, http://mojolicio.us.