The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

YAPPO / HTTP-Engine-Middleware-0.22 / lib / HTTP / Engine / Middleware / HTTPSession.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
—
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128

              
package HTTP::Engine::Middleware::HTTPSession;
use HTTP::Engine::Middleware;
use Scalar::Util qw/blessed/;
use Any::Moose 'X::Types' => [ -declare => [qw/State Store/] ];
use Any::Moose 'X::Types::'.any_moose() => [ qw(CodeRef Object HashRef) ];
use HTTP::Session;
subtype State,
    as CodeRef;
coerce State,
    from Object,
        via {
            my $x = $_;
            sub { $x }
        };
coerce State,
    from HashRef,
        via {
            my $klass = $_->{class};
            $klass = $klass =~ s/^\+// ? $klass : "HTTP::Session::State::${klass}";
            Any::Moose::load_class($klass);
            my $obj = $klass->new( $_->{args} );
            sub { $obj };
        };
subtype Store,
    as CodeRef;
coerce Store,
    from Object,
        via {
            my $x = $_;
            sub { $x }
        };
coerce Store,
    from HashRef,
        via {
            my $klass = $_->{class};
            $klass = $klass =~ s/^\+// ? $klass : "HTTP::Session::Store::${klass}";
            Any::Moose::load_class($klass);
            my $obj = $klass->new( $_->{args} );
            sub { $obj };
        };
has 'state' => (
    is     => 'ro',
    isa    => State,
    coerce => 1,
);
has 'store' => (
    is     => 'ro',
    isa    => Store,
    coerce => 1,
);
{
    my $SESSION;
    my $SELF;
    my $REQ;
    middleware_method 'session' => sub {
        $SESSION ||= HTTP::Session->new(
            state   => $SELF->state->(),
            store   => $SELF->store->(),
            request => $REQ,
        );
    };
    before_handle {
        (undef, $SELF, $REQ) = @_;
        undef $SESSION;
        $REQ;
    };
    after_handle {
        my ($c, $self, $req, $res) = @_;
        if ($SESSION && $res) {
            $SESSION->response_filter($res);
            $SESSION->finalize();
        }
        undef $SESSION;
        undef $SELF;
        undef $REQ;
        $res;
    };
}
__MIDDLEWARE__
__END__
=head1 NAME
HTTP::Engine::Middleware::HTTPSession - session support at middleware layer
=head1 SYNOPSIS
    my $mw = HTTP::Engine::Middleware->new;
    $mw->install( 'HTTP::Engine::Middleware::HTTPSession' => {
        state => {
            class => 'URI',
            args  => {
                session_id_name => 'foo_sid',
            },
        },
        store => {
            class => 'Test',
            args => { },
        },
    });
    HTTP::Engine->new(
        interface => {
            module => 'YourFavoriteInterfaceHere',
            request_handler => $mw->handler( \&handler ),
        }
    )->run();
=head1 DESCRIPTION
This middleware add the session management stuff for your web application
=head1 AUTHOR
tokuhirom
=head1 SEE ALSO
L<HTTP::Engine::Middleware>, L<HTTP::Session>