NAME
Mojo::IOLoop::Delay - Control the flow of events
SYNOPSIS
use Mojo::IOLoop::Delay;
# Synchronize multiple events
my $delay = Mojo::IOLoop::Delay->new;
$delay->on(finish => sub { say 'BOOM!' });
for my $i (1 .. 10) {
$delay->begin;
Mojo::IOLoop->timer($i => sub {
say 10 - $i;
$delay->end;
});
}
# Sequentialize multiple events
my $delay = Mojo::IOLoop::Delay->new;
$delay->steps(
# First step (simple timer)
sub {
my $delay = shift;
Mojo::IOLoop->timer(2 => $delay->begin);
say 'Second step in 2 seconds.';
},
# Second step (parallel timers)
sub {
my ($delay, @args) = @_;
Mojo::IOLoop->timer(1 => $delay->begin);
Mojo::IOLoop->timer(3 => $delay->begin);
say 'Third step in 3 seconds.';
},
# Third step (the end)
sub {
my ($delay, @args) = @_;
say 'And done after 5 seconds total.';
}
);
# Wait for events if necessary
$delay->wait unless Mojo::IOLoop->is_running;DESCRIPTION
Mojo::IOLoop::Delay controls the flow of events for Mojo::IOLoop.
EVENTS
Mojo::IOLoop::Delay can emit the following events.
finish
$delay->on(finish => sub {
my ($delay, @args) = @_;
...
});Emitted once the active event counter reaches zero and there are no more steps.
ATTRIBUTES
Mojo::IOLoop::Delay implements the following attributes.
ioloop
my $ioloop = $delay->ioloop;
$delay = $delay->ioloop(Mojo::IOLoop->new);Event loop object to control, defaults to the global Mojo::IOLoop singleton.
METHODS
Mojo::IOLoop::Delay inherits all methods from Mojo::EventEmitter and implements the following new ones.
begin
my $cb = $delay->begin;Increment active event counter, the returned callback can be used instead of end, which has the advantage of preserving the order of arguments. Note that the first argument passed to the callback will be ignored.
my $delay = Mojo::IOLoop->delay;
Mojo::UserAgent->new->get('mojolicio.us' => $delay->begin);
my $tx = $delay->wait;end
my $remaining = $delay->end;
my $remaining = $delay->end(@args);Decrement active event counter, all arguments are queued for the next step or finish event and wait method.
steps
$delay = $delay->steps(sub {...}, sub {...});Sequentialize multiple events, the first callback will run right away, and the next one once the active event counter reaches zero, this chain will continue until there are no more callbacks left.
wait
my @args = $delay->wait;Start ioloop and stop it again once the finish event gets emitted, only works when ioloop is not running already.
# Use the "finish" event to synchronize portably
$delay->on(finish => sub {
my ($delay, @args) = @_;
...
});
$delay->wait unless $delay->ioloop->is_running;