/ 
Mojolicious-7.86
River stage four • 995 direct dependents • 1115 total dependents
/ Mojo::IOLoop

NAME

Mojo::IOLoop - Minimalistic event loop

SYNOPSIS

use Mojo::IOLoop;

# Listen on port 3000
Mojo::IOLoop->server({port => 3000} => sub {
  my ($loop, $stream) = @_;

  $stream->on(read => sub {
    my ($stream, $bytes) = @_;

    # Process input chunk
    say $bytes;

    # Write response
    $stream->write('HTTP/1.1 200 OK');
  });
});

# Connect to port 3000
my $id = Mojo::IOLoop->client({port => 3000} => sub {
  my ($loop, $err, $stream) = @_;

  $stream->on(read => sub {
    my ($stream, $bytes) = @_;

    # Process input
    say "Input: $bytes";
  });

  # Write request
  $stream->write("GET / HTTP/1.1\x0d\x0a\x0d\x0a");
});

# Add a timer
Mojo::IOLoop->timer(5 => sub {
  my $loop = shift;
  $loop->remove($id);
});

# Start event loop if necessary
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

DESCRIPTION

Mojo::IOLoop is a very minimalistic event loop based on Mojo::Reactor, it has been reduced to the absolute minimal feature set required to build solid and scalable non-blocking clients and servers.

Depending on operating system, the default per-process and system-wide file descriptor limits are often very low and need to be tuned for better scalability. The LIBEV_FLAGS environment variable should also be used to select the best possible EV backend, which usually defaults to the not very scalable select.

LIBEV_FLAGS=1   # select
LIBEV_FLAGS=2   # poll
LIBEV_FLAGS=4   # epoll (Linux)
LIBEV_FLAGS=8   # kqueue (*BSD, OS X)

The event loop will be resilient to time jumps if a monotonic clock is available through Time::HiRes. A TLS certificate and key are also built right in, to make writing test servers as easy as possible. Also note that for convenience the PIPE signal will be set to IGNORE when Mojo::IOLoop is loaded.

For better scalability (epoll, kqueue) and to provide non-blocking name resolution, SOCKS5 as well as TLS support, the optional modules EV (4.0+), Net::DNS::Native (0.15+), IO::Socket::Socks (0.64+) and IO::Socket::SSL (2.009+) will be used automatically if possible. Individual features can also be disabled with the MOJO_NO_NNR, MOJO_NO_SOCKS and MOJO_NO_TLS environment variables.

See "REAL-TIME WEB" in Mojolicious::Guides::Cookbook for more.

EVENTS

Mojo::IOLoop inherits all events from Mojo::EventEmitter and can emit the following new ones.

finish

$loop->on(finish => sub {
  my $loop = shift;
  ...
});

Emitted when the event loop wants to shut down gracefully and is just waiting for all existing connections to be closed.

ATTRIBUTES

Mojo::IOLoop implements the following attributes.

max_accepts

my $max = $loop->max_accepts;
$loop   = $loop->max_accepts(1000);

The maximum number of connections this event loop is allowed to accept, before shutting down gracefully without interrupting existing connections, defaults to 0. Setting the value to 0 will allow this event loop to accept new connections indefinitely. Note that up to half of this value can be subtracted randomly to improve load balancing between multiple server processes, and to make sure that not all of them restart at the same time.

max_connections

my $max = $loop->max_connections;
$loop   = $loop->max_connections(100);

The maximum number of accepted connections this event loop is allowed to handle concurrently, before stopping to accept new incoming connections, defaults to 1000.

reactor

my $reactor = $loop->reactor;
$loop       = $loop->reactor(Mojo::Reactor->new);

Low-level event reactor, usually a Mojo::Reactor::Poll or Mojo::Reactor::EV object with a default subscriber to the event "error" in Mojo::Reactor.

# Watch if handle becomes readable or writable
Mojo::IOLoop->singleton->reactor->io($handle => sub {
  my ($reactor, $writable) = @_;
  say $writable ? 'Handle is writable' : 'Handle is readable';
});

# Change to watching only if handle becomes writable
Mojo::IOLoop->singleton->reactor->watch($handle, 0, 1);

# Remove handle again
Mojo::IOLoop->singleton->reactor->remove($handle);

METHODS

Mojo::IOLoop inherits all methods from Mojo::EventEmitter and implements the following new ones.

