The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

THALJEF / Pinto-0.14 / lib / Pinto / Chrome / Net.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
—
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128

              
# ABSTRACT: Interface for network-based interaction
package Pinto::Chrome::Net;
use Moose;
use MooseX::StrictConstructor;
use MooseX::MarkAsMethods ( autoclean => 1 );
use Pinto::Types qw(Io);
use Pinto::Util qw(itis);
use Pinto::Constants qw(:protocol);
#-----------------------------------------------------------------------------
our $VERSION = '0.14'; # VERSION
#-----------------------------------------------------------------------------
extends qw( Pinto::Chrome::Term );
#-----------------------------------------------------------------------------
has stdout => (
    is       => 'ro',
    isa      => Io,
    required => 1,
    coerce   => 1,
);
has stderr => (
    is       => 'ro',
    isa      => Io,
    required => 1,
    coerce   => 1,
);
#-----------------------------------------------------------------------------
sub diag {
    my ( $self, $msg, $opts ) = @_;
    $opts ||= {};
    $msg = $msg->() if ref $msg eq 'CODE';
    if ( itis( $msg, 'Pinto::Exception' ) ) {
        # Show full stack trace if we are debugging
        $msg = $ENV{PINTO_DEBUG} ? $msg->as_string : $msg->message;
    }
    chomp $msg;
    $msg = $self->colorize( $msg, $opts->{color} );
    $msg .= "\n" unless $opts->{no_newline};
    # Prepend prefix to each line (not just at the start of the message)
    # The prefix is used by Pinto::Remote to distinguish between
    # messages that go to stderr and those that should go to stdout
    $msg =~ s/^/$PINTO_PROTOCOL_DIAG_PREFIX/gmx;
    print { $self->stderr } $msg or croak $!;
}
#-----------------------------------------------------------------------------
sub show_progress {
    my ($self) = @_;
    return if not $self->should_render_progress;
    $self->stderr->autoflush;    # Make sure pipes are hot
    print { $self->stderr } $PINTO_PROTOCOL_PROGRESS_MESSAGE . "\n" or croak $!;
}
#-----------------------------------------------------------------------------
sub should_render_progress {
    my ($self) = @_;
    return 0 if $self->verbose;
    return 0 if $self->quiet;
    return 1;
}
#-----------------------------------------------------------------------------
sub edit {
    my ( $self, $document ) = @_;
    return $document;    # TODO!
}
#-----------------------------------------------------------------------------
__PACKAGE__->meta->make_immutable;
#-----------------------------------------------------------------------------
1;
__END__
=pod
=encoding UTF-8
=for :stopwords Jeffrey Ryan Thalhammer
=head1 NAME
Pinto::Chrome::Net - Interface for network-based interaction
=head1 VERSION
version 0.14
=head1 AUTHOR
Jeffrey Ryan Thalhammer <jeff@stratopan.com>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2015 by Jeffrey Ryan Thalhammer.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut