/ 
POE-Component-IRC-Plugin-BasePoCoWrap-0.003
/ POE::Component::IRC::Plugin::BasePoCoWrap

NAME

POE::Component::IRC::Plugin::BasePoCoWrap - base talking/ban/trigger functionality for plugins using POE::Component::*

SYNOPSIS

package POE::Component::IRC::Plugin::WrapExample;

use strict;
use warnings;

use base 'POE::Component::IRC::Plugin::BasePoCoWrap';
use POE::Component::WWW::Google::Calculator;

sub _make_default_args {
    return (
        response_event   => 'irc_google_calc',
        trigger          => qr/^calc\s+(?=\S)/i,
    );
}

sub _make_poco {
    return POE::Component::WWW::Google::Calculator->spawn(
        debug => shift->{debug},
    );
}

sub _make_response_message {
    my $self   = shift;
    my $in_ref = shift;
    return [ exists $in_ref->{error} ? $in_ref->{error} : $in_ref->{out} ];
}

sub _make_response_event {
    my $self = shift;
    my $in_ref = shift;

    return {
        ( exists $in_ref->{error} 
            ? ( error => $in_ref->{error} )
            : ( result => $in_ref->{out} )
        ),

        map { $_ => $in_ref->{"_$_"} }
            qw( who channel  message  type ),
    }
}

sub _make_poco_call {
    my $self = shift;
    my $data_ref = shift;

    $self->{poco}->calc( {
            event       => '_poco_done',
            term        => delete $data_ref->{what},
            map +( "_$_" => $data_ref->{$_} ),
                keys %$data_ref,
        }
    );
}

1;
__END__

DESCRIPTION

The module is a base class to use for plugins which use a POE::Component::* object internally. It provides: triggering with a trigger, listening for requests in public channels, /notice and /msg (with ability to configure which exactly) as well as auto-responding to those requests. It provides "banned" feature which allows you to ignore certain people if their usermask matches a regex.

I am not sure how flexible this base wrapper can get, just give it a try. Suggestions for improvements/whishlists are more than welcome.

FORMAT OF THIS DOCUMENT

This document uses word "plugin" to refer to the plugin which uses this base class.

Of course, by providing more functionality you need to document it. At the end of this document you will find a POD snippet which you can simply copy/paste into your plugin's docs. I recommend that you read that snippet first as to understand what functionality this base class provides.

SUBS YOU NEED TO OVERRIDE

_make_default_args

sub _make_default_args {
    return (
        response_event   => 'irc_google_calc',
        trigger          => qr/^calc\s+(?=\S)/i,
    );
}

This sub must return a list of key/value arguments which you need to override. What you specify here will be possible to override by the user from the new() method of the plugin.

A (sane) plugin would return a response_event and trigger arguments from this sub. There are some mandatory, or I shall rather say "reserved" arguments (they have defaults) which you can return from this sub which are as follows. On the left are the argument name, on the right is the default value it will take if you don't return it from the _make_default_args sub:

debug            => 0,
auto             => 1,
response_event   => 'irc_poco_wrap_response',
banned           => [],
addressed        => 1,
eat              => 1,
trigger          => qr/^poco_wrap\s+(?=\S)/i,
listen_for_input => [ qw(public notice privmsg) ],

Read the "PLUGIN DOCUMENTATION" section to understand what each of these do.

_make_poco

sub _make_poco {
    return POE::Component::WWW::Google::Calculator->spawn(
        debug => shift->{debug},
    );
}

This sub must return your POE::Component::* object. The arguments which are available to the user in the new() method of the plugin (i.e. the ones which you returned from _make_default_args and the default ones) will be available as hash keys in the first element of @_ which is also your plugin's object.

_make_poco_call

sub _make_poco_call {
    my $self = shift;
    my $data_ref = shift;

    $self->{poco}->calc( {
            event       => '_poco_done',
            term        => delete $data_ref->{what},
            map +( "_$_" => $data_ref->{$_} ),
                keys %$data_ref,
        }
    );
}

In this sub you would make a call to your POE::Component::* object asking for some data. After the plugin returns the calls to _make_response_message and _make_response_event will be made and @_[ARG0 .. $#_ ] will contain whatever your PoCo returns.

NOTE: your PoCo must send the response to an event named _poco_done otherwise you'll have to override more methods which is left as an exercise. (RTFS! :) )

The first element of @_ in _make_poco_call sub will contain plugin's object, the second element will contain a hashref with the following keys/values:

$VAR1 = {
    'who' => 'Zoffix__!n=Zoffix@unaffiliated/zoffix',
    'what' => 'http://zoffix.com',
    'type' => 'public',
    'channel' => '#zofbot',
    'message' => 'CalcBot, rank http://zoffix.com'
};
who

The mask of the other who triggered the request

what

The input after stripping the trigger (note, leading/trailing white-space is stripped as well)

type

This will be either public, privmsg or notice and will indicate where the message came from.

channel

This will be the channel name if the request came from a public channel

message

This will be the full message of the user who triggered the request.

_make_response_message

sub _make_response_message {
    my $self   = shift;
    my $in_ref = shift;
    return [ exists $in_ref->{error} ? $in_ref->{error} : $in_ref->{out} ];
}

This sub must return an arrayref. Each element will be "spoken" in the channel/notice/msg (depending on the type of the request). The <@_> array will contain plugin's object as the first element and @_[ARG0 .. $#_] will be the rest of the elements.

_make_response_event

sub _make_response_event {
    my $self = shift;
    my $in_ref = shift;

    return {
        ( exists $in_ref->{error} 
            ? ( error => $in_ref->{error} )
            : ( result => $in_ref->{out} )
        ),

        map { $_ => $in_ref->{"_$_"} }
            qw( who channel  message  type ),
    }
}

This sub will be called internally like this:

$self->{irc}->_send_event(
    $self->{response_event} =>
    $self->_make_response_event( @_[ARG0 .. $#_] )
);

Therefore it must return something that you would like to see in the even handler set up to handle response_even. The @_ will contain plugin's object as the first element and @_[ARG0 .. $#_]

_message_into_response_event

sub _message_into_response_event { 'name_of_key'; }

While using previous version of this module I often found myself wishing to put the return value of _make_response_message() as a certain key in $in_ref of _make_response_event() sub.. and didn't want to do whatever the plugin would be doing twice. Now this can be easily done.

The _message_into_response_event sub must return a true value which will be the name of the key which will contain the return value of _make_response_message() sub and stuffed into $in_ref hashref of the _make_response_event() sub. Basically, if you are defining _message_into_response_event() sub you should not define _make_response_message() sub as it will never be called.

If along with the return value of _make_response_message() you also want to add some extra keys into the $in_ref you can return an arrayref from _message_into_response_event() sub with two elements. The first element of that arrayref would be the name of the key into which to stick the return value of _make_response_message(). The second element must be a hashref with extra keys/values which will be set in the $in_ref; note that you can override original keys from here.

The @_ will contain your plugin's object as the first element and $in_ref as a second element ( see _make_response_event() )

As an example, the following two snippets are equivalent:

sub _make_response_message {
    return "Right now it is " . localtime;
}

sub _make_response_event {
    my ( $self, $in_ref ) = @_;
    $in_ref->{time} = "Right now it is " . localtime;
    return $in_ref;
}

# is the same as:

sub _make_response_message {
    return "Right now it is " . localtime;
}

sub _message_into_response_event { 'time' }

PREREQUISITES

This base class likes to play with the following modules under the hood:

Carp
POE
POE::Component::IRC::Plugin

EXAMPLES

The examples/ directory of this distribution contains an example plugin written using POE::Component::IRC::Plugin::BasePoCoWrap as well as a google page rank bot which uses that plugin.

PLUGIN DOCUMENTATION

This section lists a "default" plugin's documentation which you can copy/paste (and EDIT!) into your brand new plugin to describe the functionality this base class offers. Make sure to proof read ;)

=head1 SYNOPSIS

    use strict;
    use warnings;

    use POE qw(Component::IRC  Component::IRC::Plugin::EXAMPLE);

    my $irc = POE::Component::IRC->spawn(
        nick        => 'EXAMPLE',
        server      => 'irc.freenode.net',
        port        => 6667,
        ircname     => 'EXAMPLE',
    );

    POE::Session->create(
        package_states => [
            main => [ qw(_start irc_001) ],
        ],
    );

    $poe_kernel->run;

    sub _start {
        $irc->yield( register => 'all' );
        
        $irc->plugin_add(
            'EXAMPLE' =>
                POE::Component::IRC::Plugin::EXAMPLE->new
        );

        $irc->yield( connect => {} );
    }

    sub irc_001 {
        $_[KERNEL]->post( $_[SENDER] => join => '#zofbot' );
    }

    <Zoffix_> EXAMPLE, example example
    <EXAMPLE> HUH?!?!! This is just an example?!?! :(

=head1 DESCRIPTION

This module is a L<POE::Component::IRC> plugin which uses
L<POE::Component::IRC::Plugin> for its base. It provides interface to
EXAMPLE EXAMPLE EXAMPLE EXAMPLE EXAMPLE.
It accepts input from public channel events, C</notice> messages as well
as C</msg> (private messages); although that can be configured at will.

=head1 CONSTRUCTOR

=head2 C<new>

    # plain and simple
    $irc->plugin_add(
        'EXAMPLE' => POE::Component::IRC::Plugin::EXAMPLE->new
    );

    # juicy flavor
    $irc->plugin_add(
        'EXAMPLE' =>
            POE::Component::IRC::Plugin::EXAMPLE->new(
                auto             => 1,
                response_event   => 'irc_EXAMPLE',
                banned           => [ qr/aol\.com$/i ],
                addressed        => 1,
                root             => [ qr/mah.net$/i ],
                trigger          => qr/^EXAMPLE\s+(?=\S)/i,
                triggers         => {
                    public  => qr/^EXAMPLE\s+(?=\S)/i,
                    notice  => qr/^EXAMPLE\s+(?=\S)/i,
                    privmsg => qr/^EXAMPLE\s+(?=\S)/i,
                },
                listen_for_input => [ qw(public notice privmsg) ],
                eat              => 1,
                debug            => 0,
            )
    );

The C<new()> method constructs and returns a new
C<POE::Component::IRC::Plugin::EXAMPLE> object suitable to be
fed to L<POE::Component::IRC>'s C<plugin_add> method. The constructor
takes a few arguments, but I<all of them are optional>. The possible
arguments/values are as follows:

=head3 C<auto>

    ->new( auto => 0 );

B<Optional>. Takes either true or false values, specifies whether or not
the plugin should auto respond to requests. When the C<auto>
argument is set to a true value plugin will respond to the requesting
person with the results automatically. When the C<auto> argument
is set to a false value plugin will not respond and you will have to
listen to the events emited by the plugin to retrieve the results (see
EMITED EVENTS section and C<response_event> argument for details).
B<Defaults to:> C<1>.

=head3 C<response_event>

    ->new( response_event => 'event_name_to_recieve_results' );

B<Optional>. Takes a scalar string specifying the name of the event
to emit when the results of the request are ready. See EMITED EVENTS
section for more information. B<Defaults to:> C<irc_EXAMPLE>

=head3 C<banned>

    ->new( banned => [ qr/aol\.com$/i ] );

B<Optional>. Takes an arrayref of regexes as a value. If the usermask
of the person (or thing) making the request matches any of
the regexes listed in the C<banned> arrayref, plugin will ignore the
request. B<Defaults to:> C<[]> (no bans are set).

=head3 C<root>

    ->new( root => [ qr/\Qjust.me.and.my.friend.net\E$/i ] );

B<Optional>. As opposed to C<banned> argument, the C<root> argument
B<allows> access only to people whose usermasks match B<any> of
the regexen you specify in the arrayref the argument takes as a value.
B<By default:> it is not specified. B<Note:> as opposed to C<banned>
specifying an empty arrayref to C<root> argument will restrict
access to everyone.

=head3 C<trigger>

    ->new( trigger => qr/^EXAMPLE\s+(?=\S)/i );

B<Optional>. Takes a regex as an argument. Messages matching this
regex, irrelevant of the type of the message, will be considered as requests. See also
B<addressed> option below which is enabled by default as well as
B<trigggers> option which is more specific. B<Note:> the
trigger will be B<removed> from the message, therefore make sure your
trigger doesn't match the actual data that needs to be processed.
B<Defaults to:> C<qr/^EXAMPLE\s+(?=\S)/i>

=head3 C<triggers>

    ->new( triggers => {
            public  => qr/^EXAMPLE\s+(?=\S)/i,
            notice  => qr/^EXAMPLE\s+(?=\S)/i,
            privmsg => qr/^EXAMPLE\s+(?=\S)/i,
        }
    );

B<Optional>. Takes a hashref as an argument which may contain either
one or all of keys B<public>, B<notice> and B<privmsg> which indicates
the type of messages: channel messages, notices and private messages
respectively. The values of those keys are regexes of the same format and
meaning as for the C<trigger> argument (see above). 
Messages matching this
regex will be considered as requests. The difference is that only messages of type corresponding to the key of C<triggers> hashref
are checked for the trigger. B<Note:> the C<trigger> will be matched
irrelevant of the setting in C<triggers>, thus you can have one global and specific "local" triggers. See also
B<addressed> option below which is enabled by default as well as
B<trigggers> option which is more specific. B<Note:> the
trigger will be B<removed> from the message, therefore make sure your
trigger doesn't match the actual data that needs to be processed.
B<Defaults to:> C<qr/^EXAMPLE\s+(?=\S)/i>

=head3 C<addressed>

    ->new( addressed => 1 );

B<Optional>. Takes either true or false values. When set to a true value
all the public messages must be I<addressed to the bot>. In other words,
if your bot's nickname is C<Nick> and your trigger is
C<qr/^trig\s+/>
you would make the request by saying C<Nick, trig EXAMPLE>.
When addressed mode is turned on, the bot's nickname, including any
whitespace and common punctuation character will be removed before
matching the C<trigger> (see above). When C<addressed> argument it set
to a false value, public messages will only have to match C<trigger> regex
in order to make a request. Note: this argument has no effect on
C</notice> and C</msg> requests. B<Defaults to:> C<1>

=head3 C<listen_for_input>

    ->new( listen_for_input => [ qw(public  notice  privmsg) ] );

B<Optional>. Takes an arrayref as a value which can contain any of the
three elements, namely C<public>, C<notice> and C<privmsg> which indicate
which kind of input plugin should respond to. When the arrayref contains
C<public> element, plugin will respond to requests sent from messages
in public channels (see C<addressed> argument above for specifics). When
the arrayref contains C<notice> element plugin will respond to
requests sent to it via C</notice> messages. When the arrayref contains
C<privmsg> element, the plugin will respond to requests sent
to it via C</msg> (private messages). You can specify any of these. In
other words, setting C<( listen_for_input => [ qr(notice privmsg) ] )>
will enable functionality only via C</notice> and C</msg> messages.
B<Defaults to:> C<[ qw(public  notice  privmsg) ]>

=head3 C<eat>

    ->new( eat => 0 );

B<Optional>. If set to a false value plugin will return a
C<PCI_EAT_NONE> after
responding. If eat is set to a true value, plugin will return a
C<PCI_EAT_ALL> after responding. See L<POE::Component::IRC::Plugin>
documentation for more information if you are interested. B<Defaults to>:
C<1>

=head3 C<debug>

    ->new( debug => 1 );

B<Optional>. Takes either a true or false value. When C<debug> argument
is set to a true value some debugging information will be printed out.
When C<debug> argument is set to a false value no debug info will be
printed. B<Defaults to:> C<0>.

=head1 EMITED EVENTS

=head2 C<response_event>

   EXAMPLE

The event handler set up to handle the event, name of which you've
specified in the C<response_event> argument to the constructor
(it defaults to C<irc_EXAMPLE>) will recieve input
every time request is completed. The input will come in C<$_[ARG0]>
on a form of a hashref.
The possible keys/values of that hashrefs are as follows:

=head3 C<EXAMPLE>

=head3 C<who>

    { 'who' => 'Zoffix!Zoffix@i.love.debian.org', }

The C<who> key will contain the user mask of the user who sent the request.

=head3 C<what>

    { 'what' => 'EXAMPLE', }

The C<what> key will contain user's message after stripping the C<trigger>
(see CONSTRUCTOR).

=head3 C<message>

    { 'message' => 'EXAMPLE' }

The C<message> key will contain the actual message which the user sent; that
is before the trigger is stripped.

=head3 C<type>

    { 'type' => 'public', }

The C<type> key will contain the "type" of the message the user have sent.
This will be either C<public>, C<privmsg> or C<notice>.

=head3 C<channel>

    { 'channel' => '#zofbot', }

The C<channel> key will contain the name of the channel where the message
originated. This will only make sense if C<type> key contains C<public>.

AUTHOR

Zoffix Znet, <zoffix at cpan.org>

BUGS

Please report any bugs or feature requests to bug-poe-component-irc-plugin-basepocowrap at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=POE-Component-IRC-Plugin-BasePoCoWrap. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

You can find documentation for this module with the perldoc command.

perldoc POE::Component::IRC::Plugin::BasePoCoWrap

You can also look for information at:

COPYRIGHT & LICENSE

Copyright 2008 Zoffix Znet, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.