acceptor

my $server = Mojo::IOLoop->acceptor($id);
my $server = $loop->acceptor($id);
my $id     = $loop->acceptor(Mojo::IOLoop::Server->new);

Get Mojo::IOLoop::Server object for id or turn object into an acceptor.

client

my $id
  = Mojo::IOLoop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client(address => '127.0.0.1', port => 3000, sub {...});
my $id = $loop->client({address => '127.0.0.1', port => 3000} => sub {...});

Open a TCP/IP or UNIX domain socket connection with Mojo::IOLoop::Client and create a stream object (usually Mojo::IOLoop::Stream), takes the same arguments as "connect" in Mojo::IOLoop::Client in addition to stream_class.

# Connect to 127.0.0.1 on port 3000 with a custom stream class
my $class = 'Mojo::IOLoop::Stream::HTTPClient';
Mojo::IOLoop->client({port => 3000, stream_class => $class} => sub {
  my ($loop, $err, $stream) = @_;
  ...
});

delay

my $delay = Mojo::IOLoop->delay;
my $delay = $loop->delay;
my $delay = $loop->delay(sub {...});
my $delay = $loop->delay(sub {...}, sub {...});

Build Mojo::IOLoop::Delay object to use as a promise and/or for flow-control. Callbacks will be passed along to "steps" in Mojo::IOLoop::Delay.

# Wrap continuation-passing style APIs with promises
my $ua = Mojo::UserAgent->new;
sub get {
  my $promise = Mojo::IOLoop->delay;
  $ua->get(@_ => sub {
    my ($ua, $tx) = @_;
    my $err = $tx->error;
    $promise->resolve($tx) if !$err || $err->{code};
    $promise->reject($err->{message});
  });
  return $promise;
}
my $mojo = get('https://mojolicious.org');
my $cpan = get('https://metacpan.org');
Mojo::Promise->race($mojo, $cpan)->then(sub { say shift->req->url })->wait;

# Synchronize multiple non-blocking operations
my $delay = Mojo::IOLoop->delay(sub { say 'BOOM!' });
for my $i (1 .. 10) {
  my $end = $delay->begin;
  Mojo::IOLoop->timer($i => sub {
    say 10 - $i;
    $end->();
  });
}
$delay->wait;

# Sequentialize multiple non-blocking operations
Mojo::IOLoop->delay(

  # First step (simple timer)
  sub {
    my $delay = shift;
    Mojo::IOLoop->timer(2 => $delay->begin);
    say 'Second step in 2 seconds.';
  },

  # Second step (concurrent timers)
  sub {
    my $delay = shift;
    Mojo::IOLoop->timer(1 => $delay->begin);
    Mojo::IOLoop->timer(3 => $delay->begin);
    say 'Third step in 3 seconds.';
  },

  # Third step (the end)
  sub { say 'And done after 5 seconds total.' }
)->wait;

is_running

my $bool = Mojo::IOLoop->is_running;
my $bool = $loop->is_running;

Check if event loop is running.

exit unless Mojo::IOLoop->is_running;

next_tick

my $undef = Mojo::IOLoop->next_tick(sub {...});
my $undef = $loop->next_tick(sub {...});

Execute callback as soon as possible, but not before returning or other callbacks that have been registered with this method, always returns undef.

# Perform operation on next reactor tick
Mojo::IOLoop->next_tick(sub {
  my $loop = shift;
  ...
});

one_tick

Mojo::IOLoop->one_tick;
$loop->one_tick;

Run event loop until an event occurs.

# Don't block longer than 0.5 seconds
my $id = Mojo::IOLoop->timer(0.5 => sub {});
Mojo::IOLoop->one_tick;
Mojo::IOLoop->remove($id);

recurring

my $id = Mojo::IOLoop->recurring(3 => sub {...});
my $id = $loop->recurring(0 => sub {...});
my $id = $loop->recurring(0.25 => sub {...});

Create a new recurring timer, invoking the callback repeatedly after a given amount of time in seconds.

# Perform operation every 5 seconds
Mojo::IOLoop->recurring(5 => sub {
  my $loop = shift;
  ...
});

remove

Mojo::IOLoop->remove($id);
$loop->remove($id);

Remove anything with an id, connections will be dropped gracefully by allowing them to finish writing all data in their write buffers.

reset

Mojo::IOLoop->reset;
$loop->reset;

Remove everything and stop the event loop.

server

my $id = Mojo::IOLoop->server(port => 3000, sub {...});
my $id = $loop->server(port => 3000, sub {...});
my $id = $loop->server({port => 3000} => sub {...});

Accept TCP/IP and UNIX domain socket connections with Mojo::IOLoop::Server and create stream objects (usually Mojo::IOLoop::Stream, takes the same arguments as "listen" in Mojo::IOLoop::Server in addition to stream_class.

# Listen on port 3000 with a custom stream class
my $class = 'Mojo::IOLoop::Stream::HTTPServer';
Mojo::IOLoop->server({port => 3000, stream_class => $class} => sub {
  my ($loop, $stream, $id) = @_;
  ...
});

# Listen on random port
my $id = Mojo::IOLoop->server({address => '127.0.0.1'} => sub {
  my ($loop, $stream, $id) = @_;
  ...
});
my $port = Mojo::IOLoop->acceptor($id)->port;

singleton

my $loop = Mojo::IOLoop->singleton;

The global Mojo::IOLoop singleton, used to access a single shared event loop object from everywhere inside the process.

# Many methods also allow you to take shortcuts
Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
Mojo::IOLoop->start;

# Restart active timer
my $id = Mojo::IOLoop->timer(3 => sub { say 'Timeout!' });
Mojo::IOLoop->singleton->reactor->again($id);

# Turn file descriptor into handle and watch if it becomes readable
my $handle = IO::Handle->new_from_fd($fd, 'r');
Mojo::IOLoop->singleton->reactor->io($handle => sub {
  my ($reactor, $writable) = @_;
  say $writable ? 'Handle is writable' : 'Handle is readable';
})->watch($handle, 1, 0);

start

Mojo::IOLoop->start;
$loop->start;

Start the event loop, this will block until "stop" is called. Note that some reactors stop automatically if there are no events being watched anymore.

# Start event loop only if it is not running already
Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

stop

Mojo::IOLoop->stop;
$loop->stop;

Stop the event loop, this will not interrupt any existing connections and the event loop can be restarted by running "start" again.

stop_gracefully

Mojo::IOLoop->stop_gracefully;
$loop->stop_gracefully;

Stop accepting new connections and wait for already accepted connections to be closed, before stopping the event loop.

stream

my $stream = Mojo::IOLoop->stream($id);
my $stream = $loop->stream($id);
my $id     = $loop->stream(Mojo::IOLoop::Stream->new);

Get Mojo::IOLoop::Stream object for id or turn object into a connection.

# Increase inactivity timeout for connection to 300 seconds
Mojo::IOLoop->stream($id)->timeout(300);

subprocess

my $subprocess = Mojo::IOLoop->subprocess(sub {...}, sub {...});
my $subprocess = $loop->subprocess;
my $subprocess = $loop->subprocess(sub {...}, sub {...});

Build Mojo::IOLoop::Subprocess object to perform computationally expensive operations in subprocesses, without blocking the event loop. Callbacks will be passed along to "run" in Mojo::IOLoop::Subprocess.

# Operation that would block the event loop for 5 seconds
Mojo::IOLoop->subprocess(
  sub {
    my $subprocess = shift;
    sleep 5;
    return '♥', 'Mojolicious';
  },
  sub {
    my ($subprocess, $err, @results) = @_;
    say "Subprocess error: $err" and return if $err;
    say "I $results[0] $results[1]!";
  }
);

timer

my $id = Mojo::IOLoop->timer(3 => sub {...});
my $id = $loop->timer(0 => sub {...});
my $id = $loop->timer(0.25 => sub {...});

Create a new timer, invoking the callback after a given amount of time in seconds.

# Perform operation in 5 seconds
Mojo::IOLoop->timer(5 => sub {
  my $loop = shift;
  ...
});

transition

my $stream =
  Mojo::IOLoop->transition($id => 'Mojo::IOLoop::Stream::HTTPClient');
my $stream = $loop->transition($id => 'Mojo::IOLoop::Stream::HTTPClient');

Transition stream to a different class.

DEBUGGING

You can set the MOJO_IOLOOP_DEBUG environment variable to get some advanced diagnostics information printed to STDERR.

MOJO_IOLOOP_DEBUG=1

SEE ALSO

Mojolicious, Mojolicious::Guides, https://mojolicious.org.