Dave Cross: Still Munging Data With Perl: Online event - Mar 17 Learn more

THALJEF / Pinto-0.084_02 / lib / Pinto / Store.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
—
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147

              
# ABSTRACT: Storage for distribution archives
package Pinto::Store;
use Moose;
use MooseX::StrictConstructor;
use MooseX::MarkAsMethods (autoclean => 1);
use Try::Tiny;
use CPAN::Checksums;
use Pinto::Util qw(debug throw);
#------------------------------------------------------------------------------
our $VERSION = '0.084_02'; # VERSION
#------------------------------------------------------------------------------
with qw( Pinto::Role::FileFetcher );
#------------------------------------------------------------------------------
has repo => (
   is         => 'ro',
   isa        => 'Pinto::Repository',
   weak_ref   => 1,
   required   => 1,
);
#------------------------------------------------------------------------------
# TODO: Use named arguments here...
sub add_archive {
    my ($self, $origin, $destination) = @_;
    throw "$origin does not exist"      if not -e $origin;
    throw "$origin is not a file"       if not -f $origin;
    $self->fetch(from => $origin, to => $destination);
    $self->update_checksums(directory => $destination->parent);
    return $self;
}
#------------------------------------------------------------------------------
# TODO: Use named arguments here...
sub remove_archive {
    my ($self, $archive_file) = @_;
    $self->remove_path( path => $archive_file );
    $self->update_checksums( directory => $archive_file->parent );
    return $self;
}
#------------------------------------------------------------------------------
sub remove_path {
    my ($self, %args) = @_;
    my $path = $args{path};
    throw "Must specify a path" if not $path;
    return if not -e $path;
    $path->remove or throw "Failed to remove path $path: $!";
    while (my $dir = $path->parent) {
        last if $dir->children;
        debug("Removing empty directory $dir");
        $dir->remove or throw "Failed to remove directory $dir: $!";
        $path = $dir;
    }
    return $self;
}
#------------------------------------------------------------------------------
sub update_checksums {
    my ($self, %args) = @_;
    my $dir = $args{directory};
    return 0 if $ENV{PINTO_NO_CHECKSUMS};
    return 0 if not -e $dir; # Would be fishy!
     
    my @children = $dir->children;
    return if not @children;
    my $cs_file = $dir->file('CHECKSUMS');
    if ( -e $cs_file && @children == 1 ) {
        $self->remove_path(path => $cs_file);
        return 0;
    }
    debug("Generating $cs_file");
    try   { CPAN::Checksums::updatedir($dir) }
    catch { throw "CHECKSUM generation failed for $dir: $_" };
    return $self;
}
#------------------------------------------------------------------------------
1;
__END__
=pod
=for :stopwords Jeffrey Ryan Thalhammer BenRifkah Karen Etheridge Michael G. Schwern Oleg
Gashev Steffen Schwigon Bergsten-Buret Wolfgang Kinkeldei Yanick Champoux
hesco Cory G Watson Jakob Voss Jeff
=head1 NAME
Pinto::Store - Storage for distribution archives
=head1 VERSION
version 0.084_02
=head1 DESCRIPTION
L<Pinto::Store> is the base class for Pinto Stores.  It provides the
basic API for adding/removing distribution archives to the store.
Subclasses implement the underlying logic by augmenting the methods
declared here.
=head1 AUTHOR
Jeffrey Ryan Thalhammer <jeff@stratopan.com>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2013 by Jeffrey Ryan Thalhammer.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut